CODA opinion dynamics of science

1 collaborator

Duncan Law (Author)

WHAT IS IT?

A 'continuous opinions, discrete actions' (CODA) model of scientific opinion dynamics, based on the work of A.C.R. Martins (2010).

HOW IT WORKS

Agents have one of two beliefs - which can be interpreted as accepting or rejecting a scientific hypothesis P. Those beliefs can be strongly or weakly held - this is a Bayesian model of belief. Agents can observe nature, and can observe their neighbours' beliefs. These observations allow agents to update their own probability estimate of the true state of nature. In addition to this, agents may 'retire' and be replaced by new agents with new beliefs. Finally, agents may be able to observe their neighbours' last observations of nature - a possibility that represents the 'open science' practice of sharing data and other resources.

HOW TO USE IT

The 'startingtruthprob' slider determines the probability that any given agent will accept the hypothesis P on setup.

The 'startingopinionweight' slider determines the weight that any given agent is likely to place on their initial belief.

The 'newagenttruthprob' slider determines the probability that any new agent, replacing a retiring agent, will accept the hypothesis P. New agents are assumed to hold their beliefs only weakly.

The 'retireprob' slider determines the probability that any given agent will retire and be replaced by a new agent in each round of play.

The 'experimentprob' slider determines the probability that an agent will carry out an observation of nature in any given round of play.

The 'observationaccuracy' slider determines the probability that an observation of nature will be accurate.

The 'openscienceprob' slider determines the probability in any given round of play that an agent will observe the result of a neighbour's most recent observation of nature.

The 'plot1' graph shows the changing ratio of agents with true and false beliefs.

CREDITS AND REFERENCES

Model by Duncan Law. A more detailed discussion of the model can be found in Law, D. (2019) 'The reputational economics of open inputs science', Ph.D.

This NetLogo code is adapted from Wilensky, U. (1998). NetLogo Voting model. http://ccl.northwestern.edu/netlogo/models/Voting. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

The model is an extension of the CODA model of scientific opinion dynamics described in:

Martins, ACR (2010). 'Modeling scientific agents for a better science'. In: Advances in Complex Systems 13.4, pp. 519-533.

COPYRIGHT AND LICENSE

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

patches-own
[
  vote   ;; my vote (0 or 1)
  observation  ;; last observation of nature
  likelihood  ;; assessment of the likelihood of a proposition being true
]

to setup
  clear-all
  resize-world -24 25 -24 25
  ask patches [ generateinitialagent ]
  reset-ticks
end 

to go
  ask patches [
    if random-float 1 < retireprob [ generateagent ]
    ifelse random-float 1 < experimentprob [ conductexperiment ] [ learnfromneighbor ]
    ifelse likelihood > 0 [ set vote 1 ] [ set vote -1 ]
    recolor-patch
  ]
 if ticks = 1000 [
    stop ]
  tick
end 

to conductexperiment
  ifelse random-float 1 < observationaccuracy [ set observation 1 ] [ set observation ( -1 ) ]
    set likelihood ( likelihood + observation )
end 

to learnfromneighbor
  ifelse random-float 1 < openscienceprob
    [ set likelihood ( likelihood + ( [observation] of one-of neighbors ) ) ]
    [ set likelihood ( likelihood + ( [vote] of one-of neighbors ) ) ]
end 

to generateinitialagent
;    set likelihood ( 0 - random-float 100 )
    set likelihood ( ( startingtruthprob - ( random-float 1 ) ) * startingopinionweight )
    ifelse likelihood > 0 [ set vote 1 ] [ set vote -1 ]
    recolor-patch
end 

to generateagent
;    set likelihood ( 0 - random-float 100 )
    set likelihood ( newagenttruthprob - ( random-float 1 ) )
    ifelse likelihood > 0 [ set vote 1 ] [ set vote -1 ]
    recolor-patch
end 

to recolor-patch  ;; patch procedure
  ifelse vote = 1
    [ set pcolor black ]
    [ set pcolor white ]
end 

to writetofile

  ask patches
     [ file-write likelihood
        file-print "," ]
end 


; Law, D. (2017). CODA model of open inputs science.
; Model derived from:
;   Martins, A. C. R. (2008).
;   Continuous opinions and discrete actions in opinion dynamics problems.
;   International Journal of Modern Physics C, 19(04), 617-624.
; Code adapted from:
; Wilensky, U. (1998). NetLogo Voting model.
; http://ccl.northwestern.edu/netlogo/models/Voting.
; Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

There is only one version of this model, created over 4 years ago by Duncan Law.

Attached files

File	Type	Description	Last updated
CODA opinion dynamics of science.png	preview	Preview for 'CODA opinion dynamics of science'	over 4 years ago, by Duncan Law	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo