Gridlock Alternate

;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Variable declarations ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;

globals
[
  grid-x-inc  ;; the amount of patches in between two roads in the x direction
  grid-y-inc  ;; the amount of patches in between two roads in the y direction
  acceleration  ;; the constant that controls how much a car speeds up or slows down by if it is to accelerate or decelerate
  phase  ;; keeps track of the phase
  num-cars-stopped  ;; the number of cars that are stopped during a single pass thru the go procedure
  old-display-which-metric  ;; holds the value of display-which-metric for the last time through the go procedure

  ;; patch agentsets
  intersections  ;; agentset containing the patches that are intersections
  roads  ;; agentset containing the patches that are roads

  ;; string and list variables that hold data passed accumulated in the model run
  wait-data  ;; list that holds the average wait time of the cars for each pass through the go procedure
  stopped-data  ;; list that holds the number of stopped of the cars for each pass through the go procedure
  speed-data  ;; list that holds the average speed of the cars for each pass through the go procedure
  time-data  ;; list that holds the value of clock for each pass through the go procedure

  ;; variables for plotting client-defined metrics in the client plot
  current-client-metric  ;; the current metric that is being plotted in the client plot
  current-intersection-for-client-metric  ;; the intersection whose metric we are currently plotting in the client plot
  old-intersection-for-client-metric  ;; the last intersection for current-intersection-for-metric

  ;;quick start instructions variables
  quick-start  ;; the current quickstart instruction displayed in the quickstart monitor
  qs-item  ;; the index of the current quickstart instruction
  qs-items  ;; the list of quickstart instructions
]

turtles-own
[
  speed  ;; the speed of the turtle
  up-car?  ;; this will be true if the turtle moves downwards and false if it moves to the right
  wait-time  ;; the amount of time since the last time a turtle has moved
]

patches-own
[
  intersection?  ;; this is true if the patch is at the intersection of two roads
  accident?  ;; this is true if a crash has occurred at this intersection.  this will never be true for a non-intersection patch
  green-light-up?  ;; this is true if the green light is above the intersection.  otherwise, it is false.  this is only true for patches that are intersections.
  my-row  ;; this holds the row of the intersection counting from the upper left corner of the View.  it is -1 for patches that are not intersections.
  my-column  ;; this holds the column of the intersection counting from the upper left corner of the View.  it is -1 for patches that are not intersections.
  user-id  ;; this holds the user-id that corresponds to the intersection.  it is -1 for patches that are not intersections.
  my-phase  ;; this holds the phase for the intersection.  it is -1 for patches that are not intersections.

  ;; client plot variables
  ;; this is a list of the values generated by the my-plot-metric that
  ;; will be plotted when this intersection's metric is plotted in the client plot
  my-plot-data
  ;; this is NetLogo code generates values for this intersection's values for my-plot-data.
  ;; the code should be a meaningful metric of how to measure traffic efficiency.
  my-plot-metric
]


;;;;;;;;;;;;;;;;;;;;;
;; Setup Functions ;;
;;;;;;;;;;;;;;;;;;;;;

to startup
  setup
  setup-quick-start
  hubnet-reset
end 

;; Initialize the display by giving the global and patch variables initial values.
;; Create num-cars of turtles if there are enough road patches for one turtle to be created per road patch.
;; Setup the plots
;; All code in setup is done if full-setup? is true.  If it is false, then it doesn't clear the information
;; about the users; users still retain the same light that they had before.
;; "setup false" is done by the re-run button.

to setup
  clear-output
  clear-turtles
  clear-all-plots

  let full-setup? ((grid-x-inc != (world-width / grid-size-x))
      or (grid-y-inc != (world-height / grid-size-y)))

  setup-globals

  ;; we only re-layout the grid if the sizes changed
  ifelse full-setup?
  [
    ;; if we have clients logged in we want to make sure to
    ;; keep the appropriate info around
    let users map [[user-id] of ?] sort patches with [is-string? user-id]
    let plot-metrics map [[my-plot-metric] of ?] sort patches with [is-string? user-id]
    let phases map [[my-phase] of ?] sort patches with [is-string? user-id]
    clear-patches
    setup-patches
    setup-intersections
    ;; reassign the clients to intersections
    (foreach users plot-metrics phases
    [
      get-free-intersection ?1
      ask intersections with [ user-id = ?1 ]
      [
        set my-plot-metric ?2
        set my-phase ?3
      ]
    ])
  ]
  [ setup-intersections ]

  set-default-shape turtles "car"

  if (number > count roads)
  [
    user-message (word "There are too many cars for the amount of road.  "
    "Either increase the amount of roads by increasing the GRID-SIZE-X "
    "or GRID-SIZE-Y sliders, or decrease the number of cars by lowering "
    "the NUMBER slider.\nThe setup has stopped.")
    stop
  ]

  ;; Now create the turtles and have each created turtle call the functions setup-cars and set-car-color
  crt number
  [
    setup-cars
    set-car-color
    record-data
  ]

  ;; give the turtles an initial speed
  ask turtles
  [ set-car-speed ]

  update-list-info

  my-setup-plots
end 

;; Initialize the global variables to appropriate values

to setup-globals
  reset-ticks
  set phase 0
  set num-cars-stopped 0
  set grid-x-inc world-width / grid-size-x
  set grid-y-inc world-height / grid-size-y

  ;; initialize the lists and string for HubNet
  set wait-data []
  set stopped-data []
  set speed-data []
  set time-data []

  set current-client-metric ""
  set current-intersection-for-client-metric nobody
  set old-intersection-for-client-metric nobody

  ;; don't make acceleration 0.1 since we could get a rounding error and end up on a patch boundary
  set acceleration 0.099
end 

;; Make the patches have appropriate colors, setup the roads and intersections agentsets,
;; and initialize the traffic lights to one setting

to setup-patches
  ;; initialize the patch-own variables and color the patches to a base-color
  ask patches
  [
    set intersection? false
    set accident? false
    set green-light-up? true
    set my-row -1
    set my-column -1
    set user-id -1
    set my-phase -1
    set my-plot-data []
    set my-plot-metric ""

    set pcolor brown + 3
  ]

  ;; initialize the global variables that hold patch agentsets
  set roads patches with [ (floor ((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) or
                           (floor ((pycor + max-pycor) mod grid-y-inc) = 0) ]
  set intersections roads with [ (floor ((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0) and
                                 (floor ((pycor + max-pycor) mod grid-y-inc) = 0) ]

  ask roads
  [ set pcolor white ]
end 

;; Give the intersections appropriate values for the intersection?, my-row, and my-column
;; patch variables.  Make all the traffic lights start off so that the lights are red
;; horizontally and green vertically.

to setup-intersections
  ask intersections
  [
    set intersection? true
    set green-light-up? true
    set my-plot-data []
    set my-row floor ((pycor + max-pycor) / grid-y-inc )
    set my-column floor ((pxcor + max-pxcor) / grid-x-inc )
    set-signal-colors
  ]
end 

;; Initialize the turtle variables to appropriate values and place the turtle on an empty road patch.

to setup-cars  ;; turtle procedure
  set speed 0
  set wait-time 0

  put-on-empty-road

  ifelse intersection?
  [
    ifelse random 2 = 1
    [ set up-car? true ]
    [ set up-car? false ]
  ]
  [
    ifelse (floor ((pxcor + max-pxcor - floor(grid-x-inc - 1)) mod grid-x-inc) = 0)
    [ set up-car? true ]
    [ set up-car? false ]
  ]

  ifelse up-car?
  [ set heading 180 ]
  [ set heading 90 ]
end 

;; Find a road patch without any turtles on it and place the turtle there.

to put-on-empty-road  ;; turtle procedure
  move-to one-of roads
  if any? other turtles-here
  [ put-on-empty-road ]
end 

;; Initialize the plots

to my-setup-plots
  set-current-plot "Stopped Cars"
  set-plot-y-range 0 number
  plot num-cars-stopped

  set-current-plot "Average Wait Time of Cars"
  plot mean [wait-time] of turtles

  set-current-plot "Average Speed of Cars"
  set-plot-y-range 0 speed-limit
  plot mean [speed] of turtles
end 

;;;;;;;;;;;;;;;;;;;;;;;
;; Runtime Functions ;;
;;;;;;;;;;;;;;;;;;;;;;;

;; receives information from the clients and runs the simulation

to go
  every delay
  [
    ;; get commands and data from the clients
    listen-clients

    ;; clear any accidents from the last time thru the go procedure
    clear-accidents

    ;; if there are any intersections that are to switch automatically, have them change their color
    set-signals
    set num-cars-stopped 0

    ;; set the turtles speed for this time thru the procedure, move them forward their speed,
    ;; record data for plotting, and set the color of the turtles
    ;; to an appropriate color based on their speed
    ask turtles
    [
      set-car-speed
      fd speed
      record-data
      set-car-color
    ]
    ;; crash the cars if crash? is true
    if crash?
    [ crash-cars ]

    ;; update the information in the lists of plot data
    update-list-info

    ;; update the plots with the new information from this pass thru the procedure
    do-plotting
    ;; update the clock and the phase
    clock-tick
  ]
end 

;; reports the amount of seconds by which to slow the model down

to-report delay
  ifelse simulation-speed <= 0
  [ report ln (10 / 0.001) ]
  [ report ln (10 / simulation-speed) ]
end 

;; have the traffic lights change color if phase equals each intersections' my-phase

to set-signals
  ask intersections with
      [phase = floor ((my-phase * ticks-per-cycle) / 100) and (auto? or user-id = -1)]
  [
    set green-light-up? (not green-light-up?)
    set-signal-colors
  ]
end 

;; This procedure checks the variable green-light-up? at each intersection and sets the
;; traffic lights to have the green light up or the green light to the left.

to set-signal-colors  ;; intersection (patch) procedure
  ifelse power?
  [
    ifelse green-light-up?
    [
      ask patch-at -1 0 [ set pcolor red ]
      ask patch-at 0 1 [ set pcolor green ]
    ]
    [
      ask patch-at -1 0 [ set pcolor green ]
      ask patch-at 0 1 [ set pcolor red ]
    ]
  ]
  [
    ask patch-at -1 0 [ set pcolor white ]
    ask patch-at 0 1 [ set pcolor white ]
  ]
end 

;; set any intersection's color that had an accident back to white and make accident? false

to clear-accidents
  if crash?
  [
    ask patches with [accident?]
    [
      set pcolor white
      set accident? false
    ]
  ]
end 

;; set the turtles' speed based on whether they are at a red traffic light or the speed of the
;; turtle (if any) on the patch in front of them

to set-car-speed  ;; turtle procedure
  ifelse pcolor = red
  [ set speed 0 ]
  [
    ifelse up-car?
    [ set-speed 0 -1 ]
    [ set-speed 1 0 ]
  ]
end 

;; set the speed variable of the turtle to an appropriate value (not exceeding the
;; speed limit) based on whether there are turtles on the patch in front of the turtle

to set-speed [delta-x delta-y]  ;; turtle procedure

  let turtles-ahead turtles-on patch-at delta-x delta-y

  ;; if there are turtles in front of the turtle, slow down
  ;; otherwise, speed up
  ifelse any? turtles-ahead
  [
    let up-cars?-ahead [up-car?] of turtles-ahead
    ifelse member? up-car? up-cars?-ahead and member? (not up-car?) up-cars?-ahead
    [
      if not crash?
      [ set speed 0 ]
    ]
    [
      set speed [speed] of one-of turtles-ahead
      slow-down
    ]
  ]
  [ speed-up ]
end 

;; decrease the speed of the turtle

to slow-down  ;; turtle procedure
  ifelse speed <= 0  ;;if speed < 0
  [ set speed 0 ]
  [ set speed speed - acceleration ]
end 

;; increase the speed of the turtle

to speed-up  ;; turtle procedure
  ifelse speed > speed-limit
  [ set speed speed-limit ]
  [ set speed speed + acceleration ]
end 

;; set the color of the turtle to a different color based on how fast the turtle is moving

to set-car-color  ;; turtle procedure
  ifelse speed < (speed-limit / 2)
  [ set color blue ]
  [ set color cyan - 2 ]
end 

;; keep track of the number of stopped turtles and the amount of time a turtle has been stopped
;; if its speed is 0

to record-data  ;; turtle procedure
  ifelse speed = 0
  [
    set num-cars-stopped num-cars-stopped + 1
    set wait-time wait-time + 1
  ]
  [ set wait-time 0 ]
end 

;; crash any turtles at the same intersection going in different directions

to crash-cars
  ask intersections with [any? turtles-here with [up-car?] and any? turtles-here with [not up-car?]]
  [
    set accident? true
    set pcolor orange
  ]
end 

;; add the new information from this pass thru the go procedure to the HubNet lists

to update-list-info
  set wait-data lput (mean [wait-time] of turtles) wait-data
  set stopped-data lput num-cars-stopped stopped-data
  set speed-data lput (mean [speed] of turtles) speed-data
  set time-data lput ticks time-data
  ask intersections with [ my-plot-metric != "" ]
  [ add-new-client-metric-value ]
end 

;; verify that my-plot-metric is a valid metric that will result in a number
;; and add that number to the my-plot-data list for the intersection

to add-new-client-metric-value  ;; intersection procedure
  let err __check-syntax (word "plotxy clock " my-plot-metric)
  ifelse err = ""
  [
    let new-value run-result my-plot-metric
    ifelse is-number? new-value
    [
      set my-plot-data lput list ticks new-value my-plot-data
      hubnet-send user-id "Current Metric Value" new-value
    ]
    [
      hubnet-send user-id "metric-error-message" (word my-plot-metric
        " does not produce a numeric value.")
      clear-client-plot-data
    ]
  ]
  [
    hubnet-send user-id "metric-error-message" (word my-plot-metric
      " does not produce a numeric value.")
    clear-client-plot-data
  ]
end 

;; clears the intersection's plot data and the client plot if
;; current-intersection-for-metric is the intersection

to clear-client-plot-data  ;; intersection procedure
  set my-plot-metric ""
  set my-plot-data []
  hubnet-send user-id "Current Metric Value" ""
  if current-intersection-for-client-metric = self
  [
    set-current-plot "Client Plot"
    clear-plot
    set current-intersection-for-client-metric nobody
    set old-intersection-for-client-metric nobody
    set current-client-metric ""
  ]
end 

;; plot the data from this pass thru the go procedure

to do-plotting
  if current-intersection-for-client-metric != nobody
  [ update-client-plot ]
  ifelse display-which-metric = old-display-which-metric
  [
    ;; don't plot if no plots should be plotted
    if display-which-metric != 0
    [
      ;; we only need to plot 1 value since the current plot is the same as the plot we are supposed to plot to now
      ifelse display-which-metric = 1
      [ plot-new-value "Stopped Cars" num-cars-stopped ]
      [
        ifelse display-which-metric = 2
        [ plot-new-value "Average Speed of Cars" mean [speed] of turtles ]
        [
          ifelse display-which-metric = 3
          [ plot-new-value "Average Wait Time of Cars" mean [wait-time] of turtles ]
          [
            ;; therefore display-which-metric = 4
            plot-new-value "Stopped Cars" num-cars-stopped
            plot-new-value "Average Wait Time of Cars" mean [wait-time] of turtles
            plot-new-value "Average Speed of Cars" mean [speed] of turtles
          ]
        ]
      ]
    ]
  ]
  [
    ;; otherwise, we need to plot at least 1 list since the plot we are supposed to plot to is different from the plot we last plotted in
    ifelse display-which-metric = 0
    [ clear-all-non-client-plot ]
    [
      ifelse display-which-metric = 1
      [ clear-plots-and-plot-in-new-plot "Stopped Cars" stopped-data ]
      [
        ifelse display-which-metric = 2
        [ clear-plots-and-plot-in-new-plot "Average Speed of Cars" speed-data ]
        [
          ifelse display-which-metric = 3
          [ clear-plots-and-plot-in-new-plot "Average Wait Time of Cars" wait-data ]
          [
            ;; therefore display-which-metric = 4
            ifelse old-display-which-metric = 1
            [ plot-value-and-lists "Stopped Cars" num-cars-stopped "Average Speed of Cars" speed-data "Average Wait Time of Cars" wait-data ]
            [
              ifelse old-display-which-metric = 2
              [ plot-value-and-lists "Average Speed of Cars" (mean [speed] of turtles) "Stopped Cars" stopped-data "Average Wait Time of Cars" wait-data ]
              [
                ifelse old-display-which-metric = 3
                [ plot-value-and-lists "Average Wait Time of Cars" (mean [wait-time] of turtles) "Stopped Cars" stopped-data "Average Speed of Cars" speed-data ]
                [
                  ;; therefore old-display-which-metric = 0
                  plot-new-list "Stopped Cars" stopped-data
                  plot-new-list "Average Speed of Cars" speed-data
                  plot-new-list "Average Wait Time of Cars" wait-data
                ]
              ]
            ]
          ]
        ]
      ]
    ]
    set old-display-which-metric display-which-metric
  ]
end 

;; update the client plot with the appropriate information

to update-client-plot
  let current-item []
  set-current-plot "Client Plot"
  ifelse current-intersection-for-client-metric != old-intersection-for-client-metric
  [
    clear-plot
    ;; update client plot with the new intersection's data
    ask current-intersection-for-client-metric
    [
      set current-client-metric my-plot-metric
      let index 0
      repeat length my-plot-data
      [
        set current-item item index my-plot-data
        plotxy first current-item last current-item
        set index index + 1
      ]
    ]
    set old-intersection-for-client-metric current-intersection-for-client-metric
  ]
  [
    ask current-intersection-for-client-metric
    [
      if length my-plot-data != 0
      [ plotxy first last my-plot-data last last my-plot-data ]
    ]
  ]
end 

;; clear all the plots that are not the client plot

to clear-all-non-client-plot
  set-current-plot "Stopped Cars"
  clear-plot
  set-current-plot "Average Speed of Cars"
  clear-plot
  set-current-plot "Average Wait Time of Cars"
  clear-plot
end 

to plot-new-value [name-of-plot value]
  set-current-plot name-of-plot
  plot value
end 

to clear-plots-and-plot-in-new-plot [name-of-plot list-to-plot]
  clear-all-non-client-plot
  plot-new-list name-of-plot list-to-plot
end 

to plot-new-list [name-of-plot list-to-plot]
  let index 0

  set-current-plot name-of-plot
  clear-plot
  repeat length list-to-plot
  [
    plot item index list-to-plot
    set index index + 1
  ]
end 

to plot-value-and-lists [value-plot value list-plot1 list-to-plot1 list-plot2 list-to-plot2]
  plot-new-value value-plot value
  plot-new-list list-plot1 list-to-plot1
  plot-new-list list-plot2 list-to-plot2
end 

;; increases the clock by 1 and cycles phase to the next appropriate value

to clock-tick
  tick
  ;; The phase cycles from 0 to ticks-per-cycle, then starts over.
  set phase phase + 1
  if phase mod ticks-per-cycle = 0
  [ set phase 0 ]
end 

;; update the plots to show the current value of display-which-metric
;; done only by the Refresh Plots button

to show-current-metric-in-plots
  if display-which-metric != old-display-which-metric
  [
    ;; we need to plot at least 1 list since the plot we are supposed to plot to is different from the plot we last plotted in
    ifelse display-which-metric = 0
    [ clear-all-non-client-plot ]
    [
      ifelse display-which-metric = 1
      [ clear-plots-and-plot-in-new-plot "Stopped Cars" stopped-data ]
      [
        ifelse display-which-metric = 2
        [ clear-plots-and-plot-in-new-plot "Average Speed of Cars" speed-data ]
        [
          ifelse display-which-metric = 3
          [ clear-plots-and-plot-in-new-plot "Average Wait Time of Cars" wait-data ]
          [
            ;; therefore display-which-metric = 4
            ifelse old-display-which-metric = 1
            [
              plot-new-list "Average Speed of Cars" speed-data
              plot-new-list "Average Wait Time of Cars" wait-data
            ]
            [
              ifelse old-display-which-metric = 2
              [
                plot-new-list "Stopped Cars" stopped-data
                plot-new-list "Average Wait Time of Cars" wait-data
              ]
              [
                ifelse old-display-which-metric = 3
                [
                  plot-new-list "Stopped Cars" stopped-data
                  plot-new-list "Average Speed of Cars" speed-data
                ]
                [
                  ;; therefore old-display-which-metric = 0
                  plot-new-list "Stopped Cars" stopped-data
                  plot-new-list "Average Speed of Cars" speed-data
                  plot-new-list "Average Wait Time of Cars" wait-data
                ]
              ]
            ]
          ]
        ]
      ]
    ]
    set old-display-which-metric display-which-metric
  ]
  if current-intersection-for-client-metric != old-intersection-for-client-metric
  [ update-client-plot ]
end 

;; set the current client plot's variable information

to set-current-client-metric-intersection [ intersection-to-plot ]
  set current-intersection-for-client-metric intersection-to-plot
  set current-client-metric [my-plot-metric] of intersection-to-plot
end 

;; select an intersection to plot its my-plot-metric in the client plot

to select-intersection-for-client-plot
  if mouse-down?
  [
    let current-patch patch mouse-xcor mouse-ycor
    if ([intersection?] of current-patch) and (-1 != [user-id] of current-patch)
    [
      set-current-client-metric-intersection patch mouse-xcor mouse-ycor
      stop
    ]
  ]
end 


;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Quick Start functions ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; instructions to quickly setup the model, and clients to run this activity

to setup-quick-start
  set qs-item 0
  set qs-items
  [
    "Teacher: Follow these directions to setup the HubNet activity."
    "Optional: Zoom In (see Tools in the Menu Bar)"
    "Change the traffic grid (using the sliders GRID-SIZE-X and..."
      "GRID-SIZE-Y) to make enough lights for everyone."
    "Change any other of the settings that you would like to change."
    "For example, if you plan on running Gridlock in..."
      "the MANUAL mode, be sure to have AUTO? set to OFF."
    "Press the SETUP button."
    "Press the LOGIN button."
    "Everyone: Open the HubNet Client on your machine and..."
      "input the IP Address of this computer, type your user name in..."
        "the user name box and press ENTER"
    "Teacher: Once everyone is logged in and has a light..."
      "stop the LOGIN button by pressing it again."
    "Everyone: Whichever mode AUTO? is set for in NetLogo,..."
      "you will control your intersection in a different way."
    "If you have chosen MANUAL,..."
      "you can change the state of your light by pressing..."
        "the CHANGE LIGHT button."
    "If you have chosen AUTO,..."
      "you can change the phase of your light by moving..."
        "the PHASE slider to a different position."
    "If you wish to keep track of your own metric,..."
      "input it in the metric-code input box."
    "Teacher: Once everyone is ready,..."
      "start the simulation by pressing the GO button."
    "Teacher: You may want to view some of the plots."
      "Do this by changing the DISPLAY-WHICH-METRIC slider,..."
        "which changes the plot displayed for everyone."
    "Choose 0 to turn off all the plots..."
      "Choose 1 to see the STOPPED CARS plot..."
        "Choose 2 for the AVERAGE SPEED plot..."
          "Choose 3 for the AVERAGE WAIT plot..."
            "or Choose 4 for all the plots..."

    "Teacher: To run the activity again with the same group,..."
      "stop the model by pressing the GO button, if it is on."
        "Change any of the settings that you would like."
          "Press the SETUP button."
    "Teacher: Once everyone is ready,..."
      "restart the simulation by pressing the GO button."

    "Teacher: To start the simulation over with a new group,..."
      "stop the model by pressing the GO button, if it is on..."
      "Press the RESET button in the Control Center..."
        "and follow these instructions again from the beginning."
  ]
  set quick-start (item qs-item qs-items)
end 

;; view the next item in the quickstart monitor

to view-next
  set qs-item qs-item + 1
  if qs-item >= length qs-items
  [ set qs-item length qs-items - 1 ]
  set quick-start (item qs-item qs-items)
end 

;; view the previous item in the quickstart monitor

to view-prev
  set qs-item qs-item - 1
  if qs-item < 0
  [ set qs-item 0 ]
  set quick-start (item qs-item qs-items)
end 


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Code for interacting with the clients ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; when a command is sent, find out which client sent it and then execute the command

to listen-clients
  while [hubnet-message-waiting?]
  [
    hubnet-fetch-message
    ifelse hubnet-enter-message?
    [
      give-intersection-coords
      wait 1  ;; we want to give some time for other clients to log in on this round
    ]
    [
      ifelse hubnet-exit-message?
        [ abandon-intersection ]
      [
        ifelse hubnet-message-tag = "Change Light"
          [ manual hubnet-message-source ]
        [
          ifelse hubnet-message-tag = "Phase"
            [ auto hubnet-message-source ]
          [
            if hubnet-message-tag = "metric-code"
              [ new-client-metric hubnet-message-source hubnet-message ]
          ]
        ]
      ]
    ]
  ]
end 

;; when a new client logs in, if there are free intersections,
;; assign one of them to that client
;; if this current-id already has an intersection, give the client that intersection.

to give-intersection-coords
  let current-id hubnet-message-source
  ifelse not any? intersections with [user-id = current-id]
  [
      ;; the case where they tried logging in previously but there was no room for them
      ;; or they haven't logged in before
      get-free-intersection current-id
  ]
  [
    ;; otherwise, we already have an intersection for the current-id.
    ;; all we need to do is send where the light is located at
    ask intersections with [user-id = current-id]
    [ hubnet-send current-id "Located At:" (word "(" my-column "," my-row ")") ]
  ]
end 

;; when a client disconnects, free up its intersection

to abandon-intersection
  ask intersections with [user-id = hubnet-message-source]
  [
    set user-id -1
    set my-phase 0
    ask patch-at -1 1 [ set plabel "" ]
    set my-plot-data []
    set my-plot-metric ""
    if current-intersection-for-client-metric = self
    [
      set current-client-metric ""
      set current-intersection-for-client-metric nobody
    ]
  ]
end 

;; if there are any free intersections, pick one of them at random and give it to the current-id.
;; if there are not any free intersections, toss an error and put error values into the list

to get-free-intersection [current-id]
  ifelse any? intersections with [user-id = -1]
  [
    ;; pick a random intersection that hasn't been taken yet
    ask one-of intersections with [user-id = -1]
    [
      set user-id current-id
      ask patch-at -1 1
      [
        set plabel-color black
        set plabel current-id
      ]
      hubnet-send current-id "Located At:" (word "(" my-column "," my-row ")")
    ]
  ]
  [
    hubnet-send current-id "Located At:" "Not enough lights"
    user-message word "Not enough lights for student with id: " current-id
  ]
end 

;; switch the traffic lights at the intersection for the client with user-id

to manual [current-id]
  if not auto?
  [
    ask intersections with [user-id = current-id]
    [
      set green-light-up? (not green-light-up?)
      set-signal-colors
    ]
  ]
end 

;; change the value of the phase for the intersection at (xc,yc) to
;; the value passed by the client

to auto [current-id]
  ask intersections with [user-id = current-id]
  [
    set my-phase hubnet-message
  ]
end 

;; change the metric to plot on the client plot for the client
;; if it is valid code to generate values to plot

to new-client-metric [ current-id new-metric ]
  ask intersections with [ user-id = current-id ]
  [
    let err __check-syntax (word "plotxy ticks " new-metric)
    ;; don't send an error message if the client sent the empty string
    if new-metric != ""
    [
      hubnet-send user-id "metric-error-message" err
      hubnet-send user-id "Current Metric Value" ""
    ]
    ifelse err = ""
    [
      hubnet-send user-id "Current Metric Value" ""
      set my-plot-metric new-metric
      set my-plot-data []
      if current-intersection-for-client-metric = self
      [
        set-current-plot "Client Plot"
        clear-plot
        set current-client-metric my-plot-metric
      ]
    ]
      [ clear-client-plot-data ]
  ]
end 

;; report the user-id of current-intersection-for-metric or the empty string if it is nobody

to-report user-id-of-intersection-for-current-metric
  ifelse current-intersection-for-client-metric = nobody or not is-patch? current-intersection-for-client-metric
  [ report "" ]
  [ report [user-id] of current-intersection-for-client-metric ]
end 


; Copyright 2002 Uri Wilensky and Walter Stroup.
; See Info tab for full copyright and license.