Tumor

Tumor preview image

1 collaborator

Uri_dolphin3 Uri Wilensky (Author)

Tags

biology 

Tagged by Reuven M. Lerner almost 6 years ago

tumor 

"(Optional) comment about why this tag is relevant to this model"

Tagged by Abigail Jacobs over 10 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 329 times • Downloaded 31 times • Run 0 times
Download the 'Tumor' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model illustrates the growth of a tumor and how it resists chemical treatment. A tumor consists of two kinds of cells: stem cells (blue turtles) and transitory cells (all other turtles).

HOW IT WORKS

During mitosis, a stem cell can divide either asymmetrically or symmetrically. In asymmetric mitosis, one of the two daughter cells remains a stem cell, replacing its parent. So a stem cell effectively never dies - it is quasi reincarnated after each division. The other daughter cell turns into a transitory cell that moves outward.

Young transitory cells may divide, breeding other transitory cells. The transitory cells stop dividing at a certain age and change color from red to white to black, eventually dying.

A stem cell may also divide symmetrically into two stem cells (blue turtles). In this example the original stem cell divides symmetrically only once. The first stem cell remains static, but the second stem cell moves to the right. This activity, in which the cell advances into distant sites and creates another tumor colony, is called metastasis. Notice that the metastasis is red. It is made of cells that die young, when they are still red, rather than ending as black dots as in the static tumor. As the disease progresses, cells die younger and younger.

HOW TO USE IT

SETUP: Clears the world and creates two blue neoplastic (cancerous) stem cells. One cell stays put and the other moves to the right. GO: Runs the simulation. KILL TRANSITORY CELLS: Kills transitory cells that are younger than 10 time steps. KILL STEM CELL: Kills a stem cell. If the adjacent KILL-MOVING-CELL switch is set to OFF, the original is eliminated. If the switch is set to ON, the moving stem cell is eliminated. KILL-MOVING-CELL: Determines which stem cell is killed when the KILL STEM CELL button is pressed. LEAVE-TRAIL: If it's ON, the cells trace their paths; if it's OFF, they do not. CELL-COUNT: Displays the total number of living cells. LIVING CELLS PLOT: plots the number of living cells.

THINGS TO NOTICE

First, notice the blue dot. It represents a normal stem cell that has been transformed into a tumor stem cell. Set the "leave-trail" switch to On, and click 'go'. A tumor is formed as the stem cell creates transitory cells, which reproduce themselves. It grows to a certain size. As it grows, a bulge appears on the right side. This is a tumor outgrowth, caused by symmetric mitosis of the stem cell. The outgrowth will turn into a metastasis and grow into remote regions.

After a while the tumor and metastasis appear to reach their ultimate size and nothing interesting seems to be happening. This illustrates how the tumor presents itself to the physician - as a solid cell mass. In reality, this seemingly solid mass conceals active cell turnover. To reveal it, set the leave-trail switch to Off, click on SETUP, and then click on GO to run the simulation again.

Slow down the model so you can follow individual steps. Move the speed slider to the left, click on SETUP and GO, and observe the blue stem cell. It divides into two blue stem cells. One remains static, and the other moves to the right.

Look at the static stem cell (blue). It breeds red cells which move outward and change their color as they age. When young, they are red and create more transitory cells. Then they turn white, then black, and then they die.

THINGS TO TRY

Try a treatment: click on the 'kill transitory cells' button while the model is running. This simulates treatment with a chemical agent. The agent eliminates young (red) cells that divide, and it spares older cells. Note that the tumor shrinks and grows again. Continue with this "chemotherapy" by clicking on the button again and watch the plot. Repeat the treatment several times until you have understood why it fails.

Most of the chemotherapy drugs known as M- and S-poisons inhibit cell division, but generally do not cause cell death. Thus chemotherapy can be represented as killing the young (red) transitory cells, since only young cells divide. Older, non-dividing transitory cells are not affected; they continue aging and finally pass away.

The problem is that the stem cells maintain the tumor and propagate its metastases. Also known as clonogenic cells, stem cells are generally resistant to chemotherapy. They can be eliminated only with high doses of chemicals, which endanger healthy stem cells. The therapeutic margin of chemical drugs is extremely narrow. That is, they do about the same amount of harm as good.

Let the tumor grow again. Click on 'kill moving stem cell' and continue running the model. The right blue stem cell disappears. Its progeny live a bit longer and then die. Now click on "kill original stem cell", and watch the gradual disappearance of the tumor, as no new cells are created and existing cells continue aging until they die and disappear.

Any questions? Before asking, continue exploring the model until you grasp its behavior. The model reveals a hidden dimension that is difficult to understand. It is the time dimension of tissues (and the tumor) in the body.

EXTENDING THE MODEL

What alternative treatments would you suggest? How would you model them here?

CREDITS AND REFERENCES

The original StarLogoT Tumor model was contributed by Gershom Zajicek M.D., Professor of Experimental Medicine and Cancer Research at The Hebrew University-Hadassah Medical School, Jerusalem.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

  • Wilensky, U. (1998). NetLogo Tumor model. http://ccl.northwestern.edu/netlogo/models/Tumor. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
  • Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Copyright 1998 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

a question (Question)

where are the cookies?

Posted over 10 years ago

Click to Run Model

turtles-own
[
  stem?     ;; true for stem cells, false for transitory cells
  age  ;; age of cell. changes color with age
  metastatic?  ;; false for progeny of stem cell 0, true for progeny of stem cell 1
]

globals
[
  cell-count
]

to setup
  clear-all
  set-default-shape turtles "circle 3"
  ask patches
    [ set pcolor gray ]
  set-stem
  evaluate-params
  reset-ticks
end 

to set-stem   ;;create two stem cells
  crt 2
  [
    set size 2   ; easier to see
    setxy (min-pxcor / 2) 0
    set stem? true
    set metastatic? false
    set color blue
    set age 0
  ]
  ask turtle 1
  [
    set metastatic? true
    set heading 90            ;; stem cell 1 will move away
  ]
  set cell-count 2
end 

to go
  ask turtles
  [
    ifelse leave-trail?
      [ pd ]
      [ pu ]
    if (who = 1) and (xcor < 25)
    [ fd 1 ]  ;stem cell movement
    set age age + 1
    move-transitional-cells
    mitosis
    death
  ]
  tick
  evaluate-params
end 

;;transitional cells move and hatch more. Turtle proc.

to move-transitional-cells
  if (not stem?)
  [
    set color ( red + 0.25 * age )
    fd 1
    if (age < 6)
    [
      hatch 1
      [  ;amplification
        rt random-float 360
        fd 1
      ]
    ]
  ]
end 

to mitosis ;; turtle proc. - stem cells only
  if stem?
  [
    hatch 1
    [
      fd 1
      set color red
      set stem? false
      ifelse (who = 1)
        [ set age 16 ]
        [ set age 0 ]
    ]
  ]
end 

to death   ;; turtle proc.
  if (not stem?) and (not metastatic?) and (age > 20)
    [ die ]
  if (not stem?) and metastatic? and (age > 4)
    [ die ]
end 

to evaluate-params
  set cell-count count turtles  ;cell count
  if (cell-count <= 0)
    [ stop ]
end 

to kill-original-stem-cell
  ask turtle 0
    [ die ]
end 

to kill-moving-stem-cell
  ask turtle 1
    [ die ]
end 

to kill-transitory-cells
  ask turtles with [ age < 10 and not stem? ]
    [ die ]
end 


; Copyright 1998 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by When Description Download
Uri Wilensky about 6 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky over 6 years ago Updated version tag Download this version
Uri Wilensky over 6 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky over 7 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky almost 9 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 9 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 9 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 9 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky about 9 years ago Model from NetLogo distribution Download this version
Uri Wilensky about 9 years ago Tumor Download this version

Attached files

File Type Description Last updated
Tumor.png preview Preview for 'Tumor' about 6 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.