Excitable Media

1 collaborator

WHAT IS IT?

This is an excitable media cellular automaton model described in Daniel Kaplan and Leon Glass (1995), "Understanding Nonlinear Dynamics", Springer-Verlag, New York.

HOW IT WORKS

Each patch (cell) is in one of three states:

Quiescent
Excited
Refractory

As explained by Kaplan and Glass (1995, p.86), if a cell is quiescent at time t, then it stays quiescent at time t+1 unless one or more of its neighbors is excited at time t, in which case the cell becomes excited at time t+1. If a node is excited at time t, then it becomes refractory at time t+1. If a node is refractory at time t, it becomes quiescent at time t+T where T is the refractory time.

HOW TO USE IT

Initially, all of the cells are quiescent, except for one chosen at random that is excited.

The user can control the refractory time and the excitation frequency.

The excitation frequency will lead to the temporal frequency at which a randomly chosen quiescent cell is excited. Thus, at each n-steps where n = "excitation frequency" a randomly chosen quiescent cell will become excited.

The user can also choose the base color for updating the refractory cell's colors in according with the color scheme:

"quiescent" -> white] "excited" -> black
"refractory" -> base-color-ref + r * 10

Where r is equal to refractory level (when r = 0 the refractory cell becomes quiescent again).

THINGS TO NOTICE

There are two plots: the number of quiescent cells and the delay plot for this number.

The user may notice the different dynamics for the different values of the excitation frequency.

THINGS TO TRY

An interesting test is to increase the excitation frequency to see the emerging patterns on the screen (Netlogo World) and on the plots.

Longer frequencies lead to more regular periodic dynamics, shorter frequencies lead to a chaotic dynamics.

The model makes emerge a form of nonlinear dynamics in a discrete state system that closely approaches a continuous state trajectory, a major modelling issue for risk science as stressed in the following article:

http://papers.ssrn.com/sol3/papers.cfm?abstract_id=2085482

The continuous state orbit is like a ghost skeleton present in the sequence of dots of the plot of the number quiescent cells.

In the delay plot we set the graph to "line" so that the shape of an attractor can be better visualized.

CREDITS AND REFERENCES

The current model has been used by the author, for teaching modelling techniques in the context of evolutionary game theory to MsC students at ISCSP - Technical University of Lisbon, and is part of the research project:

Complex Quantum Systems Science and Risk Mathematics

https://sites.google.com/site/quantumcomplexity/

In the classroom context, the model has been used to exemplify different social processes that lead to a behavioral propagation in the form of social waves, so that a connection is usually made in regards to risk mathematics.

Regarding the model the user may consult the reference:

Daniel Kaplan and Leon Glass (1995), "Understanding Nonlinear Dynamics", Springer-Verlag, New York.

Regarding the importance of emerging continuous state-like chaos in discrete state systems see:

Carlos P. Gonalves (2012), "Risk Governance - A Framework for Risk Science-Based Decision Support Systems", http://papers.ssrn.com/sol3/papers.cfm?abstractid=2085482

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

patches-own 
[ state
  new-state
  r ]


globals 
[clock
 number-of-quiescent_t-1
 number-of-quiescent_t ]

to setup
  ca
  ask patches [ set state "quiescent" ]
  ask one-of patches [ set state "excited" ]
  set number-of-quiescent_t count patches with [ state = "quiescent" ]
  colorscheme
end 

to go
  set clock clock + 1
  set number-of-quiescent_t-1 number-of-quiescent_t
  if (clock mod excitation-frequency) = 0 [ excite-patch ]
  set-new-state
  update-state
  set number-of-quiescent_t count patches with [ state = "quiescent" ]
  colorscheme
  do-plot
end 

to excite-patch
  ask one-of patches with [state = "quiescent"] [ set state "excited" ]
end 

to set-new-state
  ask patches [ ifelse (state = "quiescent") [quiescent-dynamics] [non-quiescent-dynamics] ]
end 

to update-state
  ask patches [ set state new-state ]
end 

to quiescent-dynamics
  ifelse (any? neighbors4 with [state = "excited"]) [ set new-state "excited" ] [ set new-state "quiescent" ]
end 

to non-quiescent-dynamics
  if state = "excited" [ set new-state "refractory" set r refractory-time ]
  if state = "refractory" and r > 0 
  [ set new-state "refractory" 
    set r r - 1 ]
  if state = "refractory" and r = 0 [ set new-state "quiescent" ]
end 

to do-plot
  set-current-plot "Number of Quiescent"
  plot number-of-quiescent_t
  
  set-current-plot "Number of Quiescent Delay"
  plotxy number-of-quiescent_t-1 number-of-quiescent_t
end 

to colorscheme
  ask patches 
  [ if state = "quiescent" [set pcolor white]
    if state = "excited" [set pcolor black]
    if state = "refractory" [set pcolor base-color-ref + r * 10] ]
end

There is only one version of this model, created over 11 years ago by Carlos Pedro S. Gonçalves.

Attached files

File	Type	Description	Last updated
Excitable Media.png	preview	Preview for 'Excitable Media'	about 11 years ago, by Carlos Pedro S. Gonçalves	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo