Deterministic SIR

;; System dynamics model globals
globals [
  R
  I
  S
  dt
]

;; Initializes the system dynamics model.
;; Call this in your model's SETUP procedure.

to setup
  ca
  set dt 0.001
  ;; initialize stock values
  set R 0
  set I I_0
  set S 1 - I_0
  reset-ticks
end 


;; ===========================================================================================
;; Step through the system dynamics model by performing next iteration of Euler's method.
;; Call this in your model's GO procedure.

to go
  if  ticks >= t_max  [ stop ]
  do-SIR-step
  do-plot
  tick-advance dt
end 

;; ===========================================================================================

to do-SIR-step
  let dS ( bd * (1 - vac) - transmission * S * I - bd * S )
  let dI ( transmission * S * I - recovery * I - bd * I )
  let dR ( bd * vac + recovery * I - bd * R )
  set S ( S + dS * dt )
  set I ( I + dI * dt )
  set R ( R + dR * dt )
end 


;; =========================================================================================
;; Plot the current state of the system dynamics model's stocks

to do-plot
  if plot-pen-exists? "R" [
    set-current-plot-pen "R"
    plotxy ticks R
  ]
  if plot-pen-exists? "I" [
    set-current-plot-pen "I"
    plotxy ticks I
  ]
  if plot-pen-exists? "S" [
    set-current-plot-pen "S"
    plotxy ticks S
  ]
end