Noisy threshold-based contagion in a small world

globals
[
  num-infected
  infected-size
]

turtles-own
[
  infected?          ;; true if agent has been infected
]


;;;;;;;;;;;;;;;;;;;;;;;
;;; Main Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to complex-spread
    if all? turtles [infected?]
    [stop]
  ask turtles with [ infected? = true ]
  [
    ;; infect neighbors
      ask link-neighbors
      [
        if (( random-float 1 <= prob-spread-two ) and ((count link-neighbors with [infected? = true] > 1)
          or (count link-neighbors with [infected? = true] = 1 and random-float 1 <= prob-spread-one)))    ;; infect with probability p
        [
          if not infected?  ;; agents can be infected only once
          [
            set infected? true
             show-turtle
            set color yellow
            set size infected-size

            ;; color the link with the node doing the infection
            ask link-with myself [set color yellow show-link]
            ;; increment the total number of infected agents
          ]
        ]
      ]
  ]

  do-plotting
  set num-infected count turtles with [infected? = true]
  tick
end 

to spread
  ;; or if every agent has already been infected
  if all? turtles [infected?]
    [stop]
  ask turtles with [ infected? = true ]
  [
    ;; infect neighbors
      ask link-neighbors
      [
        if ( random-float 1 <= prob-infection )  ;; infect with probability p
        [
          if not infected?  ;; agents can be infected only once
          [
            set infected? true
             show-turtle
            set color yellow
            set size infected-size

            ;; color the link with the node doing the infection
            ask link-with myself [set color yellow show-link]
            ;; increment the total number of infected agents
          ]
        ]
      ]
    ]

  do-plotting
  set num-infected count turtles with [infected? = true]
  tick
end 

;;layout all nodes and links

to do-layout
  repeat 5 [layout-spring turtles links 0.2 4 0.9]
  display
end 



;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

to generate-topology
  ;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  clear-all
  set infected-size 4
  set-default-shape turtles "outlined circle"
  ;; setup small world topology
  create-turtles num-nodes
  create-lattice
  rewire-network

  setup
  reset-ticks
end 

to reinfect-two

  set infected-size 4
  ask turtles
    [reset-node]
  ask links
    [set color gray + 1.5]

  ;; infect a single agent
  ask one-of turtles
  [
    set infected? true
    set color yellow
    set size infected-size
    ask one-of link-neighbors [
          set infected? true
          set color yellow
          set size infected-size
    ]
  ]
  set num-infected 1

  ;; Layout turtles:
  layout-circle (sort turtles) max-pxcor - 8
  ;; space out turtles to see clustering
  ask turtles
  [
    facexy 0 0
    if who mod 2 = 0 [fd 4]
  ]
  display
end 

to setup

  set infected-size 4
  ask turtles
    [reset-node]
  ask links
    [set color gray + 1.5]

  ;; infect a single agent
  ask one-of turtles
  [
    set infected? true
    set color yellow
    set size infected-size
  ]
  set num-infected 1

  reinfect-two

  ;; Layout turtles:
  layout-circle (sort turtles) max-pxcor - 8
  ;; space out turtles to see clustering
  ask turtles
  [
    facexy 0 0
    if who mod 2 = 0 [fd 4]
  ]
  display
end 

to reset-node
    set color gray + 1.5
    set size 3
    set infected? false
end 


;; WARNING: the simplified rewiring algorithm does not certain checks (ie disconnected graph)
;; for large networksthis shouldn't be too much of an issue.

to rewire-network
  ask links
  [
    ;; whether to rewire it or not?
    if (random-float 1) < rewiring-probability
    [
      ask end1
      [
        create-link-with one-of other turtles with [not link-neighbor? myself ]
          [set color gray + 1.5]
      ]
      die
    ]
  ]
end 


;; creates a new lattice

to create-lattice
  ;; iterate over the nodes
  let n 0
  while [n < count turtles]
  [
    ;; make links with the next two neighbors
    ;; this makes a lattice with average degree of 4
    make-link-between turtle n
              turtle ((n + 1) mod count turtles)
    make-link-between turtle n
              turtle ((n + 2) mod count turtles)
    set n n + 1
  ]
end 


;; connects the two nodes

to make-link-between [node1 node2]
  ask node1 [
    create-link-with node2
      [ set color gray + 1.5]
  ]
end 

to-report pct-infected
  report 100 * (num-infected ) / (count turtles)
end 

;;;;;;;;;;;;;;;;
;;; Plotting ;;;
;;;;;;;;;;;;;;;;

to do-plotting
     ;; plot the number of infected individuals at each step
     set-current-plot "% infected"
     set-current-plot-pen "inf"

     let percent-inf 100 * (num-infected ) / (count turtles)
     plotxy ticks percent-inf
end