Emergence of despotic and egalitarian societies

1 collaborator

David Sousa (Author)

THEORY

Dominance interactions between group-living animal species are related with control of resources such as food, safe spatial locations and sexual partners. Despotic and egalitarian societies (based on different dominance styles) can be found in nature (insects, birds and primates). While in the former, these benefits (due to priority of access to resources) are strongly biased towards most dominant individuals, in the later they are more equally distributed.

It is generally considered by observation and analysis of the social behavior of different macaque species, that differences between despotic and egalitarian societies are a consequence of differences in the co-evolution of related social dispositions, such as, intensity of aggression and degree of nepotism (Thierry, 1985 and 1990). Hemelrijk (1999) shows however that these differences in social behavior can also arise in the absence of nepotism, due only to different potentials of spatial self-structuring that depend on different intensities of aggression. Higher intensity of aggression promotes dominance differentiation and a steeper hierarchy, which leads to the emergent phenomenon of spatial centrality of dominants because less dominants flee to the periphery of the group but never too far since the group provides safety. This in turn affects group cohesiveness, decreases frequency of interactions and feeds back dominance differentiation. Dominance relations are thus self-reinforcing. A positive feedback loop system is established between spatial structure and hierarchy differentiation.

WHAT IS IT?

This model is inspired on the artificial life model of Hemelrijk, to simulate the complex system described. In this computational model of dominance and spatial structure, resources are not explicitly implemented but they are implicitly assumed as agents in a virtual world engage in competitive interactions whenever other agents are found in their personal space.

HOW IT WORKS

Agents can move in a toroidal virtual world (to avoid border effects) of size 51 x 51 spatial units. Their visual field is defined by an attentional angle (attentional-angle) and attentional-distance (maxview). The order in which agents act in the world is random, which is biologically plausible for small groups of agents as considered here by default. For much larger groups however a locally controlled activity sequence should also be implemented, in which agents act if they see any another agent acting in their visual field. Here to simplify, one time-step counts after all agents act in a random order.

Two opposing forces affect the group spatial structure: the agents are attracted to one another because being in the group provides safety, but aggregation implies competition for resources (individuals strive for higher ranks) which drives individuals apart. In this model, aggregation is defined by the grouping rules defined in Hemelrijk, C. K. (1999, January).

THINGS TO TRY

1) Setup and go with default settings and observe the plots and monitors.

2) Try different values of initdom and stepdom (eg: 8 and 0.1). Setup, go and observe the plots and monitors. In this case dominance values are much lower than in the former case and changes in dominance are much slower. This would be the case of a more egalitarian society.

CREDITS

The present model was coded by David N. Sousa. Feel free to contact.

REFERENCES

Hemelrijk, C. K. (1999, January). Emergence of despotic and egalitarian societies: an individual-oriented model for hypothesis generation on macaques. In AMERICAN JOURNAL OF PHYSICAL ANTHROPOLOGY (pp. 148-149). DIV JOHN WILEY & SONS INC, 605 THIRD AVE, NEW YORK, NY 10158-0012 USA: WILEY-LISS.

Thierry, B. (1985). Social development in three species of macaque (Macaca mulatta, M. fascicularis, M. tonkeana): a preliminary report on the first ten weeks of life. Behavioural processes, 11(1), 89-95.

Thierry, B. (1990). Feedback loop between kinship and dominance: the macaque model. Journal of theoretical Biology, 145(4), 511-522.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals[mean-feq-attacks mean-centrality dominance-differentiation]

turtles-own[dominance win list-of-mean-distances current-mean-distance centrality n-attacks]

to setup
  ca
  ask patches [set pcolor blue]
  crt n-turtles [set color white setxy (random-xcor / init-cohesion ) (random-ycor / init-cohesion ) set dominance initdom set list-of-mean-distances []]
  collect-data
  reset-ticks
end 

to go
  ask turtles [activation-procedure]
  ask turtles [set color scale-color red dominance 0 ([dominance] of max-one-of turtles [dominance])]
  ask turtles [if color > 19.9 [set color yellow]]
  tick
  collect-data
end 

to collect-data
  ask turtles [
    set current-mean-distance mean [distance myself] of turtles
    set list-of-mean-distances fput current-mean-distance list-of-mean-distances
    set centrality mean list-of-mean-distances
  ]
  set mean-centrality mean [centrality] of turtles
  if not any? turtles with [n-attacks = 0] [ set mean-feq-attacks mean [n-attacks / ticks] of turtles]
  set dominance-differentiation standard-deviation [dominance] of turtles / mean [dominance] of turtles
end 

to activation-procedure
  ifelse any? turtles-in perspace [interact][
    ifelse any? turtles-in nearview [step 1][
      ifelse any? turtles-in maxview [face one-of turtles-in maxview step 1][
        set heading heading + (search-angle * ( - 1) ^ (random 2))]]]
end 

to step [d]
  repeat 10 [fd d / 10]
end 

to-report turtles-in [d]
  report other turtles in-cone d attentional-angle
end 

to interact
  let target min-one-of turtles-in perspace [distance myself]
  let relative-dominance (dominance / (dominance + [dominance] of target))
  attack target relative-dominance
  ifelse win = 1 [
    attack target relative-dominance
    set n-attacks n-attacks + 1
    move-after-attack target
    update-rank target relative-dominance
  ][
  ;loosers-move
  ]
end 

to attack [tgt rd]
  let rnd random-float 1
  ifelse rd >= rnd [set win 1 ask tgt [set win 0]][set win 0 ask tgt [set win 1]]
end 

to move-after-attack [tgt]
  ifelse win = 1 [winners-move ask tgt [loosers-move]]
    [loosers-move ask tgt [winners-move]]
end 

to winners-move
  step 1 set heading heading + (45 * ( - 1) ^ (random 2))
end 

to loosers-move
  set heading (heading + 180 + (45 * ( - 1) ^ (random 2))) step flee-distance
end 

to update-rank [tgt rd]
  set dominance dominance + stepdom * (win - rd) * ( - 1) ^ (abs (win - 1))
  ask tgt [
    set dominance dominance + stepdom * ([win] of myself - rd) * ( - 1) ^ (abs (win - 1))
    ]
  ; correct null/negative dominance
  if dominance <= 0.001 [set dominance 0.001]
  ask tgt [if dominance <= 0.001 [set dominance 0.001]]
end

There is only one version of this model, created almost 5 years ago by David Sousa.

Attached files

File	Type	Description	Last updated
Emergence of despotic and egalitarian societies.png	preview	Preview for 'Emergence of despotic and egalitarian societies'	almost 5 years ago, by David Sousa	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo