Turbulence

Turbulence preview image

2 collaborators

Uri_dolphin3 Uri Wilensky (Author)
Eytan Bakshy (Author)

Tags

chemistry and physics 

Tagged by Reuven M. Lerner about 9 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 223 times • Downloaded 26 times • Run 0 times
Download the 'Turbulence' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model demonstrates the transition from order, or "laminarity", to disorder, or "turbulence" in fluids. Using a one-dimensional continuous cellular automaton, this model allows you to explore the relationship between turbulence, laminarity, and the viscosity of a fluid flowing through a "pipe." It also shows you how the roughness of pipes in which the fluid travels through affects the fluid's behavior.

HOW IT WORKS

This model is based on a "coupled map lattice," otherwise known as a continuous cellular automaton. See CA 1D Elementary for an introduction to one-dimension cellular automata, and see CA 1D Continuous for an introduction to continuous CA's.

Each cell has a value ranging continuously from 0 to 1.5, where 0 is the greatest degree of turbulence, and 1.5 is the greatest degree of laminarity. Cells are considered laminar when their value is greater than 1, and turbulent when their value is less than or equal to 1.

To draw each subsequent row, each cell in the previous row is updated in three steps:

1) The first step is coupling, where the cell's value "diffuses," or is averaged with its nearest neighbors on each side. The degree of influence that the cells have on one another is determined by the COUPLING-STRENGTH slider. The higher the value of the coupling strength, the more the cells will influence one another. COUPLING-STRENGTH is a rough analog of viscosity.

2) In the second step, another function is applied in order to properly scale the result of the coupling function.

3) The third and last step is the application of friction, which is the analog of roughness (on, for instance, the inside of a pipe or the surface of a sheet of glass). The ROUGHNESS parameter controls the amount of friction imposed upon the fluid, increasing the cell's turbulence. This may seem a bit strange, but it is important to remember turbulence is measured in terms of disorder; when the fluid's velocity is changed, these fluctuations cause more disorder.

These steps are then repeated for the next row, and so on.

HOW TO USE IT

Setup:

  • SETUP initializes the model with a mix of turbulent and non-turbulent initial conditions.
  • INITIAL-TURBULENCE controls the degree of initial turbulence.

Parameters:

  • COUPLING-STRENGTH is the amount of "diffusion," or the influence that cells have on one another.
  • ROUGHNESS is the amount of turbulence that is added to each cell at every time step.
  • DISPLAY-CONTINUOUS? will display state values as a gradient from dark to light (laminar and turbulent, respectively) if on, otherwise they will discretized and displayed as either black and white.

Running the model:

  • If AUTO-CONTINUE? is off, GO runs the model until it reaches the bottom (min-pycor). If pressed again, GO will continue the same run at the top row of patches. If AUTO-CONTINUE? is on, upon reaching the bottom row of patches, GO will immediately continue the run from the top.
  • AUTO-CONTINUE? will cause GO to automatically wrap back to the top and continue when switched on. If the model has reached a completely laminar state, and cannot produce any more turbulence, it will not run again.

THINGS TO NOTICE

Under what circumstances do darker, more "laminar" patches occur? How is this dependent on the turbulence?

Why do straight, non-budding turbulent streams eventually die out when ROUGHNESS is set to 0? How come this doesn't occur so much when ROUGHNESS is greater than 0?

THINGS TO TRY

Set ROUGHNESS to 0:

Change the COUPLING STRENGTH until you find the "critical value" that the COUPLING-STRENGTH must be above in order to produce long-lived turbulence. This transition is very fast, and occurs within a very small range of the COUPLING-STRENGTH parameter.

When the COUPLING-STRENGTH is above the critical value, what change do you see that might explain why the turbulence is able to perpetuate itself so well?

With a COUPLING-STRENGTH above the critical value, about how much INITIAL-TURBULENCE is required for the turbulence to continue indefinitely?

What happens when the COUPLING-STRENGTH is too high? Can you give a physical interpretation of this?

Think about these questions while experimenting with ROUGHNESS values above 0:

How does ROUGHNESS affect turbulence in the fluid?

How does ROUGHNESS affect the critical value required for long-lived turbulence?

With higher ROUGHNESS values, is it necessary for there to be a certain amount of INITIAL-TURBULENCE in order to produce long-lived turbulence? Why or why not?

Is there a difference between turbulence caused by large COUPLING-STRENGTHs and the turbulence caused by friction? If so, how do they differ?

Can you give a physical interpretation of a ROUGHNESS of 0?

EXTENDING THE MODEL

Although this is a continuous-valued CA, in a sense the system is discrete in that there is a sharp distinction between "turbulent" and "laminar" cells. If you modify the COLOR-PATCH procedure to color the cells only as black or white depending on which of these two discrete states they are in, you will see a discrete "view" of this continuous model.

In physical systems, "coupling strength" is a product of various factors, such as temperature, pressure, and viscosity. Can you come up with a way to take these factors into account in this model?

Surface tension is a subject common to fluid dynamics and turbulence. Can you figure out a way to integrate it into the model?

There are many ways to quantitatively analyze turbulence. Try coming up with a plot of the entropy (see 'CA Stochastic' for an example), or the average size of the laminar regions.

Can you create a turbulence model in two dimensions?

RELATED MODELS

  • CA 1D Elementary - the elementary two-state 1D cellular automata
  • CA Continuous - an elementary continuous 1D cellular automaton
  • CA Stochastic - a probabilistic cellular automaton that exhibits critical phase transitions similar to this model
  • Lattice Gas Automaton - two-dimensional wave propagation through a lattice gas
  • Wave Machine - wave motion in a two-dimensional membrane
  • Percolation - the percolation of oil through soil

CREDITS AND REFERENCES

Criticality in cellular automata: H. Chate and P. Manneville. 1990 Physica D 45 122-135 Pattern Dynamics in Spatiotemporal Chaos: Kunihiko Kaneko. 1989 Physica D 34 1-41 Supertransients, spatiotemporal intermittency and stability of fully developed spatiotemporal chaos: Kunihiko Kaneko. 1990 Physics Letters A Vol 149, Number 2,3 Shepherd, Dennis G. 1965. Elements of Fluid Mechanics. Harcourt, Brace, & World, Inc., New York, NY.

Thanks to Eytan Bakshy for his work on this model.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

  • Wilensky, U. (2003). NetLogo Turbulence model. http://ccl.northwestern.edu/netlogo/models/Turbulence. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
  • Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

Copyright 2003 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals
[
  row      ;; this is the current row we are now calculating
  done?    ;; a flag set to allow you to press the go button multiple times
]

patches-own
[
  value    ;; this variable is a floating point number between 0 and 1.5
]


;; initializes patches and globals

to setup-general
  clear-patches
  set row max-pycor   ;; set the current row to the top
  set done? false
end 


;; set up a random initial condition, parameterized by initial-turbulence

to setup-random
  setup-general
  reset-ticks
  ;; randomize the values of the current row (top row in this case)
  ask patches with [pycor = row]
  [
    set value ((3 / 2) - ((random-float initial-turbulence) / 100 * (3 / 2)))
    color-patch
  ]
end 


;; this is called to copy the bottom row to the top row when the user presses
;; GO again

to setup-continue
  let value-list []
  if not done?  ;; make sure go has already been called
    [ stop ]

  ;; copy values from bottom row of patches to top row
  set value-list map [[value] of ?] sort patches with [pycor = row]
  setup-general
  foreach sort patches with [pycor = row]
  [
    ask ?
    [
      set value item (pxcor + max-pxcor) value-list
      color-patch
    ]
  ]
  set done? false
end 


;; main routine

to go
  let row-patches patches with [pycor = row]
  ;; if the end has been reached, continue from the top or stop
  if (row = min-pycor)
  [
    ifelse auto-continue?
    [
      ;; if we are stuck in an absorbing state, there is no reason to continue
      ifelse (roughness = 0.0
              and not any? row-patches with [value > 0 and value <= 1])
      [
        stop
      ]
      [
        set done? true
        display    ;; ensure everything gets drawn before we clear it
        setup-continue
        set row-patches patches with [pycor = row]
      ]
    ]
    [
      ifelse done?
      [
        ;; a run has already been completed, so continue with another
        setup-continue
        set row-patches patches with [pycor = row]
      ]
      [
        ;; otherwise just stop
        set done? true
        stop
      ]
    ]
  ]

  ask row-patches     ;; apply rule
  [
    calculate-next-value
    color-patch
  ]

  set row row - 1
  tick
end 


;; calculates and sets the value of the patch immediately below self.

to calculate-next-value  ;; patch procedure
  let patch-below (patch-at 0 -1)

  ;; coupling step: diffuse values
  let value-sum ([value] of (patch-at -1 0) + [value] of (patch-at 1 0))
  let new-value
        ((1 - coupling-strength) * value + ((coupling-strength / 2) * value-sum))

  ;; set variables
  ask patch-below [
    set value new-value
    ;; scale & apply roughness
    set value scale value - roughness
    ;; if we've subtracted too much, just set the value to 0
    if value < 0 [ set value 0 ]
  ]
end 

to-report scale [ x ]
  ifelse (x >= 0 and x <= 0.5)
    [ report 3 * x ]
    [
      ifelse (x > 0.5 and x <= 1)
        [ report 3 * (1 - x) ]
        [ report x ]
    ]
end 

to color-patch  ;; patch procedure
  set pcolor scale-color pink value 1.5 -1.5
end 


; Copyright 2003 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by When Description Download
Uri Wilensky over 9 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky almost 10 years ago Updated version tag Download this version
Uri Wilensky almost 10 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky over 10 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky over 12 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 12 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 12 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 12 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky over 12 years ago Model from NetLogo distribution Download this version
Uri Wilensky over 12 years ago Turbulence Download this version

Attached files

File Type Description Last updated
Turbulence.png preview Preview for 'Turbulence' over 9 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.