sex-ratio-equilibrium

No preview image

1 collaborator

My_photo_2 Sugat Dabholkar (Author)

Tags

evolution 

Tagged by Sugat Dabholkar over 2 years ago

Model group MAM-2016 | Visible to everyone | Changeable by everyone
Model was written in NetLogo 6.0-M5 • Viewed 311 times • Downloaded 19 times • Run 0 times
Download the 'sex-ratio-equilibrium' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


## WHAT IS IT

This is the first model in a series of NetLogo models about population dynamics, population genetics and evolutionary biology developed by Sugat Dabholkar for the Designing & Constructing Models With Multi-Agent Languages, a course offered by Prof. Uri Wilensky at the School of Education and Social Policy in the Northwestern University.

The core phenomenon that is modeled is the sex-ratio equilibrium in sexually reproducing organisms. Most of the sexually reproducing organisms have sex-ratio 1:1. Fisher (1930) explained the rational based on natural selection, irrespective of particular mechanism of sex-determination, which is known as Fisher’s first principle (Hamilton, 1967).

This model is based on the Fisher's assumptions of biparentism and Mendelian inheritance.

It captures emergence of Fisherian Sex Ratio (1:1) for a wide range of initial sex-ratios.

## HOW IT WORKS

This is a population dynamics model, where individuals mate, give birth, die. The demographics changes in total population and sex ratio are captured in the model.

There are two types of individuals in the model:

Males (Indicated by green color)

Females (Indicated by blue color if not carrying a child and indicated by orange color if carrying a child)

At every time-step the individuals:

Age and check if dead - probability of dying increases with age

Move

Search-a-partner – (Only males). This procedure involves mating, which is dependent on mating-chance. If agents mate, the female carries. (For simplicity, mating chance incorporate conception-chance as well.)

Reproduce – (Only for females)

Each male and female carries a trait called male-child-chance. This determines the probability of a child being male. In this basic model, the sex of child is equally influenced by both the parents.

A child inherits this trait from its parents with a mutation. The mutation is implemented by choosing the value for the trait from a random-normal distribution with mean equal to average of male-child-chance of the parents.

## HOW TO USE IT

Click the SETUP button to set up the population.

You can use sliders to choose the following parameters when you SETUP.

INI-NUMBER : initial number of individuals in the population.

INI-SEX-RATIO : initial female-proportion in the population

INI-AVERAGE-MALE-CHILD-CHANCE : initial average male child chance of all the individuals in the population

GESTATION-PERIOD : number of 'ticks' a female is going to carry a child

MAX-LITTER-SIZE : maximum number of children a female would give birth to after she completes gestation

LONGEVITY : maximum 'ticks' an individual lives

MATING-CHANCE : probability that a female mates with a male when a male finds a female partner

Click the GO button to start the simulation.

## THINGS TO NOTICE

When you run the model, notice how the number of males and the number of females vary in the GENDER DISTRIBUTION plot. Also, notice that for a wide range of parameter values, the female proportion converges to 50% as seen in the FEMALE-PROPORTION plot.

The plot AVERAGE-MALE-CHILD-CHANCE plots average value of the trait male-child-chance across all agents. This value also converges to 0.5 for a wide range of parameters.

## THINGS TO TRY

Change the parameters and see if you can get to a different stable sex ratio.

## EXTENDING THE MODEL

This model implements search of partner by a male, see if you can change it and make it a female action. You can add a variety of features related to evolutionary population genetics and sex ratio equilibrium studies, such as different mortality rates for males and females, sexual selection by females.

## RELATED MODELS

Red Queen, Fish Tank Genetic Drift, Plant Speciation

## CREDITS AND REFERENCES

Hamilton, W. D. (1967). Extraordinary sex ratios. Science, 156(3774), 477-488

Fisher, R. A. (1930). The genetical theory of natural selection: a complete variorum edition. Oxford University Press.

## COPYRIGHT AND LICENSE

Copyright 2006 Uri Wilensky.

![CC BY-NC-SA 3.0](http://ccl.northwestern.edu/images/creativecommons/byncsa.png)

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  sex-ratio-list  ;; global-variable to track time-series data (for behavior space experiment)
  ]
breed [males male]
breed [females female]

females-own [
  partner                ;; a variable to temporary store a mating-partner
  carrying?              ;; a boolean to track if a female is carrying a child after mating
  male-child-chance      ;; this is a trait veriable that influences the probability of giving birth to a male child
  temp-male-child-chance ;; a variable to store male-chind-chance for a particular father-mother pair
  gestation              ;; a veriable to track time of carrying a child till a female reachers gesatation-period
  age                    ;; a veriable to keep track of age
]

males-own [
  partner               ;; a variable to temporary store a mating-partner
  male-child-chance     ;; this is a trait veriable that influences the probability of giving birth to a male child
  age                   ;; a veriable to keep track of age
]

;;set-up pupulation of males and females

to setup
  ca
  create-males round ( ( 1 - ini-sex-ratio ) * ini-number ) [
    setxy random-xcor random-ycor
    set shape "male"
    set color green
    set male-child-chance random-normal ini-average-male-child-chance 0.1    ;; males are assinged initial male-child-chance from a random-normal distribution
    set age 0
    set partner nobody
  ]
  create-females round ( ini-sex-ratio * ini-number ) [
    setxy random-xcor random-ycor
    set color blue
    set shape "female"
    set carrying? false
    set partner nobody
    set male-child-chance random-normal ini-average-male-child-chance 0.1  ;; females are assinged initial male-child-chance from a random-normal distribution
  ]
  set sex-ratio-list []
  reset-ticks
end 

to go
  if not any? turtles [stop]
  ask males [
    check-if-dead
    move
    search-a-partner
  ]
  ask females [
    check-if-dead
    if not carrying? [move]
    reproduce
  ]
  update-sex-ratio-list
  tick
end 

to move
    rt random 60
    lt random 60
    fd 1
end 

to search-a-partner  ;; a male procedure
  if count females in-radius 1 with [not carrying?] = 1 and count other males in-radius 1 = 0  [  ;; spatial restriction is used to incorporate density-dependant growth rate
    set partner one-of females in-radius 1 with [not carrying?]                                   ;; this is a common emperically validated assumpotion in many evolution models
    ]
    if partner = nobody [stop]
    ifelse [partner] of partner != nobody [
      set partner nobody
      stop                        ;; just in case two males find the same partner
    ]
    [
      ifelse random-float 1 < mating-chance [
        ask partner [
          set partner myself
          set carrying? true
          set color orange    ;; color oragne indicates carrying female
          set temp-male-child-chance ( male-child-chance + [male-child-chance] of myself ) / 2  ;; sex of a child is determined by male-child-chance (determined by father and mother)
        ]                                                                                       ;; this is a part of the fundamental assumption in Fisher's model
        set partner nobody                                                                      ;; autosomal inheritance of sex-determination-mechanism
      ]
      [
        set partner nobody
      ]
    ]
end 

to reproduce     ;; a female procedure
    if carrying? [
      ifelse gestation = gestation-period [   ;; genstation-period can be set. When it's over, a female gives birth to a a child, starts afrest and can have a new partner
        set gestation 0
        set carrying? false
        set color blue
        set partner nobody
        repeat random max-litter-size + 1 [
          ifelse random-float 1 < temp-male-child-chance [
            hatch 1 [
              set breed males
              set shape "male"
              set color green
              set male-child-chance random-normal [temp-male-child-chance] of myself 0.1  ;; inheritance of male-child-chance is also determined by father and mother.
              set age 0
            ]
          ][
          hatch 1 [
            set male-child-chance random-normal temp-male-child-chance 0.1
            set age 0
          ]
          ]
        ]
      ][
      set gestation gestation + 1
      ]
    ]
end 

to check-if-dead
    ifelse random-float longevity < age [       ;; With age probability of dying increases
      die
    ][
    set age age + 1
    ]
end 

;; reporting procedures for plotting and for behaviorspace experiments

to-report female-percentage
  ifelse any? turtles [
    report ( count females / count turtles ) * 100
  ]
  [
    report 0
  ]
end 

to-report average-male-child-chance
  ifelse any? turtles [
    report mean [male-child-chance] of turtles
  ]
  [
    report 0
  ]
end 

to update-sex-ratio-list
  if ticks > 10000 [
    set sex-ratio-list lput female-percentage sex-ratio-list
  ]
end 

to-report average-sex-ratio
    ifelse length sex-ratio-list > 0 [
    report precision mean sex-ratio-list 2]
    [report 0]
end 

to-report sd-sex-ratio
    ifelse length sex-ratio-list > 0 [
    report precision standard-deviation sex-ratio-list 2]
    [report 0]
end 

There are 2 versions of this model.

Uploaded by When Description Download
Sugat Dabholkar over 2 years ago Revised final version of the model Download this version
Sugat Dabholkar over 2 years ago Initial upload Download this version

Attached files

File Type Description Last updated
SugatDabholkar-Firehose-Presentation.pdf pdf Firehose Presentation for the MAM-16 class over 2 years ago, by Sugat Dabholkar Download

This model does not have any ancestors.

Children:

Graph of models related to 'sex-ratio-equilibrium'