Infectious Disease Outbreak (COVID-19)

;;
;; This model is developed by Dr. Lin Xiang at the University of Kentucky. Contact: lin.xiang@uky.edu
;;
;; If you see this page rather than a "download" button when downloading the model, click the "download" icon
;; in your browser to download this model file.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


turtles-own[day]
Globals [RM LM current-distance max-cases-L max-cases-r]

to-report divider   ;label the divider patches
  report patches with [ abs pxcor <= 1 and abs pycor < max-pycor]
end 

to-report left-population     ;call all the turtles at the left
  report turtles with [xcor <= 0]
end 

to-report right-population     ;call all the turtles at the right
  report turtles with [xcor > 0]
end 

;;;;;;;;;;;;;;;;;;;;main setup procedures;;;;;;;;;;;;;;

to setup
  clear-all
  setup-patches
  setup-turtles
  reset-ticks
end 

to setup-patches

  ask patches with [ abs pxcor = max-pxcor ] [set pcolor 116]   ;setup boundary
  ask patches with [ abs pycor = max-pycor ] [set pcolor 116]   ;setup boundary
  ask divider  [set pcolor 47]    ;set divider
end 

to setup-turtles
  create-turtles Right-population-size         ;set up the right population
  [set color 68
    set size 1.75
    set shape "person-1"
    setxy 2 + random-float 43 25 - random-float 50   ;randomize turtle positions at right
  ]

  create-turtles Left-population-size         ;set up the left population
  [set color 68
    set size 1.75
    set shape "person-1"
    setxy (-1) * (2 + random-float 43) 25 - random-float 50   ;randomize turtle positions at left
  ]
end 

;;;;;;;;;;;;;;;;;;;;main go procedures;;;;;;;;;;;;;;

to go

  if ticks >= Days [stop]

  ask turtles with [pcolor = 47][set xcor xcor * 5]

  move
  transmission
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask left-population     ;control turtles' movement at the left
  [ifelse [pcolor] of patch-ahead 1 = 0 [forward Mobility-left rt random 360] [set heading heading - random 180]]

   ask right-population        ;control turtles' movement at the right
  [ifelse [pcolor] of patch-ahead 1 = 0 [forward Mobility-right rt random 360] [set heading heading - random 180]]
end 

to add-an-infected-person-at-left
  create-turtles 1
  [set size 1.75
    set shape "person-1"
    set color orange
    setxy (-1) * (1 + random-float 39) 24 - random-float 47]
end 

to add-an-infected-person-at-right
  create-turtles 1
  [set size 1.75
    set shape "person-1"
    set color orange
    setxy 1 + random-float 39 24 - random-float 47]
end 

to transmission       ;set up transmission
  ask turtles with [color = orange]
  [let healthy-person one-of other turtles in-radius 1.5 with [color = 68]
    if healthy-person != nobody
    [ask healthy-person [
      if random 100 < Transmission-rate
      [set color orange]]]
  ]
end 

to sickness     ;set up recovery or death
  ask turtles with [color = orange]
  [set day day + 1
    if day >= 15
    [ifelse random 100 < mortality
      [ifelse xcor >= 0 [set RM RM + 1][set LM LM + 1] die  ]
      [set color blue] ]
  ]
end 

to watch-a-sick-person
  watch one-of turtles with [color = orange]
end 

to find-max-daily-cases
  if count turtles with [color = orange and xcor <= 0] > max-cases-l
  [set max-cases-l  count turtles with [color = orange and xcor <= 0]]

    if count turtles with [color = orange and xcor > 0] > max-cases-r
  [set max-cases-r  count turtles with [color = orange and xcor > 0]]
end