States of Matter-intermolecular forces and kinetic energy

1 collaborator

lin xiang (Author)

WHAT IS IT?

This model represents the changes of state at the micro-particle level. In this model, the states of matter are determined by three factors--kinetic motion, attraction, and repulsion. By heating up and cooling down a set of particles, students can explore the fundamental features of three states. This model also allows students to explore the interplay between the attractive force and repulsive force. This model is particularly good for students to identify visual evidence for describing different states and the changes, as well as explore how intermolecular forces and kinetic energy influence the states of matter.

HOW IT WORKS

All the particles follow three rules: kinetic motion, attraction, and repulsion. The model starts with many randomly distributed particles. All particles have the same initial speed. When users "heat up" the particle, the speed increases. When users "cool down" the particle, the speed decreases. i.e., you add and remove kinetic energy.

Each particle is attracted to one of the other particles in a radius of 5, indicated by the fact that it moves towards the particle a little bit, determined by the slider "attractive-force." Each particle is repelled by one of the other particles if the distance between the two particles is less than 1, indicated by the fact that it moves away from the particle a little bit, determined by the slider "repulsive-force" if the distance is less than 1.

HOW TO USE IT

Choose "Number-of-particles" and "Particle-color" first. The colors do not indicate different types of particles. They are for fun.
Click on the button "start/reset" to confirm the setting, and then click "Run/Pause" to run the model.
Click the "heat up" or "cool down" buttons while running the model.
Use the sliders "attractive-force" and "repulsive-force" to adjust the levels of these two intermolecular forces.

THINGS TO NOTICE

Can you identify the solid, liquid, and gas states in this model?
What evidence can you gather in the model for identifying each of the states?
Does the amount of matter change when the state changes?
What evidence can you gather in the model for determining whether the amount of matter changes?
What happens to the particles if there is no attractive force or repulsive force or neither? Can you still identify the three states now? Why?

OTHER MODELS

Check other models at http://3dsciencemodeling.com.

CREDITS AND REFERENCES

Dr. Lin Xiang created this module at the University of Kentucky in 2020. If you mention this model in a publication, we ask that you include the citations below.

Xiang, L. (2020). States of Matter-intermolecular forces and kinetic energy. Department of STEM Education, University of Kentucky, Lexington, KY.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own [step watched]
patches-own [occupied tt-here]
globals [ ]

to setup
clear-all

create-turtles number-of-particles
[set-color
 set size 2.25
 set shape "dot"
 set step 0.2
 set watched false
 setxy random-xcor random-ycor ]

  check-turtles-here

reset-ticks
end 

to check-turtles-here

  ask patches[
    ifelse any? turtles-here
    [set occupied true set pcolor 49 ]
    [set occupied false set pcolor white]
    if count neighbors with [occupied = true] > 5 [set occupied true set pcolor 49]
    set tt-here count turtles-here
  ]
end 

to go
  ask turtles [set-color]
    attraction
    repulsion
    kinetic-move
    check-turtles-here

  tick
end 

to kinetic-move
  ask turtles
    [ifelse step <= 0 [user-message "The molecules cannot be cooled any more." stop]
    [fd step
      rt random-float 360]
  ]
end 

to attraction

  ask turtles [
    let a-close-molecule one-of other turtles in-radius 5
    if a-close-molecule != nobody
     [ ifelse step >= 0.02
      [face a-close-molecule fd attractive-force rt random-float 360]
      [face a-close-molecule fd step rt random-float 360]
  ]]
end 

to repulsion
   ask turtles [
    let a-close-molecule one-of other turtles in-radius 1
    if a-close-molecule != nobody
     [face a-close-molecule
      bk repulsive-force
      rt random-float 360

    ]
  ]
end 

to set-color
  (ifelse
  Particle-color = "Red" [set color red]
  Particle-color = "Orange" [set color orange]
  Particle-color = "Brown" [set color brown]
  Particle-color = "Green" [set color green]
  Particle-color = "Cyan" [set color Cyan]
  Particle-color = "Blue" [set color blue]
  Particle-color = "Violet" [set color violet]
  Particle-color = "Pink" [set color Pink]
  Particle-color = "Magenta" [set color magenta]
  Particle-color = "Colorful" [ set color 5 + (10 * random 14)])
end

There are 3 versions of this model.

Uploaded by	When	Description	Download
lin xiang	almost 3 years ago	Fix info typos	Download this version
lin xiang	about 4 years ago	fix buttons	Download this version
lin xiang	about 4 years ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
States of Matter-intermolecular forces and kinetic energy.png	preview	Preview for 'States of Matter-intermolecular forces and kinetic energy'	about 4 years ago, by lin xiang	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo