Knowledge Acquisition Through Conversation

1 collaborator

Noah Conley (Author)

WHAT IS IT?

This model demonstrates my theory for the accumulation of knowledge through conversation. The idea is that people gain knowledge when they listen, and don't when they don't listen, as in they are either talking or walking around. If they are talking to someone they are similar to, they will be more interested in talking, but will learn less from the conversation. If they are talking to someone they are not very similar to, they will be less interested in talking, but will learn more from the conversation. Accordently, they will have a longer attention span and space out for a shorter period of time with someone more similar, and vice versa for someone less similar. After a certain period when no one has spoken, they will part ways and find someone new to talk to.

HOW IT WORKS

Turtles move randomly. When they encounter another walking turtle, they start a conversation. Only one turtle can be talking at a time, but both can be listening. While one turtle talks, the other turtle "gains" knowledge, but "loses" attention, until they space out for a short duration. During this time, they don't "gain" any knowledge. After the period is over, they begin learning again, and their focus is reset. If no one is talking for long enough that one of the turtles loses focus, they both go back to walking.

PROPOSAL FOR A REAL WORLD EXPERIMENT

My dream team would be Drs. Sid Horton, Galen Bodenhausen, and Jennifer Lackey. Dr. Horton has done research in memory process of language production and how character intimacy influences the processing of metaphoric utterances. This would benefit the project because it would be a good way of indicating interest similarity and conversation flow. Two people with similar interests will be more capable of holding an interlocuter-rich conversation. Dr. Bodenhausen has studied how stereotypes affects attention and memory. This would be a good angle because it would analyze how interest similarity affects attention span, knowledge acquisition, and memory retrieval. Dr. Lackey is interested in knowledge acquisition through language, and has written an article about testimony as a source of knowledge. Her expertise would shed light on how much people actually learn from conversation, especially if they have little pre-existing knowledge in the other person's interests. This model doesn't have a specific experimental structure. One possible experiment would be similar to the "interest-variation" chooser. In other words, gather four test groups, one with people from a very specific field, such as neuroscience, one with a slightly larger range, such as neuroscience, linguistics, and biology, one with an even larger field, such as all of cognitive science, and one with a very large field, such as Weinberg. Subjects can have a conversation with only one person at a time, and it has to be about their own field and the field of the other person. When neither person has anything more to say for a period of time, they end the conversation and move on to someone else. The experimenters observe the conversations and make note of how interested the subjects seem, how long each person is talking, how long the pauses between dialogue are, and if a person appears to lose focus briefly. At the end, subjects can evaluate how much they learned in each conversation and how interested they were in the other person's field of interest. The experimenters would compare their observations with the reports given by the subjects to get an idea of how interest and knowledge acquisition are related. This is by no means a perfect study, there are many flaws and sources of error, but I think it would be an interesting experiment if someone with experience in research methodology and design were to write out a proposal and experiment design.

HOW TO USE IT

Use the sliders to adjust the population, average attention span, and average space out duration, and the drop down menu to change the variance in interests of the turtles. Average attention span and space out duration can be changed while the program is running.

THINGS TO NOTICE

Notice the length of a conversation based on how similar the turtles are and how long they pay attention for. Notice how sometimes the knowledge counters go up together, and sometimes one goes up much more than the other.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  current-population
]

turtles-own [
  personal-interest
  interest-level
  attention-span
  thought-size
  knowledge-counter
  conversing-with
  current-action
  space-out-duration
]

to setup
    ca
    reset-ticks
    set current-population population
    crt population [
      setxy random-xcor random-ycor
      set shape "person"
      set size 2
      if (interest-variation = "none") [ set color 75 ]
      if (interest-variation = "small") [ set color 75 + (random 5 * -1 ^ random 2) ]
      if (interest-variation = "medium") [ set color 75 + (random 3 * 10 * -1 ^ random 2) + (random 5 * -1 ^ random 2) ]
      if (interest-variation = "large") [ set color 75 + (random 5 * 10 * -1 ^ random 2) + (random 5 * -1 ^ random 2) ]
      set knowledge-counter 0
      set interest-level 0
      set label knowledge-counter
      set current-action "walking"
      set attention-span 0
      set personal-interest color
    ]
end 

to go
  ask turtles [
    ifelse (current-action = "walking") [
      move
      check-location
    ] [
      ifelse (current-action = "talking")
      [ talk ] [listen]
    ]
  ]
  tick
end 

; turtle methods

to move
  rt random-float 90 * -1 ^ random 2
  fd 1
end 

to check-location
  if (count other turtles-here with [current-action = "walking"] > 0) [
    create-link-with one-of other turtles-here with [current-action = "walking"]
    set current-action "talking"
    face one-of link-neighbors
    set conversing-with [who] of one-of link-neighbors
    set-interest-level
    set-thought-size
    ask link-neighbors [
      set current-action "listening"
      set conversing-with [who] of myself
      face myself
      set-interest-level
      set-attention-span
    ]
  ]
end 

to talk
  set thought-size (thought-size - 1)
  if (thought-size <= 0) [
    set current-action "listening"
    set-attention-span
  ]
end 

to listen
  ifelse (attention-span > 0) [
    set attention-span (attention-span - 1)
    if ([current-action] of one-of link-neighbors = "talking") [ 
      set knowledge-counter (knowledge-counter + (1 - interest-level))
      set label precision knowledge-counter 2
    ]
    if (attention-span <= 0) [ set-space-out-duration ]
  ] [
    set space-out-duration (space-out-duration - 1)
    if (space-out-duration <= 0) [ set-attention-span ]
  ]
  if ([current-action] of one-of link-neighbors = "listening") [
    ifelse (attention-span = 0) [
      set current-action "walking"
      rt 180
      fd 2
      ask one-of link-neighbors [
        set current-action "walking"
        rt 180
        fd 2
        ]
      ask my-links [ die ]
    ] [
      set-thought-size
      if (thought-size > 10) [ set current-action "talking" ]
    ]
  ]
end 

; set methods

to set-thought-size
  set thought-size random 300 * interest-level
end 

to set-interest-level
  let difference abs (personal-interest - ([personal-interest] of one-of link-neighbors))
  ifelse (difference = 0)
  [ set interest-level .9 ] [
    ifelse (difference = 1)
    [ set interest-level .7 ]
    [ set interest-level 1 / difference ]
  ]
end 

to set-attention-span
  set attention-span (average-attention-span + random 6 * -1 ^ random 2) + (average-attention-span * interest-level)
end 

to set-space-out-duration
  set space-out-duration (average-space-out-duration + random 6 * -1 ^ random 2) + (average-space-out-duration * interest-level)
end

There is only one version of this model, created almost 12 years ago by Noah Conley.

Attached files

File	Type	Description	Last updated
Knowledge Acquisition Through Conversation.png	preview	Preview for 'Knowledge Acquisition Through Conversation'	almost 12 years ago, by Noah Conley	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo