Ecology of Lyme 1

Ecology of Lyme 1 preview image

1 collaborator

Default-person Michael Zito (Author)

Tags

ecology 

Tagged by Michael Zito 4 months ago

lyme 

Tagged by Michael Zito 4 months ago

Visible to everyone | Changeable by the author
Model was written in NetLogo 6.1.0 • Viewed 56 times • Downloaded 0 times • Run 0 times
Download the 'Ecology of Lyme 1' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


Info tab cannot be displayed because of an encoding error

Comments and Questions

Click to Run Model

;;----- Agent types
breed [blticks bltick]
breed [mice mouse]
breed [squirrels squirrel]
breed [possums possum]
breed [chipmunks chipmunk]

blticks-own [infected? fed?]                                     ;; larval ticks feed once and may become carriers of Lyme as a result
mice-own [body-burden reservoir-competence host-quality]         ;; each species can carry Lyme and have a probability of transmitting Lyme
squirrels-own [body-burden reservoir-competence host-quality]
possums-own [body-burden reservoir-competence host-quality]
chipmunks-own [body-burden reservoir-competence host-quality]

to setup

  ca

  ;; color the patches
  ask patches [set pcolor 63]

  ;; intialize breeds and randomly distribute them in the world
  create-blticks larval-ticks [
    set shape "spider"
    set color black
    set size 0.5
    set infected? FALSE
    set fed? FALSE
    setxy random-xcor random-ycor
  ]

  create-mice mouse-density [
    set shape "mouse side"
    set color gray
    set size 2.5
    set body-burden 28
    set reservoir-competence 0.91
    set host-quality 0.493
    setxy random-xcor random-ycor
  ]

    create-squirrels squirrel-density [
    set shape "squirrel"
    set color gray
    set size 3
    set body-burden 142
    set reservoir-competence 0.02
    set host-quality 0.172
    setxy random-xcor random-ycor
  ]

    create-chipmunks chipmunk-density [
    set shape "chipmunk"
    set color brown
    set size 2.5
    set body-burden 36
    set reservoir-competence 0.57
    set host-quality 0.243
    setxy random-xcor random-ycor
  ]

    create-possums possum-density [
    set shape "possum"
    set color gray + 3
    set size 3
    set body-burden 254
    set reservoir-competence 0.03
    set host-quality 0.035
    setxy random-xcor random-ycor
  ]


  reset-ticks
end 

to go

  ;; stop when all ticks have fed
  ;if all? blticks [ fed? ] [ stop ]
  if ticks = 1000 [stop]
  ;; have each breed move at a different speed
  move

  ;; ticks will feed on a host if one is on the same patch
  ask blticks [feed]

  tick
end 

to move

  ;; all hosts move randomly around the world
  ask squirrels [
    left random 50
    right random 50
    repeat 8 [fd 0.1]
  ]

  ask mice [
    left random 50
    right random 50
    repeat 1 [fd 0.1]
  ]

   ask possums [
    left random 50
    right random 50
    repeat 6 [fd 0.1]
  ]

   ask chipmunks [
    left random 50
    right random 50
    repeat 2 [fd 0.1]
  ]
end 

to feed

    ;; define local variables
    let pInfected  0
    let pFed 0
    let burden 0

    ;;find a host, exclude other ticks
    let host one-of other turtles-here with [member? self blticks = FALSE ]

    ;; set local variables to the host's properties
    ;; for each feeding event if larva has not aready fed
    if host != nobody and not fed?[
      ask host [
        set pFed host-quality
        set pInfected reservoir-competence
        set burden body-burden
      ]

    ;; ticks feed once, molt, and become larger
    ;; survival is determined based on the host quality
    ;; infection status is determined based on the host's reservoir competence
      if random 254 <= burden [                       ;; is host below its body burden?
        ifelse random-float 1.0 <= pFed               ;; does host feed larva?
        [
          set fed? TRUE                               ;; feed
          set size size * 2                           ;; molt
            if random-float 1.0 <= pInfected          ;; did B.burgdorferi transfer?
            [
              set infected? TRUE                      ;; if so change infection status
              set color red                           ;; and color
            ]
        ]
        [ die ]                                       ;; else larva dies
      ]
    ]
end 

to-report DON

  report count blticks with [fed?]
end 

to-report DIN

  report count blticks with [infected?]
end 

to-report NIP

  report 100 * DIN / DON
end 

to reset

  ;;  resets model parameters to intial satate

  set larval-ticks 1000
  set mouse-density 40
  set squirrel-density 8
  set possum-density 1
  set chipmunk-density 20
end 

There are 4 versions of this model.

Uploaded by When Description Download
Michael Zito 4 months ago minor edits Download this version
Michael Zito 4 months ago updated info tab references Download this version
Michael Zito 4 months ago Removed extraneous variable Download this version
Michael Zito 4 months ago Initial upload Download this version

Attached files

File Type Description Last updated
Ecology of Lyme 1.png preview Preview for 'Ecology of Lyme 1' 4 months ago, by Michael Zito Download

This model does not have any ancestors.

This model does not have any descendants.