Movement of Unskilled Workers

globals [ business-cycle-count wage-cycle costs-cycle unemployed-list ]

turtles-own [ wage expenditures unemployed? ]

patches-own [ average-wage original-wage average-costs original-costs original-available-jobs available-jobs city-num]

to setup
  ca
  ask n-of number-cities patches [ ;setting up cities
    set pcolor red 
    set average-costs random 10
    set original-costs average-costs
    ;set average-wage random 10
    set average-wage random-float random-wage-cost-seed + original-costs ;setting staring wage to be at least greater than the costs
    set original-wage average-wage
    set original-available-jobs random 20 + 1
    set available-jobs original-available-jobs
    set city-num 0
    ] ;assign it a different color
  set business-cycle-count 0
  let counter 1
  while [ counter < number-cities + 1 ] [ ; workaround to set each city a different number label "city-num"
    ask one-of patches with [ pcolor = red and city-num = 0 ] [ set city-num counter ]
    set counter counter + 1 
  ] 
  create-turtles number-workers [ ;worker setup
    setxy random-xcor random-ycor 
    set wage random 10
    set expenditures random 10
    set shape "person"
    face one-of patches with [ pcolor = red and available-jobs > 0] 
    set unemployed? false ]
  set unemployed-list (list 0)
  setup-available-job-plot
  setup-attractive-city-plot
  setup-business-cycle-plot
  update-available-job-plot
  update-attractive-city-plot
  update-business-cycle-plot
end 

to go
  ask turtles [ 
    update-worker-parameters
    stay-or-go ]
  
  ask patches with [ pcolor = red ] [ update-city-parameters move-too-many-workers]
  update-business-cycle
  tick
  update-available-job-plot
  update-attractive-city-plot
  set business-cycle-count business-cycle-count + 1 ;updating the tick counter so the business cycle can change over time
  update-business-cycle-plot
end 

to update-city-parameters ; patch function
  ; used to change the wages and costs at the given city. each worker at that city adds a cost-increase to costs and removes a wage-decrease from wages
  ; here is also where the wages and costs are scaled to account for the business cycles
   set available-jobs ( original-available-jobs - ( count turtles-here ) )
   ifelse apply-business-cycle? [
     set average-wage ( original-wage - ( ( original-available-jobs - available-jobs ) * wage-decrease-per-additional-worker ) ) * wage-cycle
     set average-costs ( original-costs + ( ( original-available-jobs - available-jobs ) * cost-increase-per-additional-worker ) ) * costs-cycle] 
   [ set average-wage ( original-wage - ( ( original-available-jobs - available-jobs ) * wage-decrease-per-additional-worker ) )
     set average-costs ( original-costs + ( ( original-available-jobs - available-jobs ) * cost-increase-per-additional-worker ) )]
end 

to update-worker-parameters ; turtle function
  set wage [ average-wage ] of patch-here
  set expenditures [ average-costs ] of patch-here
end 

to move-too-many-workers ; patch function
  let num-movers (-1 * ( original-available-jobs - (count turtles-here) ) ) ;finding the number of workers that need to leave this city
  if num-movers < 0 [ set num-movers 0 ] ; must be a positive number
  let temp one-of patches with [ pcolor = red and available-jobs > 0 ]
  if is-patch? temp [ ifelse [ average-wage ] of temp - [ average-costs ] of temp - wage-decrease-per-additional-worker + cost-increase-per-additional-worker > 0 [ ] [ set temp 0 ] ]
  ; if the patch where they want to go can hold them there, then they can go, or else try again another time
  if ( pcolor = red and available-jobs < 0 ) or ( pcolor = red and ( average-wage - average-costs ) < 0 ) [ ask n-of num-movers turtles-here [ ifelse is-patch? temp [ move ] [ go-unemployed ]] ]
  ; if there are no available jobs at your current city or you're paying more in costs than you're earning, then you have to leave. if there's nowhere else that satisfies that
  ; then you become unemployed
end 

to go-unemployed ; turtle function
  set unemployed? true
  face one-of patches with [ pycor > 10 ] move
end 

to stay-or-go ; turtle function
  let temp one-of patches with [ pcolor = red and available-jobs > 0 and ( average-wage - average-costs > 0 ) ] ;find a suitable new city
  ifelse unemployed? [ if is-patch? temp [ face temp move ] set unemployed? false] [ ] ; if you are unemployed face this suitable city and move to it and become employed
  if [ pcolor ] of patch-here != red and not unemployed? [ move ] ; if you're not at a city but aren't unemployed then keep moving to the city you had turned to face
  if ( [ pcolor ] of patch-here = red and ( wage - expenditures ) < 0 ) [ if is-patch? temp or is-patch-set? temp [face temp move ] ] ;if you can't sustain your lifestyle at your current city, leave
  if [ pcolor ] of patch-here = red and ( wage - expenditures ) > 0 [ ] ; stay if you can sustain
end 

to stay ;turtle function
end 

to move ;turtle function
  fd 1
end 

to update-business-cycle
  set wage-cycle cos ( business-cycle-count * 0.1 ) + 1.03 * business-cycle-count * 0.0005 + .15 ; bunch of scaling here to get the correct business cycle
  set costs-cycle 1.03 * business-cycle-count * 0.0005 ; no cosine function for costs-cycle
end 

to setup-available-job-plot
  set-current-plot "Available Jobs"
  set-plot-y-range 0 ( [original-available-jobs ] of max-one-of patches [ original-available-jobs ] + 3)
  let counter 1
  while [ counter < number-cities + 1 ] [ ;plot all the cities (which is a slider variable). this is a workaround
    create-temporary-plot-pen word "City " counter 
    set-current-plot-pen word "City " counter
    set-plot-pen-color one-of base-colors 
    set counter counter + 1 ]
end 

to update-available-job-plot
  set-current-plot "Available Jobs"
  let counter 1
  while [ counter < number-cities + 1 ] [
    set-current-plot-pen word "City " counter 
    plot first [ available-jobs ] of patches with [ city-num = counter ]
    set counter counter + 1 ]
end 

to setup-business-cycle-plot
  set-current-plot "Business Cycle"
end 

to update-business-cycle-plot
  if apply-business-cycle? [
    set-current-plot "Business Cycle"
    set-current-plot-pen "wage-cycle"
    plot wage-cycle
    set-current-plot-pen "costs-cycle"
    plot costs-cycle
    set-current-plot-pen "unemployed"
    plot count turtles with [ unemployed? ] 
    set unemployed-list lput count turtles with [ unemployed? ] unemployed-list ] ; adding the list together for the BehaviorSpace model
end 

to setup-attractive-city-plot
  set-current-plot "Most Attractive City"
end 

to update-attractive-city-plot
  set-current-plot "Most Attractive City"
  set-current-plot-pen "attractive-wages"
  let temp max-one-of patches [ original-wage - original-costs ] ; city that is most attractive
  plot [ average-wage ] of temp
  set-current-plot-pen "attractive-expenditures"
  plot [ average-costs ] of temp
  set-current-plot-pen "least-attractive-wages"
  set temp min-one-of patches with [ pcolor = red ] [ original-wage - original-costs ] ; city that is least attractive
  plot [ average-wage ] of temp
  set-current-plot-pen "least-attractive-expenditures"
  plot [ average-costs ] of temp
end