Extinction and Evolution

1 collaborator

David Sousa (Author)

THEORY

Evolutionary adaptability, also called evolvability is the potential of a lineage to evolve, this is, to generate heritable, selectable phenotypic variation. What are the causes for the appearance of increasing evolvability? Is evolvability evolvable? The most common explanations for evolvability rely on selection pressure. (e.g. Dawkins, R., 2003; Kirschner, M., & Gerhart, J., 1998). However, it has been shown that adaptive explanations may be unnecessary. If evolvability is heritable, increasing evolvability is demonstrated without any pressure to adapt, resulting from a more fundamental passive process of drifting over genotypes. The more genotypically diverse and evolvable organisms become, more likely they become phenotypically diverse and spread through ecological niches, such that, a biased distribution of phenotypes towards increasing evolvability can result from a passive drift over genotypes. (Lehman, J., & Stanley, K. O., 2013)

Considering this and observing that extinction events exert a powerful influence on the evolution of life (Raup, D. M., 1986; Raup, D. M., 1992), Lehman and Miikkulein (2015) explore the potential link between extinction events and the biological property of evolvability, and reinforce the interpretation that repeated and indiscriminate extinction events although being destructive and unpredictable can accelerate the evolution of life. While extinction events perturb ecological systems by eliminating those organisms that happen to be susceptible to geological rare stresses that happen by chance, it may yet benefit evolution as whole. In this view, the evolution's long-term potential of a particular lineage is not fully determined by its adaptivity. This potential is accentuated by extinction events, in detriment of more susceptible lineages. As a consequence, repeated indiscriminate extinction events accelerate evolution.

WHAT IS IT?

Extinction events can accelerate evolution. This model was designed to study the importance of mass extinction events for the evolution of biological diversity.

HOW IT WORKS

This model replicates the experiments of Lehman and Miikkulein (2015) on the effect of repeated extinction events on evolution. The model is based on the abstract limited-capacity niche model of Lehman, J. and & Stanley, K. O. (2013) inspired by the concept of adaptive radiation through ecological niches. Each organism has only one gene: evolvability - its capacity to generate novel phenotypes, expressed by a probability of shifting to a new niche (a patch in a discrete toroidal world), where new phenotypes are required for different ways of living. In this sense the world can also be seen as the phenotypic space explored by different lineages or organisms in genotypic drift. In each generation, each organism is substituted by his offspring which inherit their parents evolvability but can also become more or less evolvable according to a fixed probability of mutation of evolvability and a magnitude of mutation picked from a uniform distribution. In the beginning of each generation, an organism can shift to a new niche according to its evolvability. To model limited resources, niches support only a limited number of organisms. The simulations start with one organism at the center of the world.

Because niches have limited capacity due to limited resources and population growth is geometrical there's an indirect pressure to expand through niches which results in increasing evolvability. More evolvable lineages of organisms will spread more rapidly and occupy a larger amount of niches, however, because the world is finite, it saturates and the evolution of evolvability stagnates. Extinction thus facilitate the continuation of the evolution of evolvability. To test this hypothesis, regular extinction events can be programmed (at an every fixed number of generations). Repeated extinction events at random intervals can also be tested, as well as no extinction events at all (control) or at arbitrary chosen generations.

Due to performance issues, this model presents a simplified version of the model described above. Here, niches that become completely surronded will not change their evolvability.

HOW TO USE IT

Use the input boxes init-n-of-organisms, max-n-organisms-per-niche and n-of-offspring to specify the initial conditions: initial number of organisms, maximum number of organisms per niche and the number of offspring by each organism at each generation.

Use the sliders to specify the value of evolvability to start with (init-evolvability), the probability with which this value is changed/mutated in each new organism at each generation (prob-of-evolvability-mutation), and the maximum magnitude with which evolvability can be mutated (magnitude-of-evolvability-mutation). Note, given the default value 0.0025 of the magnitude-of-evolvability-mutation, evolvability can be changed by any magnitude (with the same probability) in the interval [-0.0025,0.0025].

Extinction events can be programmed using the box programmed-extinction-events. "Regular intervals X generations" is chosen by default. "Random uniform between X and Y" and control conditions can also be chosen. X and Y are specified in the respective input boxes (with no effect in the case no extinction events are programmed). Choose the number of surviving niches after extinction with the slider n-surviving-niches.

You can also manually provoke extinction events by clicking the button "extinction event".

To control when to stop the simulation use the slider n-generations-to-stop. One tick/time unit corresponds to one generation.

Each patch in the toroidal world corresponds to a niche. It as the size of one pixel and its color intensity corresponds to the average evolvability value at that niche. Higher intensity pixels indicate higher evolvability values at the corresponding niche. You can use the slider ticks-to-update-heat-map to choose when to update this visual information. The default is 100 for optimization but you can start with 1 and change it later as it gets slower.

Plots are given for the evolution of the average evolvability over all organisms in the world (in this case also a counter), and the total number of organisms in the world.

Setup and go! (go is also stop)

15000 generations can take some time but evolution takes time :)

THINGS TO TRY

1) Setup and go with default settings but with no programmed extinctions events (set control condition) and wait to see how evolvability evolves until it stagnates. Observe that the more phenotipicaly diverse lineages (with higher evolvability) are more far from the center of the world, and the less are closer. More evolvable lineages, explored and conquered more of the phenotypic space.

1.1) Provoke an isolated extinction event.

2) Setup and go with default settings but try different conditions of extinction, observe the evolution of evolvability and compare.

3) Change settings, setup and go. (note you can also change settings during the simulation and manually provoke extinction events.

CREDITS

The present model was coded by David N. Sousa. Feel free to contact.

REFERENCES

Dawkins, R. (2003). The evolution of evolvability. On growth, form and computers, 239-255.

Kirschner, M., & Gerhart, J. (1998). Evolvability. Proceedings of the National Academy of Sciences, 95(15), 8420-8427

Lehman, J., & Stanley, K. O. (2013). Evolvability is inevitable: Increasing evolvability without the pressure to adapt. PloS one, 8(4), e62186.

Lehman, J., & Miikkulainen, R. (2015). Extinction events can accelerate evolution. PloS one, 10(8), e0132886.

Raup, D. M. (1986). Biological extinction in earth history. Science, 231(4745), 1528-1533.

Raup, D. M. (1992). Extinction: bad genes or bad luck?. WW Norton & Company.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals[extinction-event-date global-organisms-list]

breed[organisms organism]

organisms-own[evolvability]

patches-own[saturated? blocked? survivor? painted? organisms-list mean-evolvability-here]

to setup
  ca
  set global-organisms-list []
  ask patches [set saturated? false set blocked? false set survivor? false set painted? false set organisms-list [] set mean-evolvability-here 0]
  put-organisms
  update-heat-map
  if programmed-extinction-events = "random uniform between X and Y" [set extinction-event-date ( X + random ( Y - X ))]
  reset-ticks
end 

to put-organisms
  create-organisms init-n-of-organisms [ht set evolvability init-evolvability]
end 

to go
  ask organisms [shift-niche]
  ask organisms [mutate]
  ask organisms [new-generation]
  if ticks mod ticks-to-update-heat-map = 0 [update-heat-map]
  optimize
  tick
  if programmed-extinction-events = "regular intervals X generations" [if ticks mod X = 0 [extinction-event]]
  if programmed-extinction-events = "random uniform between X and Y" [if ticks = extinction-event-date [extinction-event set extinction-event-date ( ticks + X + random ( Y - X )) ]]
  if ticks = n-generations-to-stop [stop]
end 

to optimize
  ; to save computational resources blocked  organisms (surrounded by saturated niches) are killed and their
  ; evolvabilities saved in a list (per patch) so they can be recovered after an extinction event
  ask organisms with [not blocked? and (count neighbors with [saturated?]) = 8] [
    set blocked? true
    set organisms-list fput evolvability organisms-list
    set global-organisms-list (sentence global-organisms-list organisms-list)
    die
  ]
end 

to extinction-event
  set global-organisms-list []
  ask organisms [
    set organisms-list fput evolvability organisms-list
    die
  ]
  ask n-of n-surviving-niches (patches with [pcolor != black]) [
    set survivor? true
    foreach organisms-list [ ?1 -> sprout-organisms 1 [ht set evolvability ?1] ]
  ]
  ask patches with [not survivor?] [set pcolor black]
  ask patches [set organisms-list [] set saturated? false set survivor? false set blocked? false set painted? false set mean-evolvability-here 0]
  ask organisms [
    set global-organisms-list (sentence global-organisms-list organisms-list)
  ]
end 

to update-heat-map
  ask patches with [any? organisms-here][set mean-evolvability-here (mean [evolvability] of organisms-here * 100)]
  ask patches with [not empty? organisms-list and not painted?][set mean-evolvability-here (mean organisms-list * 100) set painted? true]
  ask patches with [mean-evolvability-here > 0 ][set pcolor scale-color black mean-evolvability-here 0 9.9]
end 

to shift-niche
  let candidates neighbors with [not saturated?]
  if random-float 1 < evolvability and any? candidates [
    set saturated? false
    move-to one-of candidates
  ]
end 

to mutate
  if random-float 1 < prob-of-evolvability-mutation [set evolvability (evolvability + ((2 * random-float magnitude-of-evolvability-mutation) - magnitude-of-evolvability-mutation))]
end 

to new-generation
  repeat n-of-offspring [ifelse (count organisms-here) <= max-n-organisms-per-niche
    [hatch 1]
    [set saturated? true die]]
end

There is only one version of this model, created almost 5 years ago by David Sousa.

Attached files

File	Type	Description	Last updated
Extinction and Evolution.png	preview	Preview for 'Extinction and Evolution'	almost 5 years ago, by David Sousa	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo