PavementAntForaging-RACAS 2021 upd 4/27/2021

;;;;; types of Netlogo turtles, including ants and trail-markers
breed [foragers forager]
breed [leaders leader]
breed [followers follower]
breed [trail-markers trail-marker]

patches-own ;; variables accessible by the patches of the world
[ nest?
  nest-scent
  nest-x nest-y
  food-source-center-x
  food-source-center-y
  food
]

globals  ;; accessible by all agents within the model
[old-sum
  sum-change-tick
  first-follower-food-tick
  first-leader-tick
  food-consumption-tick
  mass-recruitment-tick
]

to setup
  clear-all
  set-default-shape turtles "bug"
  set-default-shape trail-markers "line half"
  create-foragers 10
  [set color yellow
    set size 2.25
    setxy 36 16]
  setup-patches
;;;                        sets reporters to a default value of -1
  set first-leader-tick -1
  update-first-leader-tick
  set first-follower-food-tick -1
  update-first-follower-food-tick
  set mass-recruitment-tick -1
  update-mass-recruitment-tick
  set food-consumption-tick -1
  update-food-consumption-tick

  reset-ticks
end 

to setup-patches
ask patches
  [setup-nest
  setup-food
  setup-food-quality]
end 

to setup-nest
    ;; set nest? variable to true inside the nest, false elsewhere
  set nest? (distancexy 36 16) < 2
  ;; spread a nest-scent over the whole world -- stronger near the nest
  set nest-scent 200 - distancexy 36 16
  set nest-x 36
  set nest-y 16
  if nest?
  [set pcolor brown]
end 

to setup-food
  if (distancexy (0.8 * min-pxcor) (0.8 * min-pycor)) < 5
  [set food 5                                              ;; dictates the amount of food on each food-patch
    if food > 0
    [set pcolor cyan]]
  set food-source-center-x -36
  set food-source-center-y -20
end 

to setup-food-quality  ;; patch procedure
  if food > 0
  [set food-quality one-of [0 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1.0]] ;; controllable with slider; 0 triggers no response
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to go ;; triggered by the go button
  ask foragers
    [fd 1
     ifelse any? trail-markers
      [ifelse can-move? 1            ;; if not at the edges
        [follow-trail-marker-path]
        [rt 180]]                    ;; if at the edges, turn around
        [wiggle]                     ;; wiggle (random-walk if there is no pheromone trail)
     look-for-food                   ;; respond to food if found
     return-to-nest-and-food
      eliminate-foragers
  ]
  ask leaders
      [wiggle
        lead                                 ;; go back and forth from the nest to the food, collecting followers
        initiate-trail                       ;; lay down trail markers
        mass-recruit-leaders]                ;; transform into foragers once group-recruitment has finished (maximum number of followers collected)
  ask followers
  [follow-leaders                             ;; walk behind leaders
    find-food                                 ;; first follower changes size to signal its presence on the food
  transition-to-mass-recruitment              ;; change color at the end of group recruitment
  return-to-nest-mass-recruitment-transition  ;; break away from the leaders and return to the nest at the end group-recruitment
  mass-recruit]                               ;; transform into foragers after the completion of group-recruitment

  ask patches
  [recolor-patch ]                            ;; change color to signify food-removal

  update-first-leader-tick
  update-first-follower-food-tick
  print word "first-follower-food-tick " first-follower-food-tick
  update-mass-recruitment-tick
  update-food-consumption-tick

  if sum [food] of patches with [pcolor = cyan] = 0 and ticks > 0        ;; commands for the end of the model
  [if not any? foragers with [color = orange] [ask trail-markers [die]]  ;; evaporate pheromone trail
   ask foragers [if (distancexy nest-x nest-y <= 2) [die]]               ;; re-enter the nest if close
    if count foragers = 0 and ticks > 1000 [stop]]                       ;; stops model

  tick
end 

to look-for-food  ;; forager procedure
  let foods patches with [food > 0]
  let potential-leaders foragers-on foods
  if food > 0 and food-quality > 0
  [ifelse (not any? leaders) and (any? potential-leaders) and (count foragers <= 10)  ;; checks if any leaders exist and if object = true food
  [ ask one-of potential-leaders
    [ set breed leaders
    set color magenta]]  ;; transforms first forager to find food into the leader
    [set color orange]] ;; outside of one-of potential leaders brackets --> applies to asked agents (all foragers)
end 

to return-to-nest-and-food  ;; forager procedure
  if color = orange  ;; directs movement of foragers who have found food
        [if food > 0
          [set food food - 1]          ;; pickup food
          if food > 0 and sum [food] of patches with [pcolor = cyan] <= 10
          [set food food - 5]
         if count trail-markers > 200
            [hatch-trail-markers 1       ;; reinforce trail
            [set size 1.0]]
          uphill-nest-scent           ;; directly returns to nest via dead reckoning
          if not can-move? 1 [rt 180]

        if (distancexy nest-x nest-y) <= 2   ;; "drop off" the food at the nest
          [set color yellow                  ;; change back to original color to signal new foraging status
            hatch-foragers 1                 ;; recruit an additional forager from the nest
            [ifelse any? trail-markers [follow-trail-marker-path] [wiggle]]
            ifelse any? trail-markers [follow-trail-marker-path] [wiggle]
            fd 1
  ] ]
end 

to lead  ;; leader procedure
  if color = magenta
    [fd 2              ;; walks quickly ahead of followers
      uphill-nest-scent ;; dead-reckons
      if (distancexy nest-x nest-y) <= 2
      [set color white
      if food-quality > 0.8
        [if count followers < 16 and (not any? followers with [color = violet + 1]) and (count foragers < 100) ;; hatch n followers, dependent on food-quality
          [hatch-followers 1
            [set color brown
        IF count followers = 2
              [fd 1.5]
        IF count followers = 3
              [fd 1.25]
        IF count followers = 4
              [fd 1]
        if count followers = 5
              [fd .9]
        if count followers = 6
              [fd .8]
         if count followers = 7
              [fd .7]
        if count followers >= 8
              [fd .6]  ]]
        ]
        if (food-quality > 0.6) and (food-quality < 0.9) and (count followers < 8) and (not any? followers with [color = violet + 1]) and (count foragers < 30)
          [hatch-followers 1
            [set color brown
        IF count followers = 2
              [fd 1.5]
        IF count followers = 3
              [fd 1.25]
        IF count followers = 4
              [fd 1]
              if count followers = 5
              [fd .9]
        if count followers = 6
              [fd .8]
         if count followers = 7
              [fd .7]
        if count followers = 8
              [fd .6]  ]]

        if (food-quality > 0.4) and (food-quality < 0.7) and (count followers < 4) and (not any? followers with [color = violet + 1]) and (count foragers < 28)
        [hatch-followers 1
            [set color brown
        IF count followers = 2
              [fd 1.5]
        IF count followers = 3
              [fd 1.25]
        IF count followers = 4
              [fd 1]
        ]]
        if (food-quality > 0.2) and (food-quality < 0.5) and (count followers < 2) and (not any? followers with [color = violet + 1]) and (count foragers < 14)
        [hatch-followers 1
            [set color brown
        IF count followers = 2
              [fd 1.5]
        ]]
        if (food-quality > 0) and (food-quality < 0.3) and (count followers < 1) and (not any? followers with [color = violet + 1]) and (count foragers < 12)
         [hatch-followers 1
            [set color brown]]
  ]]

  if color = white
      [wiggle
        fd 2
        facexy food-source-center-x food-source-center-y        ;; head back to the food
        hatch-trail-markers 1 [set color blue set size 1.0]     ;; lay down pheromone trail
        if food > 0
        [set color magenta] ]
  if not can-move? 1 [rt 180]
end 

to mass-recruit-leaders  ;; transiiton leaders to pheromone-following foragers
  if (not any? followers with [color = brown]) and (count foragers >= 12) and (distancexy nest-x nest-y <= 2)   ;; transforms leaders into foragers during mass-recruitment
  [set breed foragers
    set color yellow
    hatch-foragers 1]
end 

to follow-leaders  ;; follower procedure for group-recruitment
  if color = brown
  [face one-of leaders
    fd 1.75
    hatch-trail-markers 1 [set color blue set size 1.0]      ;; reinforce pheromone trail
  ]
end 

to find-food  ;; follower procedure
  if (food > 0) and (count followers = 1) [set size 1.75]  ;; identifies first follower to reach food
end 

to initiate-trail        ;; leader procedure
  ask leaders with [color = magenta]
  [hatch-trail-markers 1
    [set color blue
      set size 1.0]]
end 

to transition-to-mass-recruitment  ;; follower procedure that makes them independent of leaders
  if (distancexy food-source-center-x food-source-center-y) <= 4 and (count followers >= 1) and (food-quality < 0.3) ;; once group-recruitment has finished (max number of followers for that food-quality reached)
  [set color violet + 1]

  if (distancexy food-source-center-x food-source-center-y) <= 4 and (count followers >= 2) and (food-quality > 0.2) and (food-quality < 0.5)
  [set color violet + 1]

  if (distancexy food-source-center-x food-source-center-y) <= 4 and (count followers >= 4) and (food-quality > 0.4) and (food-quality < 0.7)
  [set color violet + 1]

  if (distancexy food-source-center-x food-source-center-y) <= 4 and (count followers >= 8) and (food-quality > 0.6) and (food-quality < 0.9)
  [set color violet + 1]

  if (distancexy food-source-center-x food-source-center-y) <= 4 and (count followers >= 16) and (food-quality > 0.8)
  [set color violet + 1]
end 

to return-to-nest-mass-recruitment-transition  ;; follower procedure that directs them back to nest to initate mass-recruitment
  if color = violet + 1
  [if food > 0
    [set food food - 1]
    hatch-trail-markers 1 [set size 1 set color orange]
    wiggle
    fd 1
    uphill-nest-scent]
end 

to mass-recruit ;; follower procedure for transforming into foragers during mass-recruitment
  if (distancexy nest-x nest-y) <= 2 and (color = violet + 1)
  [set breed foragers
    set color yellow
  hatch-foragers 1]
end 

to recolor-patch  ;; patch procedure
  ;; give color to nest and food sources
  ifelse nest?                          ;; nest? true --> color brown
  [ set pcolor brown ]
  [ ifelse food > 0                     ;; not nest, but has food
    [  set pcolor cyan ]
    [set pcolor black ] ]      ;; food/nest pheromone default to 0
end 

to wiggle            ;; determines the "randomness" of the random walk by having the ants turn any angle up to 45 degress in either direction
  rt random 45
  lt random 45
  if not can-move? 1 [ rt 180 ]
end 

to uphill-nest-scent  ;; dead-reckoning procedure that involves going towards the highest value of nest-scent
  let scent-ahead nest-scent-at-angle   0
  let scent-right nest-scent-at-angle  45
  let scent-left  nest-scent-at-angle -45
  if (scent-right > scent-ahead) or (scent-left > scent-ahead)
  [ ifelse scent-right > scent-left
    [ rt 45 ]
    [ lt 45 ] ]
end 

to follow-trail-marker-path     ;; directs ant movement toward the pheromone trail
  ifelse count foragers < 15    ;; at the beginning of recruitment, foragers weakly follow the pheromone trail and random-walk
  [ifelse any? (trail-markers-on patch-ahead 1) with [color = blue]
    [fd 1]
    [ifelse (patch-left-and-ahead 30 1 = nobody) or (patch-right-and-ahead 30 1 = nobody) or (not any? leaders) or (not any? foragers with [color = orange])
      [rt random 45 lt random 45]
      [if (any? trail-markers-on patch-left-and-ahead 30 1) and (total-trail-markers-in-cone 10 -30 10 > total-trail-markers-in-cone 10 30 10)
        [lt 30]
        if (total-trail-markers-in-cone 10 30 10 > total-trail-markers-in-cone 10 -30 10) and (any? trail-markers-on patch-right-and-ahead 30 1)
        [rt 30]]
  ]]

  [ifelse any? trail-markers-on patch-ahead 1 [fd 1 right random 20 left random 20]
    [ifelse (patch-left-and-ahead 30 1 = nobody) or (patch-right-and-ahead 30 1 = nobody)
      [wiggle]
      [if any? trail-markers-on patch-left-and-ahead 30 1 and (total-trail-markers-in-cone 10 -30 10 > total-trail-markers-in-cone 10 30 10)
        [lt 30]
      if (total-trail-markers-in-cone 10 30 10 > total-trail-markers-in-cone 10 -30 10) and any? trail-markers-on patch-right-and-ahead 30 1
        [rt 30]
        if any? leaders or any? foragers with [color = orange] or count foragers >= 20
        [if total-trail-markers-in-cone 5 30 30 < 1 or total-trail-markers-in-cone 5 -30 30 < 1 [uphill-nest-scent]]
        if not any? leaders or not any? foragers with [color = orange] [wiggle]
  ]]]
end 

to eliminate-foragers ;; some ants stuck at the edges die
  if count foragers > 10
  [if patch-here = patch 45 -25 [die]
  if patch-here = patch 45 25 [die]
  ]
end 

;;; checks for any change in various statuses; if there is a change, it will be reported; these primarily correspond to the boxes on the left panel of the model interface

to update-first-leader-tick
  if first-leader-tick < 0
  [show count leaders
    if any? leaders
    [ set first-leader-tick ticks ]
  ]
end 

to update-first-follower-food-tick
  let potential-recruiters followers with [size = 1.75]
  if first-follower-food-tick < 0
    [show count potential-recruiters
    if any? potential-recruiters
    [ set first-follower-food-tick ticks ]
  ]
end 

to update-mass-recruitment-tick
  if mass-recruitment-tick < 0
  [show count followers
    if not any? followers and count foragers > 20
      [set mass-recruitment-tick ticks]
  ]
end 

to update-food-consumption-tick
  let food-level sum [food] of patches with [pcolor = cyan]
  if food-consumption-tick < 0
  [show food-level
    if food-level < 1
    [ set food-consumption-tick ticks ]
  ]
end 

to-report nest-scent-at-angle [angle]
  let p patch-right-and-ahead angle 1
  if p = nobody [ report 0 ]
  report [nest-scent] of p
end 

to-report total-trail-markers-in-cone [cone-distance angle angle-width ] ; ant procedure - reports the total amount of trail-markers in cone
  rt angle
  let p count trail-markers in-cone cone-distance angle-width
  ;ask p [ show chemical ]
  lt angle
  report (p)
  if not any? p [report 0]
end 

to-report leader-presence
  ifelse any? leaders
  [report first-leader-tick]
  [report -1]
end 

to-report group-recruitment-initiation
  let recruited-ant followers with [size = 1.75]
ifelse any? recruited-ant
  [ report first-follower-food-tick ]
  [ report -1]
end 

to-report leader-food-follower-difference
  ifelse first-leader-tick != -1 and first-follower-food-tick !=  -1
  [ report first-follower-food-tick - first-leader-tick]
  [ report -1 ]
end 

to-report mass-recruitment-initiation
  ifelse not any? followers
  [report mass-recruitment-tick]
  [report -1]
end 

to-report food-consumption
  ifelse (sum [food] of patches with [pcolor = cyan] < 1 )
  [report food-consumption-tick]
  [report -1]
end