Infectious Disease Outbreak (COV-19)--Vaccination

1 collaborator

lin xiang (Author)

WHAT IS IT?

This model simulates the infectious disease outbreak dynamics in a population influenced by different transmission rate, mortality, and vaccination coverage. This model allows students to explore the effect of vaccination and the development of herd immunity.

HOW IT WORKS

The model starts with a human population consisting of susceptible (green color) and vaccinated (blue color) people. Once an infected case (orange color) appears in the population, it will pass the disease to one of the susceptible people nearby (within a radius of 1.5) at the defined transmission rate. The infected people are able to transmit the disease for 14 days. By the 15th day of being infected, the infected people either die (disappear from the model) at the defined mortality or recover and become immunized (blue color).

Buttons, Sliders, and Switches:

The "population size" slider is self-explanatory. So are the buttons of "Set up/Reset". "Run/Pause", and "Run a day".
The "Vaccination-rate" slider determined the vaccination coverage of the population.
The "Transmission-rate" slider determines how likely a susceptible person is infected when exposed to the disease.
The "Mortality" slider determines how likely the infected people die on the 15th day.
The "+1 Infected Case" button adds infected person into the population.
The "Watch 1 Infected Case" button allows you to focus on a single infected person or stop watching the person. You may see this person eventually recover or die.

HOW TO USE IT

First choose the factors, such as population size, transmission rate, etc.
Click on "Set up/Reset", then "Run/Pause". The model is initially set to stop on the 180th day. Change the number in "Time" if you want to run the model for a longer or shorter time period.
Observe the infection changes in population in the plot and monitors.
Use "Run one day" to run the model in a controlled way and collecting day-by-day data.

THINGS TO TRY

There are so many things you can try in this model. Here are only very a few quick ideas:

Does the total of deaths change differ in a population where all people are susceptible vs. a potion of people are vaccinated? How?
How high must the vaccination rate be for herd immunity to develop?

RELATED MODELS

Find this model series at http://3dsciencemodeling.com

Infectious Disease Outbreak-Basic Phenomenon
Infectious Disease Outbreak-Transmission and mortality
Infectious Disease Outbreak-Population Comparison
Infectious Disease Outbreak-HealthCare, Isolation and Quarantine
Infectious Disease Outbreak-Vaccination

CREDITS AND REFERENCES

Dr. Lin Xiang (lin.xiang@uky.edu) created this module at the University of Kentucky in 2020. If you mention this model in a publication, we ask that you include the citations below.

Xiang, L. (2020). Infectious Disease Outbreak-Vaccination. Department of STEM Education, University of Kentucky, Lexington, KY.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

;;
;; This model is developed by Dr. Lin Xiang at the University of Kentucky. Contact: lin.xiang@uky.edu
;;
;; If you see this page rather than a "download" button when downloading the model, click the "download" icon
;; in your browser to download this model file.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


turtles-own [days infected susceptible]
Patches-own [ ]
Globals [watching LM max-daily-cases]

to setup
  clear-all
  setup-turtles
  setup-patches

  set watching false

  reset-ticks
end 

to setup-turtles
  create-turtles Population-size * (100 - vaccination-rate) * 0.01
  [set color 68
    set size 1.75
    set shape "person-1"
    set days 0
    set infected false
    set susceptible true
    setxy random-xcor random-ycor
  ]

  create-turtles Population-size * (vaccination-rate * 0.01)
  [set color blue
    set size 1.75
    set shape "person-1"
    set days 0
    set infected false
    set susceptible false
    setxy random-xcor random-ycor
  ]

  set LM 0
end 

to setup-patches
  ask patches [set pcolor 0]
end 

to go

  if ticks >= time [stop]
  move
  transmission
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles
  [right random 360 forward 1]
end 

to add-an-infected-person
  create-turtles 1
  [set color orange
    set size 1.75
    set shape "person-1"
    set days 0
    set infected true
    set susceptible false
    setxy random-xcor random-ycor
  ]
end 

to transmission
  ask turtles with [infected = true]
  [
    let healthy-person one-of other turtles in-radius 1.5 with [susceptible = true]
    if healthy-person != nobody
    [ask healthy-person [
      if random 100 < Transmission-rate
      [set color orange set infected true]]
    ]
    ]
end 

to sickness
  ask turtles with [infected = true]
  [set days days + 1
    if days >= 15
    [ifelse random 100 < mortality
      [set LM LM + 1 die  ]
      [set color blue
       set infected false
       set susceptible false ] ]
  ]
end 

to watch-an-infected-person
  watch one-of turtles with [infected = true]
end 

to find-max-daily-cases
  if count turtles with [infected = true ] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [infected = true ]]       ;update the max daily case
end

There are 4 versions of this model.

Uploaded by	When	Description	Download
lin xiang	12 days ago	Add in max daily cases	Download this version
lin xiang	13 days ago	Add in max daily cases	Download this version
lin xiang	13 days ago	Add in max daily cases	Download this version
lin xiang	11 months ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
Infectious Disease Outbreak (COV-19)--Vaccination.png	preview	Preview for 'Infectious Disease Outbreak (COV-19)--Vaccination'	11 months ago, by lin xiang	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo