Mobility and virus propagation

;::::::::::::::::::::::::::::::::::::::::::::::::::: V I R U S   P R O P A G A T I O N ::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::Código y diseño: Dr. Javier Sadoval Félix:::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::Contacto: jarquisol@gmail.com:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
globals [available-beds]
turtles-own
  [ sick?
    immune?
    mobile?
    time-sick
    time-remaining-to-decide-to-hospitalize]

to setup
  clear-all
  setup-turtles
  update-visualization
  set available-beds total-beds
  reset-ticks
end 

to go
  ask turtles [
    if mobile? [fd .3]
    if sick? [
      infect
      set time-sick time-sick + 1
      set time-remaining-to-decide-to-hospitalize time-remaining-to-decide-to-hospitalize - 1

    if time-remaining-to-decide-to-hospitalize = 0 [
      set available-beds available-beds - 1
      set hidden? true]
    ]

    if sick? and time-sick = 300 [
      set sick? false set immune? true
      if hidden? [set available-beds available-beds + 1]
      set hidden? false
      if mobile? = false [set mobile? true]
  ]]

  update-visualization
  if count turtles with [sick?] = 0 [
    user-message "There is no more sick population"
    stop]
  if available-beds = 0 [
    user-message "There are no more beds available"
    stop]
  tick
end 

to setup-turtles
  create-turtles population
    [ setxy random-xcor random-ycor
      set mobile? true
      set size 1
      set shape "circle"
      set color green
      set immune? false
      healthy ]
  ask n-of (population * (%fixed-population / 100))  turtles [set mobile? false]
  ask n-of 1 turtles with [mobile? = true]
    [ enfermarse
      set time-remaining-to-decide-to-hospitalize random 300]
end 

to update-visualization
  ask turtles [
    ifelse sick?
    [set color red ]
    [ifelse immune? [set color grey ] [set color green]]
  ]
end 

to healthy
  set sick? false
end 

to enfermarse
  set sick? true
  set time-sick time-sick + 1
end 

to infect
  if hidden? = false [
  ask other turtles-here with [ not sick? and not immune? ] [
    enfermarse
    set time-remaining-to-decide-to-hospitalize random 150
  ]]
end