Social Uses and Gratifications

patches-own
[
  sneed  ;; magnitude of current social need (0.00–1.00)
  run-tot-sneed ;; running total of social need to calculate average sneed for viz
  avail  ;; availability for social interaction (0.00-1.00, currently equal to sneed)
  total-soc ;; total of neighbors' availability * ix-social-grat
  social-interact? ;; T/F flag for whether a patch decides to consume media () or interact socially ()
  cnt-media ;; number of ticks on which patch decided to consume media
  cnt-soc ;; number of ticks on which patch decided to interact socially
  H ;; binary entropy function as a measure of consistency/variability in choice: higher H = more variable
]

to setup
  clear-all
  reset-ticks
  ask patches
  [ set sneed random-float 1
    set run-tot-sneed sneed
    set avail sneed
    set cnt-media 0
    set cnt-soc 0
    set H 0
  ]
  recolor-patch
end 

to go
  ;; increase social need
    increase-need
  ;; decide whether to consume media or socially interact
    decide-social
  ;; obtain social gratification
    social-grat
  ;; calculate entropy as a measure of variability of selection
    calc-H
  ;; recolor patches for visualization
    recolor-patch
  ;; advance time
    tick
end 

to recolor-patch  ;; patch procedure: visualize depending on selected visualization
  ask patches

  [ if Patch-display = "Current-need" ;; visualize current social need: white = least, black = most
    [ set pcolor scale-color red sneed 1 0 ]

    if Patch-display = "Choice-consistency" ;; visualize consistency of choice between media and social interaction over all ticks:
    [ ifelse cnt-media > cnt-soc            ;; white = 50:50 split, darker = most consistent, blue = favoring media, green = favoring social interaction
      [ set pcolor scale-color blue (H + .1) 0 1]
      [ set pcolor scale-color green (H + .1) 0 1]
      if cnt-media = cnt-soc
      [ set pcolor white ] ]

    if Patch-display = "Average-need" ;; visualize average social need over all ticks
    [ set pcolor scale-color red (run-tot-sneed / (ticks + 2)) 1 0 ]
  ]
end 

to increase-need ;; patch procedure: increase social need (sneed) up to a maximum of 1
  ask patches
  [ set sneed min list (sneed + random-float need-increase-max) 1 ;; random increase 0-(need-increase-max) (slider)
    set avail sneed ;; set availability for social interaction with neighbors equal to current social need
  ]
end 

to decide-social ;; patch procedure: decide whether to consume media or socially interact based on comparison of media to neighbors
  ask patches
  [ set total-soc min list ((sum [avail] of neighbors4) * ix-social-grat) 1 ;; calculate total social gratification of interacting with 4 neighbors assuming none consume media
    ifelse total-soc > media-social-grat ;; compare social gratification of neighbors to media social gratification
    [ set social-interact? 1 ]
    [ set social-interact? 0 ]
    ifelse social-interact? = 0 ;; if not socially interacting but consuming media, set availability for social interaction to 0
    [ set avail 0
      set cnt-media (cnt-media + 1) ]
    [ set cnt-soc (cnt-soc + 1) ]
  ]
end 

to social-grat ;; obtain social gratification (social need reduction) via social interaction or media consumption depending on choice in decide-social
  ask patches
  [ ifelse social-interact? = 1
    [ set sneed (sneed - ((sum [avail] of neighbors4) * ix-social-grat)) ]
    [ set sneed (sneed - media-social-grat) ]
    set sneed max list 0 sneed
    set run-tot-sneed (run-tot-sneed + sneed)
  ]
end 

to calc-H ;; binary entropy function as a measure of consistency/variability in choice: higher H = more variable
  ask patches
  [ let sum-cnt (cnt-soc + cnt-media)
    let p ( (max list cnt-soc cnt-media) / sum-cnt)
    ifelse p = 1
    [ set H 0 ]
    [ set H ( ( (-1 * p) * (log p 2) * p) - ((1 - p) * log (1 - p) 2)) ]
  ]
end