Segregation Minority/Majority Pops

No preview image

1 collaborator

WHAT IS IT?

This project models the behavior of two types of turtles in a mythical pond. The red turtles and green turtles get along with one another. But each turtle wants to make sure that it lives near some of "its own." That is, each red turtle wants to live near at least some red turtles, and each green turtle wants to live near at least some green turtles. The simulation shows how these individual preferences ripple through the pond, leading to large-scale patterns.

This project was inspired by Thomas Schelling's writings about social systems (such as housing patterns in cities).

HOW TO USE IT

Click the SETUP button to set up the turtles. There are equal numbers of red and green turtles. The turtles move around until there is at most one turtle on a patch. Click GO to start the simulation. If turtles don't have enough same-color neighbors, they jump to a nearby patch.

The NUMBER slider controls the total number of turtles. (It takes effect the next time you click SETUP.) The %-SIMILAR-WANTED slider controls the percentage of same-color turtles that each turtle wants among its neighbors. For example, if the slider is set at 30, each green turtle wants at least 30% of its neighbors to be green turtles.

The % SIMILAR monitor shows the average percentage of same-color neighbors for each turtle. It starts at about 50%, since each turtle starts (on average) with an equal number of red and green turtles as neighbors. The % UNHAPPY monitor shows the percent of turtles that have fewer same-color neighbors than they want (and thus want to move). Both monitors are also plotted.

THINGS TO NOTICE

When you execute SETUP, the red and green turtles are randomly distributed throughout the pond. But many turtles are "unhappy" since they don't have enough same-color neighbors. The unhappy turtles jump to new locations in the vicinity. But in the new locations, they might tip the balance of the local population, prompting other turtles to leave. If a few red turtles move into an area, the local green turtles might leave. But when the green turtles move to a new area, they might prompt red turtles to leave that area.

Over time, the number of unhappy turtles decreases. But the pond becomes more segregated, with clusters of red turtles and clusters of green turtles.

In the case where each turtle wants at least 30% same-color neighbors, the turtles end up with (on average) 70% same-color neighbors. So relatively small individual preferences can lead to significant overall segregation.

THINGS TO TRY

Try different values for %-SIMILAR-WANTED. How does the overall degree of segregation change?

If each turtle wants at least 40% same-color neighbors, what percentage (on average) do they end up with?

EXTENDING THE MODEL

Incorporate social networks into this model. For instance, have unhappy turtles decide on a new location based on information about what a neighborhood is like from other turtles in their network.

Change the rules for turtle happiness. One idea: suppose that the turtles need some minimum threshold of "good neighbors" to be happy with their location. Suppose further that they don't always know if someone makes a good neighbor. When they do, they use that information. When they don't, they use color as a proxy -- i.e., they assume that turtles of the same color make good neighbors.

REFLECTION

We altered this model in a few ways. First, we allowed the user to determine the percentage of red and green turtles in the pond. Whereas previously each group represented 50% of the total population, the new model allows for a sliding scale of majority and minority populations. Secondly, we allowed for population-specific happiness criteria. In the original model, both red and green populations were seeking the same percentage of similar turtles as neighbors. In the updated version, green and red turtles can have differing happiness criteria that affects the dynamics of the neighbor search.

A lighter population density allows for each group to relatively easily reach its desired state of happiness in its neighbors. When crowding occurs, however, populations' movements are restricted and turtles are often unable to attain stability and happiness in their pond social relations.

By working with the updated model, we also learned that one population's intense desire for homogeneity in its neighbors can result in completely segregated populations, despite the relaxed desires of the other group. Surprisingly as well, in a dense population when each group merely desired 25 or 30% of like neighbors, the pond still developed clear pockets of red and green turtles. Low thresholds can still result in clear demarcations of populations.

NETLOGO FEATURES

n-of and sprout are used to create turtles while ensuring no patch has more than one turtle on it.

When a turtle moves, move-to is used to move the turtle to the center of the patch it eventually finds.

CREDITS AND REFERENCES

Schelling, T. (1978). Micromotives and Macrobehavior. New York: Norton.

See also a recent Atlantic article: Rauch, J. (2002). Seeing Around Corners; The Atlantic Monthly; April 2002;Volume 289, No. 4; 35-48. http://www.theatlantic.com/issues/2002/04/rauch.htm

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

globals [
  percent-similar-red  ;; on the average, what percent of a turtle's neighbors
  percent-similar-green                 ;; are the same color as that turtle?
                   ;; IT WOULD BE INTERESTING TO HAVE A percent-similar-red and green
  percent-unhappy-red  ;; what percent of the turtles are unhappy?
  percent-unhappy-green          ;; IT WOULD BE INTERESTING TO HAVE percent-unhappy-red and green
]

turtles-own [
  happy?       ;; for each turtle, indicates whether at least %-similar-wanted percent of
               ;; that turtles' neighbors are the same color as the turtle
  similar-nearby   ;; how many neighboring patches have a turtle with my color?
  other-nearby ;; how many have a turtle of another color?
  total-nearby  ;; sum of previous two variables
]

to setup
  clear-all
  if number > count patches
    [ user-message (word "This pond only has room for " count patches " turtles.")
      stop ]

  ;; create turtles on random patches.
  ask n-of number patches
    [ sprout 1
      [ set color red ] ]
  ;; turn half the turtles green  IT WOULD BE INTERESTING TO CONTROL DEMOGRAPHIC PROPORTIONS 
  ask n-of (number * percent-green / 100) turtles
    [ set color green ]
  update-variables
  reset-ticks
end 

to go
  if all? turtles [happy?] [ stop ]
  move-unhappy-turtles
  update-variables
  tick
end 

to move-unhappy-turtles
  ask turtles with [ not happy? ]
    [ find-new-spot ]
end 

to find-new-spot ;;find spot is based on a random direction.  what would happen if turtles had
                 ;; knowledge of what places would make them more happy
  rt random-float 360
  fd random-float 10
  if any? other turtles-here
    [ find-new-spot ]          ;; keep going until we find an unoccupied patch
  move-to patch-here  ;; move to center of patch
end 

to update-variables
  update-turtles
  update-globals
end 

to update-turtles
  ask turtles [
    ;; in next two lines, we use "neighbors" to test the eight patches
    ;; surrounding the current patch
    set similar-nearby count (turtles-on neighbors)
      with [color = [color] of myself]
    set other-nearby count (turtles-on neighbors)
      with [color != [color] of myself]
    set total-nearby similar-nearby + other-nearby
    if color = red [
    set happy? similar-nearby >= ( %-similar-wanted-red * total-nearby / 100 )]
    if color = green [
    set happy? similar-nearby >= ( %-similar-wanted-green * total-nearby / 100)]
  ]
end 

to update-globals
  let similar-neighbors-red sum [similar-nearby] of turtles with [color = red]
  let similar-neighbors-green sum [similar-nearby] of turtles with [color = green]
  let total-neighbors-red sum [total-nearby] of turtles with [color = red]
  let total-neighbors-green sum [total-nearby] of turtles with [color = green]
  set percent-similar-red (similar-neighbors-red / total-neighbors-red) * 100
  set percent-similar-green (similar-neighbors-green / total-neighbors-green) * 100
  set percent-unhappy-red (count turtles with [color = red and not happy?]) / (count turtles with [color = red]) * 100
  set percent-unhappy-green (count turtles with [color = green and not happy?]) / (count turtles with [color = green]) * 100
end

There is only one version of this model, created almost 12 years ago by Peter Leonard.

Attached files

No files

Parent: Segregation - Majority/Minority

This model does not have any descendants.

Graph of models related to 'Segregation Minority/Majority Pops'

NetLogo