Preharvest Produce Microbial Contamination Simulator

globals [num-sick run-number delay con-soil]

breed [sheep a-sheep]
breed [flies fly]
breed [plants plant]
turtles-own [energy infected? recover-count]
patches-own [countdown]
sheep-own [excreta-color]
;;;;;;;;;;;;;;;;;;;;;;;;;;;;setup;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to setup-clear
  clear-all
  set run-number 1
  setup-world
  setup-patches
  reset-ticks
end 

to setup-keep
  clear-turtles
  clear-patches
  set run-number (run-number + 1)
  setup-world
  setup-patches
  reset-ticks
end 

to setup-world
  set-default-shape sheep "sheep 2"
  create-sheep initial-number-sheep
  [
    set color white
    set excreta-color red
    set size 7
    setxy random-xcor random-ycor
    set infected? false
    set recover-count random 144 + 24
  ]

  set-default-shape flies "bug"
  create-flies initial-number-flies
  [
    set color black
    set size 0.5
    setxy random-xcor random-ycor
    set energy flies-initial-energy
    set infected? false
  ]

  set-default-shape plants "plant"
  create-plants Nx * Ny
  [
    set color green
    set size 3
    let i who - initial-number-sheep - initial-number-flies
    let x (i mod Nx)
    let y ((i - x) / Nx)
    setxy ((max-pxcor + 1) / (Nx)) * (x + 0.5)  ((max-pycor + 1) / (Ny)) * (y + 0.5)
    set energy plants-initial-energy
    set infected? false
    set recover-count random 24 + 168
  ]

  infect
  set con-soil count patches with [pcolor = (black + 1)]
  set num-sick 0
  set delay 0
  do-plots
end 

;;;;;;;;;;;;;;;;;;;;;setup-functions;;;;;;;;;;;;;;;;;;;;;;;

to infect
  ask one-of plants [
    ifelse ( Not any? plants with [ infected? = false ] )[
      print "All plants are infected!!"
      stop
    ][
      ifelse(infected? = false)[
        set infected? true
        plants-get-sick
      ][ infect ]
    ]
  ]
end 

to setup-patches
  ask patches[set pcolor brown]
end 

;;;;;;;;;;;;;;;;;;;;; go ;;;;;;;;;;;;;;;;;;;;;;; <-- Main

to go
  if ticks >= 1440 [stop]
  if (num-sick = count turtles) [ set delay (delay + 1) ]
  if (delay > 60) [ stop ]

  ask plants [
    ifelse(energy > 0)[
      ifelse(energy < plants-initial-energy)[
        set energy (energy * (1 + plants-reproduce / 100))
      ][ set energy plants-initial-energy ]
    ]
    [
      ifelse(recover-count <= 0)[
        set energy plants-initial-energy / 5
        set recover-count random 24 + 168
      ][ set recover-count (recover-count - 1) ]
    ]
  ]

  ask sheep [
    move-sheep
    eat-plants
    if(random 100 <= sheep-excretion-chance) [ set pcolor excreta-color ]
    if(infected? = true)[set recover-count (recover-count - 1)]
  ]

  ask flies [
    move-flies
    set energy (energy - 0.25)
    eat-excrement
    reproduce-flies
  ]
  ask patches [ recovery-soil ]

  plants-infection-check
  sheep-infection-check
  flies-infection-check

  flies-death
  set num-sick count turtles with [ infected? = true ]
  do-plots
  tick
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;; Functions ;;;;;;;;;;;;;;;;;;;;;;;;;;

to move-sheep
  rt random 80
  lt random 80
  fd 30
end 

to move-flies
  rt random 50
  lt random 50
  fd 5
end 

to eat-plants
  let prey one-of plants in-radius 2 with [energy > 0]
  if (prey != nobody) and (random 100 <= eat-chance) [
    ask prey [
      set energy -10
      if(energy < 0) [ set shape "plant small" ]
      if(infected? = true) and (random 100 <= infection-chance-from-plants)[
        ask sheep in-radius 2[ set infected? true ]
      ]
    ]
  ]
end 

to reproduce-flies
  if (random 100 <= flies-reproduce) and (energy > flies-initial-energy * 1.5) [
    set energy (energy / 2)
    hatch-flies 2 [
      rt random 360 fd 0.5
      set energy flies-initial-energy
    ]
  ]
end 

to eat-excrement
  if (any? patches in-radius 2)[
    ifelse (pcolor = red) [
      set pcolor orange
      set energy (energy + energy-from-red)
    ][
      ifelse (pcolor = orange) [
        set pcolor yellow
        set energy (energy + energy-from-orange)
      ][
        ifelse(pcolor = yellow) [
          set pcolor grey
          set energy (energy + energy-from-yellow)
        ][
          if(pcolor = violet) [
            set pcolor orange
            set energy (energy + energy-from-violet)

          ]
        ]
      ]
    ]
    if (any? patches in-radius 2 with [pcolor = violet or pcolor = (black + 1)]) and (random 1000 <= infection-chance-from-excreta) and (infected? = false)
    [set infected? true]
  ]
end 

to flies-death
  ask flies[ if(energy < 0) [ die ] ]
end 

to recovery-soil
  ifelse (pcolor = red) [
    set countdown excrement-recovery-red
    ifelse (countdown <= 0) [ set pcolor orange ][ set countdown (countdown - 1) ]
  ][
    ifelse (pcolor = orange) [
      set countdown excrement-recovery-orange
      ifelse (countdown <= 0) [ set pcolor yellow][ set countdown (countdown - 3) ]
    ][
       ifelse (pcolor = yellow) [
         set countdown excrement-recovery-orange
         ifelse (countdown <= 0) [set pcolor grey ][ set countdown (countdown - 5) ]
       ][
          ifelse (pcolor = grey) [
            ifelse (countdown <= 0) [ set pcolor brown ][ set countdown (countdown - 10) ]
          ][
             ifelse (pcolor = (black + 1)) [
               set countdown excrement-recovery-black
               ifelse (countdown <= 0) [ set pcolor sky ][ set countdown (countdown - 10) ]
            ][
               ifelse (pcolor = sky) [
                 set countdown excrement-recovery-sky
                 ifelse (countdown <= 0) [ set pcolor brown ][ set countdown (countdown - 10) ]
               ][
                 if (pcolor = violet) [
                   set countdown excrement-recovery-violet
                   ifelse (countdown <= 0) [ set pcolor orange ][ set countdown (countdown - 10) ]
                 ]
               ]
            ]
          ]
       ]
    ]
  ]
end 

to plants-get-sick
  set pcolor (black + 1)
  set color 57
  ifelse(energy > 0)[ set shape "plant sick" ][set shape "plant small"]
end 

to sheep-get-sick
  set shape "sheep 2 sick"
  set excreta-color violet
end 

to flies-get-sick
  set shape "bug sick"
end 

to plants-infection-check
  ask plants [
    if (any? flies in-radius 2 with [infected? = true]) and (random 1000 <= infection-chance-from-flies)[ set infected? true ]
    ifelse (infected? = true) [ plants-get-sick ]
    [
      set color green
      ifelse(energy > 0)[ set shape "plant"][ set shape "plant small" ]
    ]
  ]
end 

to sheep-infection-check
  ask sheep [
    ifelse (infected? = true) [
       sheep-get-sick
       if(recover-count <= 0)[
         set infected? false
         set excreta-color red
         set shape "sheep 2"
         set recover-count random 144 + 24
       ]
    ]
    [
      set excreta-color red
      set shape "sheep 2"
    ]
  ]
end 

to flies-infection-check
  ask flies
  [
    ifelse (infected? = true) [
      flies-get-sick
      if(random 100 <= fly-excretion-chance) [ set pcolor sky ]
    ]
    [set shape "bug"]
  ]
end 

to do-plots
  set-current-plot "soil contaminations"
  set-current-plot-pen "red"
  plot count patches with [pcolor = red]
  set-current-plot-pen "orange"
  plot count patches with [pcolor = orange]
  set-current-plot-pen "yellow"
  plot count patches with [pcolor = yellow]
  set-current-plot-pen "grey"
  plot count patches with [pcolor = grey]
  set-current-plot-pen "black"
  plot count patches with [pcolor = (black + 1)]
  set-current-plot-pen "sky"
  plot count patches with [pcolor = sky]
  set-current-plot-pen "violet"
  plot count patches with [pcolor = violet]
end