GenDrift T interact

GenDrift T interact preview image

1 collaborator

Uri_dolphin3 Uri Wilensky (Author)

Tags

biology 

Tagged by Reuven M. Lerner over 10 years ago

evolution 

Tagged by Reuven M. Lerner over 10 years ago

genetic drift 

Tagged by Reuven M. Lerner over 10 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 396 times • Downloaded 84 times • Run 0 times
Download the 'GenDrift T interact' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model is an example of random selection. It shows that turtles that randomly exchange colors converge on a single color. The idea, explained in more detail in Dennett's "Darwin's Dangerous Idea", is that trait drifts can occur without any particular purpose or "selective pressure".

HOW IT WORKS

The model starts with a random distribution of colored agents. Turtles move by wiggling randomly across the world. When two turtles are next to each other, one turtle changes its color to the color of the other one. Note that if a color dies out, it can never come back.

HOW TO USE IT

The NUMBER slider sets the number of turtles. The COLORS slider selects the number of competing colors, up to ten.

The SETUP button initializes the model, and GO runs the model.

A monitor shows the percentage of turtles sharing the most common color. When this reaches 100%, the model stops.

After pressing PLACE-WALLS, the user can "draw" walls in the world at the location where the user clicks with the mouse. By pressing REMOVE-WALLS, the user can remove added walls. The REMOVE-ALL-WALLS button removes all walls including the border. (The SETUP button does not remove walls.)

THINGS TO NOTICE

Gradually a color will gain a slight dominance. By statistical advantage, a dominant color becomes more likely to have more colors like it. However, because the process is random, there will usually be a series of dominant colors before one color finally wins.

THINGS TO TRY

Experiment with adding walls.

When walls are added, groups of individuals can be geographically isolated so that they can not interact with their neighbors on the other side of the wall. Groups that are geographically isolated with walls will often end up with a different dominant color than the larger population. A group of individuals that is walled off becomes a "founding group". The founding group of individuals has a different genetic variability and distribution than the main population, so the frequency of certain traits may end up drifting in a different direction compared with the much larger population.

EXTENDING THE MODEL

In this model, a turtle looks one patch to its right. If there's another turtle there, the "looking" turtle changes to that turtle's color. Since the turtles move randomly about the world, it's a matter of chance which turtle will change to the color of its neighbor.

Think of other rules for turtle interactions, random or otherwise, by which a turtle color might "take over".

RELATED MODELS

  • GenDrift (P Global)
  • GenDrift (P local)
  • GenDrift (T reproduce)

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

COPYRIGHT AND LICENSE

Copyright 1997 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Click to Run Model

globals [
  max-percent  ;; percent of the total population that is in the
               ;; most populous group
]

to setup
  ;; We don't use clear-all here because that would erase
  ;; any walls the user drew.
  clear-turtles
  clear-all-plots
  ;; create turtles with random colors and locations
  crt number [
    set color item (random colors) [5 15 25 35 45 55 65 85 95 125]
    setxy random-xcor random-ycor
    move-off-wall
  ]
  reset-ticks
end 

to go
  if (variance [color] of turtles) = 0
    [ stop ]
  ask turtles [
    rt random 50 - random 50
    meet
    ;; move, but don't step on wall
    ifelse [pcolor] of patch-ahead 0.5 = black
      [ fd 0.5 ]
      [ rt random 360 ]
  ]
  find-top-species
  tick
end 

to meet    ;; turtle procedure - when two turtles are next door,
           ;; the left one changes to the color of the right one
  let candidate one-of turtles-at 1 0
  if candidate != nobody [
    set color [color] of candidate
  ]
end 

to find-top-species  ;;find the percentage of the most populous species
  let winning-amount 0
  foreach base-colors [
    let how-many count turtles with [color = ?]
    if how-many > winning-amount
      [ set winning-amount how-many ]
  ]
  set max-percent (100 * winning-amount / count turtles)
end 

;; ---------------------------------------------------------------------------------
;; Below this point are procedure definitions that have to do with "walls," which
;; the user may create in order to separate groups of turtles from one another.
;; The use of walls is optional, and can be seen as a more advanced topic.
;; ---------------------------------------------------------------------------------

to place-wall
  if mouse-down? [
    ;; Note that when we place a wall, we must also place walls
    ;; at the world boundaries, so turtles can't change rooms
    ;; by wrapping around the edge of the world.
    ask patches with [abs pycor = max-pycor or
                      pycor = round mouse-ycor] [
      set pcolor white
      ;; There might be some turtles standing where the
      ;; new walls is, so we need to move them into a room.
      ask turtles-here [ move-off-wall ]
    ]
    display
  ]
end 

to remove-wall
  if mouse-down? [
    ask patches with [pycor = round mouse-ycor]
      [ set pcolor black ]
    display
  ]
end 

to remove-all-walls
  clear-patches
end 

to move-off-wall  ;; turtle procedure
  while [pcolor != black] [
    move-to one-of neighbors
  ]
end 


; Copyright 1997 Uri Wilensky.
; See Info tab for full copyright and license.

There are 15 versions of this model.

Uploaded by When Description Download
Uri Wilensky almost 11 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky over 11 years ago Updated version tag Download this version
Uri Wilensky over 11 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky about 12 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago GenDrift T interact Download this version

Attached files

File Type Description Last updated
GenDrift T interact.png preview Preview for 'GenDrift T interact' almost 11 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.