Pocket Mouse-Fitness

breed [mice mouse]
turtles-own [energy labeled order]

globals [x y   ;mouse position
         order-number    ;track labled mice order
         name-1  name-2 name-string
         watched]

to-report time-period
  report ticks / 40
end 

to setup
  clear-all
  setup-mice
  setup-patches
  reset-ticks
end 

to setup-mice
  create-mice Starting-Population-Size
  ask mice [
    set color 31 + random-float (Color-variation / 2)
    set shape "mouse side"
    set size 1.25
    setxy random-xcor random-ycor
    set labeled 0
    set order 0
    set energy 20]

    set order-number 0
end 

to setup-patches
  ask patches [set pcolor Environment-color]
end 

to go
  if years = 0 [user-message "Number of years is needed" stop]
  if ticks > years * 40 [stop]

  if color-heritable? = false [ask mice [set color 31 + random-float 7.5]]
  diff-survival
  move
  forage
  dead
  reproduce
  regrow
  if count mice = 0 [user-message "All mice have died."  Stop]
  tick
end 

to move
  ask mice [rt (random 180)
               fd 1
               set energy energy - 1]
end 

to dead
  ask mice [if energy <= 0 [die]]
end 

to forage
  ask mice [if pcolor = Environment-color [set energy (energy + Energy-gained) set pcolor pcolor - 0.75]]
end 

to reproduce
  ask mice [
    if energy >= 40
    [hatch 1
      [set energy 20
       if random 100 < Color-variation [set color ((color - 1) + random-float 2)]
        if color < 31 [set color 31]
        if color > 38.5 [set color 38.5]]
      set energy energy - 20
      ] ]
end 

to regrow
  ask patches with [pcolor != Environment-color] [set pcolor Environment-color]
end 

to diff-survival
    ask mice [
      if random 2500 < (abs (color - Environment-color) * Number-of-visual-predators * 0.3) [die]
    ]
end 

to pick-mice

  if count mice with [labeled = 1] >= 2 [user-message "Two mice have been labeled. Unlabel the mice first." stop]
  if any? mice = false [user-message "No mice here." stop]


  if mouse-inside? [
    if mouse-down? [
      let test-mouse min-one-of mice [distancexy mouse-xcor mouse-ycor]
      if test-mouse != nobody [
        ask test-mouse [if count mice with [labeled = 1] = 0 and label = "" [set label "A" set labeled 1]      ;label the 1st selected moues as "A"
                        if count mice with [labeled = 1] = 1 and label = "" [set label "B" set labeled 1]      ;label the 1st selected moues as "B"
        ]
  ]]]



  if count mice with [labeled = 1] >= 2 [stop]   ;disable the button when two mice are labelled.
end