HIV dynamics: cellular automata approach correction

; states
; T  healthy
; A1 infected stage 1
; A2 infected stage 2
; D  dead

globals [
  T A1 A2 D  ; status colors
]

patches-own [ nA1 nA2 time ]

to setup
  clear-all

  set T green
  set A1 orange
  set A2 red
  set D black

  ask patches [
    set pcolor T
    set time 0
  ]
  ask n-of (Phiv * max-pxcor * max-pycor) patches [
    set pcolor A1
  ]

  reset-ticks
end 

to-report rule1  ; T - initial healthy state
  if nA1 >= 1 or nA2 >= R [
    report A1
  ]
  report T
end 

to-report rule2  ; A1
  if time >= tao [
    report A2
  ]
  report A1
end 

to-report rule3  ; A2
  report D
end 

to-report rule4  ; D
  if random-float 1 < Prepl [
    if random-float 1 < Pinf [
      report A1
    ]
    report T
  ]
  report D
end 

to update
  ask patches [
    let N neighbors
    set nA1 count N with [ pcolor = A1 ]
    set nA2 count N with [ pcolor = A2 ]
  ]

  ask patches [
    let ncolor pcolor
    ifelse pcolor = T  [set ncolor rule1][
    ifelse pcolor = A1 [set ncolor rule2][
    ifelse pcolor = A2 [set ncolor rule3][
    ifelse pcolor = D  [set ncolor rule4][
    ]]]]

    ifelse ncolor != pcolor [
      set pcolor ncolor
      set time 0
    ][
    set time time + 1
    ]
  ]
  tick
end