Bacterial Rock Paper Scissors

1 collaborator

WHAT IS IT?

Some bacterial cultures have shown a rock-paper-scissors like interaction among colicin- sensitive, producing, and resistant strains (Kirkup & Riley, 2004). Colicin-sensitive strains sometimes mutate into colicin producing strains, which create an environment in which sensitives can't survive. But the cost of producing colicin is high and non-producing resistant bacteria outcompete the producers. Once the producers are at a low-enough level, the sensitive strains will outcompete resistant trains and become dominant begining the cycle over again.

HOW IT WORKS

Three strains of bateria are modeled in the environment. Bacteria reproduce until reaching carrying capacity. There is a 1% chance that sensitives will mutate into producers, producers into resistants, and resistants into sensitives. Sensitives can't survive if the level of colicin exceeds a limit (parameterized) and each strain has a configurable "fecundity" to reflect the relative likelihood of each strain to divide each cycle. By default, the sensitives have the highest fecundity, followed by resistants, and producers lowest of all.

HOW TO USE IT

The "setup" button clears the environment and adds 20 sensitive bateria to seed the environment.

The "go" button runs the simulation.

The "limit" represents the level of colicin the sensitive bateria can survive.

The "carrying capacity" represents the total size the population is allowed to reach -- after this point, the bateria are removed randomly to remain at this level.

Each strain of bacteria has a "fecundity" value, which represents the likelihood that each bacterium will reproduce.

THINGS TO NOTICE

Why do some strains dominate for longer periods of time than others? What determines the slopes of the lines of relative population growth when strains are competing?

THINGS TO TRY

Under what conditions will the model reach steady state?

EXTENDING THE MODEL

Some other parameters that could be explored include: the rates at which colicin is produced and broken down in the environment; the rates of mutation;

CREDITS AND REFERENCES

Kirkup, B.C. and Riley, M.A. 2004. Antibiotic-mediated antagonism leads to a bacterial game of rock-paper-scissors in vivo. Nature 428: 412-414.

Wilensky, U. (1997). NetLogo Slime model. http://ccl.northwestern.edu/netlogo/models/Slime. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Some parts adapted from Netlogo Slime model (Wilensky, 1997).

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [sensitives sensitive] 
breed [resistants resistant]
breed [producers producer]


patches-own [colicin]

to setup
  set-default-shape turtles "dot"
  clear-all
  create-sensitives 20
  [ set color red
    set size 1  ;; easier to see
    setxy random-xcor random-ycor ]
  ask patches [ set colicin 0 ]
  reset-ticks
end  

to go
  ask sensitives
  [ 
    rt random-float 40 - random-float 40 + 10
    fd 3
        if colicin > limit [die]
        if random 100 < fecundity-s [
        ifelse random 100 < 1 [hatch-producers 1 [set color green] ] [hatch-sensitives 1 [set color red]]
        ]
  ]
  ask producers [
    set colicin colicin + 50
    rt random-float 40 - random-float 40 + 10
    fd 3
    if random 100 < fecundity-p [
        ifelse random 100 < 1 [hatch-resistants 1  [set color blue]] [hatch-producers 1 [set color green] ]
      ]
    ]                    ;; drop chemical onto patch
  ask resistants [
    rt random-float 40 - random-float 40 + 10
    fd 3
    if random 100 < fecundity-r [
        ifelse random 100 < 1 [hatch-sensitives 1 [set color red] ] [hatch-resistants 1 [set color blue] ]
      ]
  ]
  diffuse colicin 1                               ;; diffuse chemical to neighboring patches
  
  
  ask patches
  [ 
    set colicin colicin * 0.9                    ;; break down colicin
    set pcolor scale-color green colicin 10 100 ]  ;; update display of colicin concentration
  
  repeat count turtles - carrying-capacity [ask one-of turtles [die]] ;; impose carrying capacity
  
  plot-levels
  tick
end  

to plot-levels ;; this creates creates the bar graph 
    set-current-plot "Bacteria Concentrations"
    clear-plot
    set-current-plot-pen "S"
    plot-pen-down
    plotxy 1 count turtles with [breed = sensitives] 
    set-current-plot-pen "P"
    plot-pen-down
    plotxy 2 count turtles with [breed = producers] 
    set-current-plot-pen "R"
    plot-pen-down
    plotxy 3 count turtles with [breed = resistants] 
end

There is only one version of this model, created about 9 years ago by Steven Brewer.

Attached files

File	Type	Description	Last updated
Bacterial Rock Paper Scissors.png	preview	Preview for 'Bacterial Rock Paper Scissors'	about 9 years ago, by Steven Brewer	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo