Epidemic development and control

Epidemic development and control preview image

1 collaborator

Screen_shot_2018-02-02_at_12.53.50_pm lin xiang (Author)

Tags

(This model has yet to be categorized with any tags)
Visible to everyone | Changeable by the author
Model was written in NetLogo 6.1.1 • Viewed 39 times • Downloaded 2 times • Run 0 times
Download the 'Epidemic development and control' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model simulates the epidemic dynamics in a human population based on a revised SEIR model, in which the disease is spread by the infected presymptomatic carriers while infectious people are well isolated (at home or hospital) and therefore cannot infect others.

RELATED MODELS

More epidemic models at www://3dsciencemodeling.com. These models are developed for teaching basic epidemic processes and conceptions.

CREDITS AND REFERENCES

Coded by Lin Xiang at the Unversity of Kentucky as part of the modeling science unit materials. email: lin.xiang@uky.edu

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

  • Xiang, L (2021). Epidemic Development and Control. Department of STEM Education, University of Kentucky, Lexington, KY.

Please cite the NetLogo software as:

COPYRIGHT AND LICENSE

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own [ days-after-exposure  days-of-sick]
Patches-own [ ]
Globals [ max-daily-cases ]

to setup
  ca
  setup-turtles
  setup-patches
  reset-ticks
end 

to setup-turtles
  create-turtles population-size
  [set color 68
    set size 1.75
    set shape "person"
    setxy random-xcor random-ycor
  ]
end 

to setup-1
  ask turtles [die]
  setup-turtles
  setup-patches
  add-a-carrier
  reset-ticks
end 

to setup-patches
  ask patches [set pcolor 52]
end 

to go

  if ticks > incubation-period and count turtles with [color = red] = 0 [stop]

  move
  transmission
  incubation
  sickness
  find-max-daily-cases
  tick
end 

to move
  ask turtles with [shape = "person"]
  [right random 360 forward mobility]
end 

to add-a-carrier
  ask one-of turtles                     ;choose a random person
  [set color orange                      ;set the color as orange (carrier color)
  ]
end 

to transmission
  ask turtles with [color = orange]                                              ;Hi, carriers
  [let susceptible-person one-of other turtles in-radius 1.5 with [color = 68]   ;Are there any susceptible people near you (within a radius of 1.5)?
    if susceptible-person != nobody                                              ;If there is at least one
    [ask susceptible-person                                                      ;ask the suscetiple person
      [ if random 100 < transmission-rate                                        ;at the defined transmission rate
        [set color orange]                                                       ;to become a carrier (orange color)
      ]
    ]
  ]
end 

to incubation
  ask turtles with [color = orange]                    ;Hi carriers
   [ifelse days-after-exposure < incubation-period     ;If the number of days after you get infected is smaller than the defined incubation period
    [set days-after-exposure days-after-exposure + 1]  ;increase the number of days after exposure by 1
    [set color red set shape "house"]                                    ;otherwise, become infectious (red color)
   ]
end 

to sickness
  ask turtles with [color = red]          ;Hi sick people,
  [ifelse days-of-sick < 14               ;if you have not been sick for 14 days
    [set days-of-sick days-of-sick + 1]   ;remain sick and increase the number of sick days by 1
    [ifelse random 100 < mortality        ;otherwise, at the define mortality rate
      [die]                               ;die
      [set color blue set shape "person"] ;or recover
    ]
   ]
end 

to vaccination
  let num-of-susceptible (count turtles with [color = 68])              ;find the number of susceptible people
  let num-of-vaccinated  (num-of-susceptible * vaccination-rate * 0.01) ;calculate number of susceptubel people to be vaccinated
  ask n-of num-of-vaccinated turtles with [color = 68]                  ;find these many susceptible people
     [set color blue]                                                   ;set as immune (blue)
end 

to find-max-daily-cases
  if count turtles with [color = red ] > max-daily-cases        ;Count the infectious.If it is greater than the current record of max daily cases
  [set max-daily-cases count turtles with [color = red ]]       ;update the max daily case
end 

There is only one version of this model, created 3 months ago by lin xiang.

Attached files

File Type Description Last updated
Epidemic development and control.png preview Preview for 'Epidemic development and control' 3 months ago, by lin xiang Download

This model does not have any ancestors.

This model does not have any descendants.