Sex Ratio Equilibrium Extension 3

No preview image

1 collaborator

My_photo_2 Sugat Dabholkar (Author)

Tags

evolution 

Tagged by Sugat Dabholkar over 2 years ago

Model group MAM-2016 | Visible to everyone | Changeable by everyone
Model was written in NetLogo 6.0-M5 • Viewed 169 times • Downloaded 11 times • Run 0 times
Download the 'Sex Ratio Equilibrium Extension 3' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


## WHAT IS IT

This is the third extension in a series of NetLogo models about population dynamics, population genetics and evolutionary biology developed by Sugat Dabholkar for the Designing & Constructing Models With Multi-Agent Languages, a course offered by Prof. Uri Wilensky at the School of Education and Social Policy in the Northwestern University.

This is an extension of the model Sex Ratio Equilibrium, where the core phenomenon that is modeled is the sex-ratio equilibrium in sexually reproducing organisms. Most of the sexually reproducing organisms have sex-ratio 1:1. Fisher (1930) explained the rational based on natural selection, irrespective of particular mechanism of sex-determination, which is known as Fisher’s first principle (Hamilton, 1967).

This extension allows understanding impact of sex-role reversal on stability of populations with extraordinary sex-ratios (Liker et al., Nature, 2013).

## HOW IT WORKS

This is a population dynamics model, where individuals mate, give birth, die. The demographics changes in the population and sex ratio are captured in the model.

There are two types of individuals in the model:

Males (Indicated by green color)

Females (Indicated by blue color if not carrying a child and indicated by orange color if carrying a child)

At every time-step the individuals:

Age and check if dead - probability of dying increases with age

Move

Search-a-partner – (Only males). This procedure involves mating, which is dependent on mating-chance. If agents mate, the female carries. (For simplicity, mating chance incorporate conception-chance as well.)

Reproduce – (Only for females)

Rare-children – (Females or Males, depending on ROLE-REVERSAL? Is ON or not.)

Each male and female carries a trait called male-child-chance. This determines the probability of a child being male. In this extension, weighted influence of parents on the determination of the sex of child can be set using a slider.

A child inherits this trait, male-child-chance from its parents with a mutation. The mutation is implemented by choosing the value for the trait from a random-normal distribution with mean equal to weighted average of male-child-chance of the parents.

These two weights can be set separately.

## HOW TO USE IT

Click the SETUP button to set up the population.

You can use sliders to choose the following parameters when you SETUP.

INI-NUMBER : initial number of individuals in the population.

INI-SEX-RATIO : initial female-proportion in the population

INI-AVERAGE-MALE-CHILD-CHANCE : initial average male child chance of all the individuals in the population

GESTATION-PERIOD : number of 'ticks' a female is going to carry a child

MAX-LITTER-SIZE : maximum number of children a female would give birth to after she completes gestation

REPRODUCTIVE-MATURITY-AGE: the age after which an individual can mate to produce offspring

LONGEVITY : maximum 'ticks' an individual lives

MATING-CHANCE : probability that a female mates with a male when a male finds a female partner

CHILD-REARING-PERIOD: time spent by a parent to rear children

SEX-DETERMINATION-WEIGHT: This slider determines the influence on sex determination of a child by its parents. 0 means the sex determination of a child is fully influenced by the mother and 1 means the sex determination of a child is fully influenced by the father.

INHERITANCE-WEIGHT: This slider determines influence on inheritance of the child sex-determination trait to the offspring.

ROLE-REVERSAL? A Boolean when on the sex-role of child rearing is reversed, i.e. males rare children.

Click the GO button to start the simulation.

## THINGS TO NOTICE

When you run the model, notice how changes in the SEX-DETERMINATION-WEIGHT and INHERITANCE-WEIGHT sliders result in evolution of different sex-ratios. Changes in INHERITANCE-WEIGHT has significant impact on the stable sex-ratios, whereas changes in SEX-DETERMINATION-WEIGHT has little impact on the stable sex-ratios.

Also notice that extreme values if the INHERITANCE-WEIGHT result in unstable population.

Sex-role reversal results in increasing population stability in case of high INHERITANCE-WEIGHT values.

## THINGS TO TRY

Change the other parameters and see if you can get to a stable extraordinary sex ratio for extreme values of INHERITANCE-WEIGHT, when ROLE-REVERSAL? Is ON and when it’s OFF.

## EXTENDING THE MODEL

This model implements search of partner by a male, see if you can change it and make it a female action. You can add a variety of features related to evolutionary population genetics and sex ratio equilibrium studies, such as different mortality rates for males and females, sexual selection by females.

## RELATED MODELS

Red Queen, Fish Tank Genetic Drift, Plant Speciation

## CREDITS AND REFERENCES

Hamilton, W. D. (1967). Extraordinary sex ratios. Science, 156(3774), 477-488

Fisher, R. A. (1930). The genetical theory of natural selection: a complete variorum edition. Oxford University Press.

Liker, A., Freckleton, R. P., & Székely, T. (2013). The evolution of sex roles in birds is related to adult sex ratio. Nature communications, 4, 1587.

## COPYRIGHT AND LICENSE

Copyright 2006 Uri Wilensky.

![CC BY-NC-SA 3.0](http://ccl.northwestern.edu/images/creativecommons/byncsa.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  sex-ratio-list  ;; global-variable to track time-series data (for behavior space experiment)
  ]
breed [males male]
breed [females female]
;;
females-own [
  partner
  carrying?                 ;;  a boolean to track if a female is carrying a child after mating
  male-child-chance         ;; this is a probability of giving birth to a male child
  temp-male-child-chance    ;; a variable to store male-chind-chance for a particular father-mother pair
  child-male-child-chance   ;; it is the inherited male-child-chance by a child
  gestation                 ;; a veriable to track time of carrying a child till a female reaches gesatation-period
  age
  rearing?                  ;; a boolean to track if a female is rearing a child after giving birth, she can't mate if she is rearing
  child-rearing             ;; a veriable to track time of rearing a child till a female reaches child-rearing-period
]

males-own [
  partner
  male-child-chance
  child-male-child-chance
  age
  rearing?                   ;; a boolean to track if a female is rearing a child after giving birth, she can't mate if she is rearing
  child-rearing              ;; a veriable to track time of rearing a child till a female reaches child-rearing-period
]

;;set-up pupulation of males and females

to setup
  ca
  create-males round ( ( 1 - ini-sex-ratio ) * ini-number ) [
    setxy random-xcor random-ycor
    set shape "male"
    set color green
    set male-child-chance random-normal ini-average-male-child-chance 0.1     ;; males are assinged initial male-child-chance from a random-normal distribution
    set age 0
    set partner nobody
    set rearing? false
  ]
  create-females round ( ini-sex-ratio * ini-number ) [
    setxy random-xcor random-ycor
    set color blue
    set shape "female"
    set carrying? false
    set partner nobody
    set rearing? false
    set male-child-chance random-normal ini-average-male-child-chance 0.1    ;; females are assinged initial male-child-chance from a random-normal distribution
  ]
  set sex-ratio-list []
  reset-ticks
end 

to go
  if ticks = 15000 [stop]
  if not any? turtles [stop]
  ask males [
    check-if-dead
    if not rearing? and age > reproductive-maturity-age [move]
    search-a-partner
    if role-reversal? [child-rear]
  ]
  ask females [
    check-if-dead
    if not carrying? and not rearing? and age > reproductive-maturity-age [move]
    reproduce
    if not role-reversal? [child-rear]
  ]
  update-sex-ratio-list
  tick
end 

to move
    rt random 60
    lt random 60
    fd 1
end 

to search-a-partner  ;; male procedure
  if age > reproductive-maturity-age [             ;; males find partners only after they are mature to reproduce
  ifelse role-reversal? [                          ;; in case of role-reversal males rear children
    if partner = nobody and count females in-radius 1 = 1 and count females in-radius 1 with [not carrying? and age > reproductive-maturity-age ] = 1 and count other males in-radius 1 = 0  [  ;; spatial restriction is used to incorporate density-dependant growth rate
      set partner one-of females in-radius 1 with [not carrying? and age > reproductive-maturity-age]
    ]
  ]
  [
    if partner = nobody and count females in-radius 1 = 1 and count females in-radius 1 with [not carrying? and not rearing? and age > reproductive-maturity-age] = 1 and count other males in-radius 1 = 0  [
      set partner one-of females in-radius 1 with [not carrying? and not rearing? and age > reproductive-maturity-age]
    ]
  ]
  if partner = nobody [stop]
    ifelse [partner] of partner != nobody [
      set partner nobody
      stop                        ;; just in case two males find the same partner
    ]
    [
      ifelse random-float 1 < mating-chance [
        ask partner [
          set partner myself
          set carrying? true
          set color orange    ;; color oragne indicates carrying female
          set child-male-child-chance ( ( 1 - inheritance-weight ) * male-child-chance ) +  ( inheritance-weight * ( [male-child-chance] of myself ) )         ;; this is inherited male-child-chance by a child (determined by father and mother according to inheritance-weight)
          set temp-male-child-chance ( ( 1 - sex-determination-weight ) * male-child-chance ) +  ( sex-determination-weight * ( [male-child-chance] of myself ) )   ;; sex of a child is determined by male-child-chance (determined by father and mother according to sex-determination-weight)
        ]
        ifelse role-reversal? [
          set rearing? true           ;; in case of role-reversal, males have rearing role from the time they find a partner to the rearing-period for the childern is over
        ]
        [
          set partner nobody
        ]
      ]
      [
        set partner nobody
      ]
    ]
  ]
end 

to reproduce ;; female procedure
    if carrying? [
      ifelse gestation = gestation-period [   ;; genstation-period can be set. When it's over, a female gives birth to a a child, starts afrest and can have a new partner
        set gestation 0
        set carrying? false
        ifelse role-reversal? [
          set partner nobody
        ]
        [
          set rearing? true
        ]
        set color blue
        repeat random max-litter-size + 1 [
          ifelse random-float 1 < temp-male-child-chance [    ;; sex of a child is determined by male-child-chance
            hatch 1 [
              set breed males
              set shape "male"
              set color green
              set male-child-chance random-normal child-male-child-chance 0.1
              set age 0
              set rearing? false
              set partner nobody
              set heading random 360
              fd 1
            ]
          ][
          hatch 1 [
            set male-child-chance random-normal child-male-child-chance  0.1
            set age 0
            set rearing? false
            set partner nobody
            set heading random 360
            fd 1
          ]
          ]
        ]
      ][
      set gestation gestation + 1
      ]
    ]
end 

to child-rear
  if rearing? [
    ifelse child-rearing = child-rearing-period [
      set child-rearing 0
      set rearing? false
      set partner nobody
    ]
    [
      set child-rearing child-rearing + 1
    ]
  ]
end 

to check-if-dead
    ifelse random-float longevity < age [
      die
    ][
    set age age + 1
    ]
end 

;; reporting procedures for plotting and for behaviorspace experiments

to-report female-percentage
  ifelse any? turtles [
    report ( count females / count turtles ) * 100
  ]
  [
    report 0
  ]
end 

to-report average-male-child-chance
  ifelse any? males [
    report mean [male-child-chance] of males
  ]
  [
    report 0
  ]
end 

to update-sex-ratio-list
  if ticks > 10000 [
    set sex-ratio-list lput female-percentage sex-ratio-list
  ]
end 

to-report average-sex-ratio
    ifelse length sex-ratio-list > 0 [
    report precision mean sex-ratio-list 2]
    [report 0]
end 

to-report sd-sex-ratio
    ifelse length sex-ratio-list > 0 [
    report precision standard-deviation sex-ratio-list 2]
    [report 0]
end 

There is only one version of this model, created over 2 years ago by Sugat Dabholkar.

Attached files

No files

This model does not have any ancestors.

This model does not have any descendants.