Great Salt Lake

1 collaborator

lin xiang (Author)

WHAT IS IT?

This model simulates the salinity dynamics in the south arm of the Great Salt Lake caused by the surface inflows from three local rivers and the water exchanges with the north arm. The salinity changes, in turn, affect the brine shrimp population in the lake.

DESIGN NOTES

Only three factors are included in the model to determine the salinity changes in the south arm of GSL: stream inflow, north arm water inflow, and evaporation.
Massive precipitation is unusual in the GSL area. When it happens, the stream inflow increases
The salinity of the North arm is always high due to fewer freshwater inputs compared to the south arm.
To simply the model, only two river entrances, Bear River and Jordan-weber River, are simulated.
The highest salinity is 28% (saturation point) with color 90.5 and lowest is 0% (freshwater) with color 99.5. { pcolor= (-0.32) * salinity + 99.5} When salinity is higher than 28%, crystallization starts.
The tolerable salinity for brine shrimps ranges from 8% (approximate color of 97) to 20% (approximate color of 93). 100 % of mortality rate is set to shrimps moving to the higher or lower saline area.
The brine shrimp population size constantly fluctuates due to salinity diffusion. The curves of shrimp populations have been smoothened to improve visualization.

Reference:

Great Salt Lake Ecosystem Program. Brine Shrimp. https://wildlife.utah.gov/gsl/brineshrimp/salinity.php

White, J., Null, S. E., & Tarboton, D. G. (2014). More than meets the eye-managing salinity in Great Salt Lake, Utah. Lakeline Magazine, 34(3), 25.

Wurtsbaugh, W., Miller, C., Null, S., Wilcock, P., Hahnenberger, M., & Howe, F. (2016). Impacts of water development on Great Salt Lake and the Wasatch Front. https://qcnr.usu.edu/pdfs/publications/Great%20Salt%20Lake%20Water%20Level_Feb%2024%202016.pdf

HOW TO USE IT

First press on "set up/reset simulation" and then click on "run/pause simulation."
Pull the bars on the sliders to adjust parameters while running the simulation.
Turn on/off the switches to show or hide shrimps.

THINGS TO NOTICE

When maximizing the surface inflows from all rivers, the mean salinity drops to around 6, representing the flooding scenario in the 1980s.
When minimizing the surface inflows from all rivers, the mean salinity increases to about 20.5. The temperature increase will further boost the mean.

THINGS TO TRY

Change the inflows from the rivers and north arm and observe how it affects the 1) average salinity and salinity gradient of the lake and 2) population size and distribution of brine shrimps.
Change the evaporation rate and observe how it affects the 1) average salinity and salinity gradient of the lake and 2) population size and distribution of brine shrimps.

CREDITS AND REFERENCES

This model is made by Dr. Lin Xiang at the University of Kentucky. If you mention this model in a publication, we ask that you include the citations below.

Xiang, L. (2021). Great Salt Lake. Department of STEM Education, University of Kentucky, Lexington, KY.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

;; Great Salt Lake
;;
;; Coded in 2017 by Lin Xiang; Last revised in 2021 by Lin Xiang (lxiang75@gmail.com; lin.xiang@uky.edu)
;;
;; If you mention this model in a publication, we ask that you include the citations below.
;;
;; Xiang, L. (2021). Great Salt Lake. Department of STEM Education, University of Kentucky, Lexington, KY.
;;
;;-----------------------------------------
;;CREATIVE COMMONS LICENSE
;;This code is distributed by Lin Xiang under a Creative Commons License:
;;Attribution-ShareAlike 4.0 International (CC BY-SA 4.0)
;;https://creativecommons.org/licenses/by-sa/4.0/
;;
;;-----------------------------------------

globals [sh gre]

breed [shrimps shrimp]
breed [salts salt]

to-report salinity
  report (pcolor - 99.5) / (-0.32)
end 

to-report tolerable-habitate
  report count patches with [pcolor >= 93 and pcolor <= 97] / count patches
end 

;===============================

to setup
ca
ask patches [set pcolor 95]
repeat 500
[
 Bearriver
 jordan-weber-river
 northarm
 evaporation
  diffuse pcolor 1
]

if show-shrimps? [

setup-shrimp
swim
]

set sh count shrimps

RESET-TICKS
end 

;==================================

to go
 tick

 Bearriver
 jordan-weber-river
 northarm
 evaporation
 diffuse pcolor 1

ifelse show-shrimps?
  [
    swim
    tolerance
    setup-shrimp
    thinning
  ]
 [ask shrimps [die]]


crystalization

smooth-line
end 

;--|Salinity|---------------------

to evaporation
  ask patches [ifelse pcolor >= 90
    [set pcolor (pcolor - ((Evaporation-Rate * 0.5) + 3) * 0.001) ]
    [set pcolor 89.9]
          ]
end 

to Bearriver
  ask patch (max-pxcor * 0.8) (max-pycor)
  [if Bear-river > 0 [
       ask patches in-radius ((((Bear-river * 0.34) + 1) ^ 2) * 0.4)
    [set pcolor 99.5]
  ]
  ]
end 

to jordan-weber-river
  ask patch (max-pxcor ) (min-pycor * 0.9)
  [if Jordan-and-Weber-Rivers > 0 [
       ask patches in-radius ((((Jordan-and-Weber-Rivers * 0.34) + 1) ^ 2) * 0.4)
    [set pcolor 99.5]
  ]]
end 

to northarm
   ask patch (min-pxcor * 0.85 ) (max-pycor)
   [if North-Arm > 0
     [ask patches in-radius North-Arm
    [set pcolor 90.5]
   ]]
end 

to crystalization
  ask patches [if pcolor < 90 [sprout-salts 1 [set color white set size 1 set shape "tile water"]]]
  ask salts [if pcolor >= 90 [die]]
end 

;---|Brine Shrimp|--------------------------

to setup-shrimp
  ask patches with [pcolor >= 93 and pcolor <= 97]
[if not any? shrimps-here[
  sprout-shrimps 1 [
    set color 28
    set size 1
    set shape "b-shrimp-1"
    ]]]
end 

to swim
  ask shrimps [
   rt random-float 45 fd 1
 ]
end 

to tolerance
  ask shrimps [if abs (pcolor - 95) > 2 [die]]
end 

to thinning
  ask patches [
    let num-here count shrimps-here
    if num-here > 1 [
      ask n-of (num-here - 1) shrimps-here [die]]]
end 


;---|Supportive procedure|------------------

to smooth-line
  set sh sh * 0.9 + ( 1 - 0.9 ) * count shrimps
end

There are 3 versions of this model.

Uploaded by	When	Description	Download
lin xiang	over 3 years ago	Add procedure to thin shrimp population	Download this version
lin xiang	over 3 years ago	Update the model info	Download this version
lin xiang	over 3 years ago	Initial upload	Download this version

Attached files

File	Type	Description	Last updated
Great Salt Lake.png	preview	Preview for 'Great Salt Lake'	over 3 years ago, by lin xiang	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo