Electron Sink

2 collaborators

Uri Wilensky (Author)

WHAT IS IT?

This is a simplified model of electrical conduction based on Drude's free electron theory. It shows how electric current in a circuit consisting of a resistive wire connected across two terminals of a battery can be represented as a process of accumulation of free-electrons inside the battery-positive.

HOW IT WORKS

This model is based on Drude's free electron theory. The wire in this model (gray patches region) is composed of atoms, which in turn are made of negatively charged electrons and positively charged nuclei. These nuceli are hidden from view in this model for simplicity, but are displayed in the subsequent NIELS models (Current in a Wire, Series Circuit and Parallel Circuit).

According to the Bohr model of the atom, these electrons revolve in concentric shells around the nucleus. However, in each atom, the electrons that are farthest away from the nucleus (i.e., the electrons that are in the outermost shell of each atom) behave as if they are free from the nuclear attraction. These outermost electrons from each atom are called "free electrons". These free electrons obey some rules that are specified in the "Procedures" tab in the model. The applied voltage due to the battery imparts a constant speed to the electrons in the direction of the positive terminal. This is again a simplification - in reality, the voltage imparts acceleration to the electrons, and this can be seen in the subsequent NIELS models.

HOW TO USE IT

This model has three variables: NUMBER-OF-ELECTRONS, SPEED-OF-ELECTRONS, and ELECTRON-SINK-CAPACITY. The first two variables control the number and the speed of electrons towards the battery positive, respectively. The battery terminals are represented as "electron-source" and "electron-sink" in the user interface of the models. The function of this variable is to stop the model once a certain number of electrons reach the battery positive, and a "monitor" displays the "time taken to fill the electron-sink". Electric current can be thought of as the how fast the electron-sink is filling up.

THINGS TO NOTICE

Note that the number of free electrons inside the wire is always constant throughout a run. Given that electrons are constantly being lost to the battery-positive, how do you think this constancy is maintained in the model?

THINGS TO TRY

For any given value of the "maximum filling capacity" of the electron-sink, find two different sets of values of the "Number" and "Speed" of electrons for which the time taken to fill the electron-sink is identical.

EXTENDING THE MODEL

Can you alter the speed of electrons towards the battery-positive by creating obstacles in its way within the wire?

NETLOGO FEATURES

Electrons wrap around the world only vertically.

RELATED MODELS

Current in a Wire, Series Circuit, Parallel Circuit.

CREDITS AND REFERENCES

This model is a part of the NIELS curriculum. The NIELS curriculum has been and is currently under development at Northwestern's Center for Connected Learning and Computer-Based Modeling and the Mind, Matter and Media Lab at Vanderbilt University. For more information about the NIELS curriculum please refer to http://ccl.northwestern.edu/NIELS.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

Sengupta, P. and Wilensky, U. (2008). NetLogo Electron Sink model. http://ccl.northwestern.edu/netlogo/models/ElectronSink. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

To cite the NIELS curriculum as a whole, please use: Sengupta, P. and Wilensky, U. (2008). NetLogo NIELS curriculum. http://ccl.northwestern.edu/NIELS. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

To use this model for academic or commercial research, please contact Pratim Sengupta at mailto:pratim.sengupta@vanderbilt.edu or Uri Wilensky at uri@northwestern.edu for a mutual agreement prior to usage.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [electrons electron]
breed [buckets bucket]
globals [ current ]

to setup
  clear-all

  set current 1
  set-default-shape electrons "circle 2"

  ask patches
    [ set pcolor gray + 2 ]

  ;; negative terminal
  ask patches with [ pxcor > (max-pxcor - 14) ]
    [ set pcolor red ]
  ask patch (max-pxcor - 6) 0
    [ sprout 1 [ set shape "minus" set size 10 set color white ] ]

  ;; positive terminal
  ask patches with [pxcor < (min-pxcor + 14)]
    [ set pcolor black ]
  ask patch (min-pxcor + 6) 0
    [ sprout 1 [ set shape "plus" set size 10 set color white]]

  ;; create electrons
  ask n-of (number-of-electrons) patches with [pcolor = gray + 2]
    [ sprout-electron ]

  reset-ticks
end 

to sprout-electron  ;; patch procedure
  sprout-electrons 1
  [
    set color orange - 2  ;; dark orange
    set size 3
  ]
end 

;;;;;;;;;;;;;;;;;;;;;;;;
;; Runtime Procedures ;;
;;;;;;;;;;;;;;;;;;;;;;;;

to go
  tick

  ask electrons
  [
    set heading 270
    fd speed-of-electrons
    rt random 360
    fd 0.5
  ]

  ask electrons with [pcolor = black]
  [
    hatch-electrons 1
    [
      set color orange - 2  ;; dark orange
      set size 3
      setxy max-pxcor - 10 ycor
    ]
    set current current + 1
    die
  ]

  if current >= Filling-Capacity
  [
    user-message (word "The Sink Is Full; Time Taken to Fill = " ticks " isecs ")
    stop
  ]
end 


; Copyright 2008 Pratim Sengupta and Uri Wilensky.
; See Info tab for full copyright and license.

There are 9 versions of this model.

Uploaded by	When	Description	Download
Uri Wilensky	over 11 years ago	Updated to NetLogo 5.0.4	Download this version
Uri Wilensky	about 12 years ago	Updated version tag	Download this version
Uri Wilensky	about 12 years ago	Updated to version from NetLogo 5.0.3 distribution	Download this version
Uri Wilensky	almost 13 years ago	Updated to NetLogo 5.0	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Model from NetLogo distribution	Download this version

Attached files

File	Type	Description	Last updated
Electron Sink.png	preview	Preview for 'Electron Sink'	over 11 years ago, by Uri Wilensky	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo