Initial Setup and Population Reproduction Problem

turtles-own
 [
  age                                     ; how many years (ticks) old the turtle is ?
  male?                                   ; turtle's gender
 ] 

to setup
  clear-all
  setup-turtles
  reset-ticks  
end 

to setup-turtles
  set-default-shape turtles "person"
  create-turtles people
    [ setxy random-pxcor random-pycor
      
      ; IF asked, set the 'uniform' age distrubution as initial one; ELSE set the CZE (2011) population age distribution
      ifelse ( age-distribution = "uniform" )
      [ set age random 100 ]
      [
      ; Set the age distribution of agents following the Czech Population Census (2011) 5yrs age-group data: 
      let coinA random-float 100
      let coinB random 5
        ifelse (coinA < 4.8 )
              [ set age coinB ][ 
        ifelse (coinA < 9.5 )
              [ set age (coinB + 5) ][
        ifelse (coinA < 14.3 )
              [ set age (coinB + 10) ][
        ifelse (coinA < 19.9 )
              [ set age (coinB + 15) ][
        ifelse (coinA < 26.3 )
              [ set age (coinB + 20) ][
        ifelse (coinA < 33.2 )
              [ set age (coinB + 25) ][
        ifelse (coinA < 41.6 )
              [ set age (coinB + 30) ][
        ifelse (coinA < 50.1 )
              [ set age (coinB + 35) ][
        ifelse (coinA < 56.8 )
              [ set age (coinB + 40) ][
        ifelse (coinA < 63.5 )
              [ set age (coinB + 45) ][
        ifelse (coinA < 69.8 )
              [ set age (coinB + 50) ][
        ifelse (coinA < 77.0 )
              [ set age (coinB + 55) ][
        ifelse (coinA < 84.2 )
              [ set age (coinB + 60) ][
        ifelse (coinA < 89.6 )
              [ set age (coinB + 65) ][
        ifelse (coinA < 93.3 )
              [ set age (coinB + 70) ][
        ifelse (coinA < 96.5 )
              [ set age (coinB + 75) ][
        ifelse (coinA < 98.5 )
              [ set age (coinB + 80) ][
        ifelse (coinA < 99.7 )
              [ set age (coinB + 85) ]
              [ set age (coinB + 90) ]
              ]]]]]]]]]]]]]]]]]
      ]                               ; end of 'set turtles age distribution' procedures
      
      ; Set turtles gender distribution and corresponding color:
      let coinC random 100 
        ifelse (coinC < %males )
              [ set male? true set color blue ]
              [ set male? false set color red  ]
      
      ; Set turtles size
      set size 1
     ]
end 

;;;
;;; GO PROCEDURES
;;;

to go
   ask turtles [ 
   move                               ; turtles move randomly within their world
   get-older                          ; turtles age every tick (year)
     if ( reproduce? ) [ reproduce ]  ; turtles reproduce in the given age
   ]                                  ; end of 'go' procedures 
   tick
end 


; Turtles move randomly from one patch to another:

to move                               ; turtle procedure
   rt random-float 360
   forward 1
end 


; Turtles get older each year (tick) by one year

to get-older                          ; turtle procedure
   ifelse ( die? )                    ; if turtle reaches the given age, it dies
   [ die ]
   [ set age ( age + 1 ) ]
end 

to-report die?                        ; turtle dies at the age of 'lifespan'
report ( age >= lifespan )
end 


; All turtles reproduce as they reach the given age:

to reproduce
   let coinD random-float 1
   hatch 1 [                          
     ifelse ( coinD < %males / 100 )             ; new turtle 'gender' probability by birth (defined by initial global variable before the 'setup')
     [ set age 0 set male? true set color blue ]
     [ set age 0 set male? false set color red ] 
  ]
end 

to-report reproduce?                  ; turtle reproduces at the age of 'mean age at childbirth'
report age = mean-age-at-childbirth
end 


;;;
;;; MONITOR PROCEDURES
;;;

; All monitors are defined on the Interface tab