B-Z Benchmark

globals [result]

patches-own [state new-state]

to benchmark
  random-seed 5454
  reset-timer
  setup
  repeat 10 [ go ]
  set result timer
end 

to setup
  ca
  ask patches
    [ set state random (n + 1)   ;; pick a state from 0 to n
      set pcolor scale-color red state 0 n ]
end 

to go
  ;; first all the patches compute their new state
  ask patches [ find-new-state ]
  ;; only once all the patches have computed their new state
  ;; do they actually change state
  ask patches
  [ set state new-state
    set pcolor scale-color red state 0 n ]
  tick
end 

to find-new-state  ;; patch procedure
  ifelse state = n  ;; ill?
    [ set new-state 0 ] ;; get well
    [ let a count neighbors with [state > 0 and state < n]  ;; count infected
      let b count neighbors with [state = n] ;; count ill
      ifelse state = 0  ;; healthy?
        [ set new-state int (a / k1) + int (b / k2) ]
        [ let s state + sum [state] of neighbors
          set new-state int (s / (a + b + 1)) + g ]
      if new-state > n   ;; don't exceed the maximum state
        [ set new-state n ] ]
end