Breeds and Shapes Example

breed [monsters monster]
breed [fish a-fish]       ;; the word "fish" is both singular and plural,
                          ;; so we need to use something different for
                          ;; the singular form

to setup
  clear-all               ;; clear all patches and turtles
  set-default-shape monsters "monster"  ;; shape is defined in Turtle Shapes Editor
  set-default-shape fish     "fish"     ;; ditto
  ask patches with [pxcor = 0] [        ;; just the middle column of patches
    ifelse random 2 = 0                 ;; flip a coin
      [ sprout-monsters 1 ]
      [ sprout-fish     1 ]
  ]
  ask turtles [           ;; includes both monsters and fish
    set heading 90        ;; face east
  ]
  reset-ticks
end 

to move-monsters
  ask monsters [ fd 1 ]
  tick
end 

to move-fish
  ask fish [ fd 1 ]
  tick
end 


; Public Domain:
; To the extent possible under law, Uri Wilensky has waived all
; copyright and related or neighboring rights to this model.