Camada de Ozônio

globals [
  sky-top      ;; y coordinate of top row of sky
  earth-top    ;; y coordinate of top row of earth
  temperature  ;; overall temperature
  valor
]

breed [rays ray]     ;; packets of sunlight
breed [IRs IR]       ;; packets of infrared radiation
breed [heats heat]   ;; packets of heat energy
breed [clouds cloud]
clouds-own [cloud-speed cloud-id]

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================

breed [CFCs CFC];;DECLARAÇÃO DO GAS CFC NO MODELO
breed [suns sun] ;;DECLARAÇÃO DO SOL NO MODELO
suns-own [sun-speed];;DECLARAÇÃO DA VELOCIDADE DO SOL NO MODELO
breed [factories factory];;DECLARAÇÃO DAS FÁBRICAS DO MODELO
breed [ozones ozone] ;;DECLARAÇÃO DAS MOLÉCULAS DE OZONIO
breed [houses house] ;;DECLARAÇÃO DAS CASAS DO MODELO
ozones-own [ozone-speed] ;; DECLARAÇÃO DA VELOCIDADE DAS MOLÉCULAS NO MODELO

;=====================================================================


;;
;; Setup Procedures
;;

to setup
  clear-all
  set-default-shape rays "ray"
  set-default-shape IRs "ray"
  set-default-shape clouds "cloud"
  set-default-shape heats "dot"
  ;set-default-shape CO2s "CO2-molecule"
  setup-world
  set temperature 12
  reset-ticks
;================== MODIFICAÇÃO NO MODELO ORIGINAL====================
  set-default-shape CFCs "co2-molecule" ;;CHAMADA DA MOLÉCULA DO GÁS CFC
  set-default-shape suns "sun";;CHAMADA DO SOL NO MODELO PELO BOTÃO DE SETUP
  set-default-shape factories "factory" ;; CHAMADO DAS FÁBRICAS NO MODELO
  set-default-shape ozones "cfc-ozone" ;;CHAMADO DAS MOLÉCULAS DO GÁS OZONIO
  set-default-shape houses "house";;CHAMADO DAS CASAS NO MODELO
  set valor 0
;======================================================================
end 

to setup-world
  set sky-top max-pycor - 5
  set earth-top 0
  ask patches [  ;; set colors for the different sections of the world
    if pycor > sky-top [  ;; space
      set pcolor scale-color white pycor 22 15
    ]
    if pycor <= sky-top and pycor > earth-top [ ;; sky
      set pcolor scale-color blue pycor -20 20
    ]
    if pycor < earth-top
      [ set pcolor red + 3 ] ;; earth
    if pycor = earth-top ;; earth surface
      [ update-albedo ]
  ]

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================
create-suns 1
[
    set color yellow
    set size 4
    setxy (min-pxcor + 0.3) 20.5
    set heading 90
    set sun-speed 0.045
]
;; CÓDIGO QUE CRIA O SOL E ALTERA CONFIGURAÇÕES DESTE
;======================================================================
end 

;;
;; Runtime Procedures
;;

to go
  ask clouds [ fd cloud-speed ]  ; move clouds along
  run-sunshine   ;; step sunshine
  ;; if the albedo slider has moved update the color of the "earth surface" patches
  ask patches with [pycor = earth-top]
    [ update-albedo ]
  run-heat  ;; step heat
  run-IR    ;; step IR
  run-CFC   ;; MOVIMENTA AS MOLÉCULAS DE CFC
  tick

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================
;PEDE PARA AS FÁBRICAS EMITIREM CFC
   ask factories [
     emmit-factory
   ]

; PEDE PARA O SOL "CORRER" PELO AMBIENTE QUANDO PRESSIONADO O BOTÃO EXECUTAR
  ask suns [
    run-sun
  ]
;PEDE PARA AS PARTÍCULAS DE OZONIO ANDAREM PELO AMBIENTE
  ask ozones [
    run-ozone
  ]
  ;PEDE PARA AS CASAS DO AMBIENTE EMITAM PARTÍCULAS DE CFCs.

  ask houses [
    emmit-house
  ]

  ask cfcs [
      run-ozone
  ]
;========================= ============================================
end 


;================== MODIFICAÇÃO NO MODELO ORIGINAL====================

to run-sun
      fd sun-speed * 49 / 48

; CÓDIGO QUE DEFINE A VELOCIDADE DO QUAL O SOL PERCORRE O AMBIENTE
end 

to run-ozone
      fd .04
      ;let dist 12; + random-float 0.1
      ;fd dist
 ; CÓDIGO QUE DEFINE A VELOCIDADE DO QUAL AS PARTÍCULAS DE OZONIO PERCORREM O AMBIENTE
end 

;=====================================================================

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================

to emmit-factory
  if random 100 > 98 [
    hatch-CFCs 1 [
    set size 1
    set color red
  ]
]
end 

to emmit-house
  if random 100 > 80 [
    hatch-CFCs 1 [
    set size 1
    set color red
  ]
]
end 
;CÓDIGO QUE EMITE O GÁS CFC NA ATMOSFERA DO AMBIENTE
;====================================================================

to update-albedo ;; patch procedure
  set pcolor scale-color green albedo 0 1
end 

to add-cloud            ;; erase clouds and then create new ones, plus one
  let sky-height sky-top - earth-top
  ;; find a random altitude for the clouds but
  ;; make sure to keep it in the sky area
  let y earth-top + (random-float (sky-height - 4)) + 2
  ;; no clouds should have speed 0
  let speed (random-float 0.1) + 0.01
  let x random-xcor
  let id 0
  ;; we don't care what the cloud-id is as long as
  ;; all the turtles in this cluster have the same
  ;; id and it is unique among cloud clusters
  if any? clouds
  [ set id max [cloud-id] of clouds + 1 ]

  create-clouds 3 + random 20
  [
    set cloud-speed speed
    set cloud-id id
    ;; all the cloud turtles in each larger cloud should
    ;; be nearby but not directly on top of the others so
    ;; add a little wiggle room in the x and ycors
    setxy x + random 9 - 4
          ;; the clouds should generally be clustered around the
          ;; center with occasional larger variations
          y + 2.5 + random-float 2 - random-float 2
    set color white
    ;; varying size is also purely for visualization
    ;; since we're only doing patch-based collisions
    set size 2 + random 2
    set heading 90
  ]
end 

to run-sunshine
  ask rays [
    if not can-move? 0.3 [ die ]  ;; kill them off at the edge
    fd 0.3                        ;; otherwise keep moving
  ]
  create-sunshine  ;; start new sun rays from top
  reflect-rays-from-clouds  ;; check for reflection off clouds
  encounter-earth   ;; check for reflection off earth and absorption
end 

to create-sunshine
  ;; don't necessarily create a ray each tick
  ;; as brightness gets higher make more
  if 10 * sun-brightness > random 50 [
    create-rays 1 [
      set heading 160
      set color yellow
      ;; rays only come from a small area
      ;; near the top of the world
      setxy (random 10) + min-pxcor max-pycor
    ]
  ]
end 

to reflect-rays-from-clouds
 ask rays with [any? clouds-here] [   ;; if ray shares patch with a cloud
   set heading 180 - heading   ;; turn the ray around
 ]
end 

to encounter-earth
  ask rays with [ycor <= earth-top] [
    ;; depending on the albedo either
    ;; the earth absorbs the heat or reflects it
    ifelse 100 * albedo > random 100
      [ set heading 180 - heading  ] ;; reflect
      [ rt random 45 - random 45 ;; absorb into the earth
        set color red - 2 + random 4
        set breed heats ]
  ]
end 

to run-heat    ;; advances the heat energy turtles
  ;; the temperature is related to the number of heat turtles
  set temperature 0.99 * temperature + 0.01 * (12 + 0.1 * count heats)
  ask heats
  [
    let dist 0.5 * random-float 1
    ifelse can-move? dist
      [ fd dist ]
      [ set heading 180 - heading ] ;; if we're hitting the edge of the world, turn around
    if ycor >= earth-top [  ;; if heading back into sky
      ifelse temperature > 20 + random 40
              ;; heats only seep out of the earth from a small area
              ;; this makes the model look nice but it also contributes
              ;; to the rate at which heat can be lost
              and xcor > 0 and xcor < max-pxcor - 8
        [ set breed IRs                    ;; let some escape as IR
          set heading 20
          set color magenta ]
        [ set heading 100 + random 160 ] ;; return them to earth
    ]
  ]
end 

to run-IR
  ask IRs [
    if not can-move? 0.3 [ die ]
    fd 0.3
    if ycor <= earth-top [   ;; convert to heat if we hit the earth's surface again
      set breed heats
      rt random 45
      lt random 45
      set color red - 2 + random 4
    ]
    ;if any? CO2s-here    ;; check for collision with CO2
    if any? CFCs-here    ;; CONFERIR A COLISÃO COM O GÁS CFC
      [ set heading 180 - heading ]
  ]
end 

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================

to run-CFC
  ask CFCs [
    rt random 51 - 25 ;; turn a bit
    let dist 0.05 + random-float 0.1
    ;; MANTÉM AS MOLÉCULAS DE CFC NA ÁREA DA ATMOSFÉRA DO AMBIENTE
    if [not shade-of? blue pcolor] of patch-ahead dist
      [ set heading 180 - heading ]
    fd dist ;; move forward a bit
  ]
end 

;=====================================================================

;================== MODIFICAÇÃO NO MODELO ORIGINAL====================

to add-factory
    create-factories 1 [
    set color red
    set size 3.5
       setxy random-xcor 1
  ]
end 
;CÓDIGO QUE ADICIONA AS FÁBRICAS NO AMBIENTE

to add-ozone
   create-ozones 1
    [
       set color 105
       set size 1.3
       setxy (min-pxcor + 1) 17
       set heading 90
    ]
end 
;CÓDIGO QUE ADICIONA AS MOLÉCULAS DE OZÔNIO NA CAMADA SUPERIOR DO AMBIENTE

to add-house
    create-houses 1 [
    set color green
    set size 1.5
       setxy random-xcor 1
  ]
end 
;CÓDIGO QUE ADICIONA AS CASAS NO AMBIENTE

;=====================================================================

to remove-factory ;; REMOVE UMA FÁBRICA POR VEZ
  repeat 1 [
    if any? factories [
      ask one-of factories [ die ]
    ]
  ]
end 

;CÓDIGO QUE REMOVE AS FÁBRICAS DO AMBIENTE

to remove-CFC ;; RANDOMICAMENTE REMOVE 25 MOLÉCULAS DE CFC
  repeat 25 [
    if any? CFCs [
      ask one-of CFCs [ die ]
    ]
  ]
end 
;CÓDIGO QUE REMOVE AS MOLÉCULAS DE CFC DO AMBIENTE

to remove-cloud
  if any? clouds [
    let doomed-id one-of remove-duplicates [cloud-id] of clouds
    ask clouds with [cloud-id = doomed-id]
      [ die ]
  ]
end 

to remove-ozone ;;
  repeat 1 [
    if any? ozones[
      ask one-of ozones [ die ]
    ]
  ]
end 
; CÓDIGO QUE REMOVE AS NUVENS DO AMBIENTE
;=======================================================================



; Copyright 2007 Uri Wilensky.
; See Info tab for full copyright and license.