Vibrational Heat Diffusion

Vibrational Heat Diffusion preview image

1 collaborator

Default-person Jacob Wolf (Author)

Tags

(This model has yet to be categorized with any tags)
Visible to everyone | Changeable by everyone
Model was written in NetLogo 6.0.3 • Viewed 87 times • Downloaded 4 times • Run 0 times
Download the 'Vibrational Heat Diffusion' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model simulates transient and steady-state temperature distribution of a thin plate.

The View shows a square thin plate as viewed from above. The plate is thermally isolated on the two faces parallel to the view such that heat can flow only in and out from the perimeter of the plate and not into or out of the world. Heat is kept constant at the edges. As the simulation runs, heat is transmitted from warmer parts of the plate to cooler parts of the plate as shown by the varying color of the plate. Therefore, the temperature of the plate begins to change immediately and possibly differently at different locations, gradually converging to a stable state. Overall, the temperature distribution over the plate is a function of time and location. In addition to this simple use of the model, you are encouraged to control various paramaters, such as the temperature of each edge edge of the plate and of the center of the plate before--and even while--the model is running.

Heat diffuses ("spreads") at different rates through different media. These rates can be determined and are called the Thermal Diffusivity of the material. The Greek letter alpha is often associated with this value. The diffusivity of a material does not change based on how much of the material there is. It is always the same. Below is a table containing several different materials with different diffusivity rates. See that wood (bottom row) has a lower heat diffusivity than, say, iron. This means that it takes a longer for heat to spread through a wooden object than an iron one. That is one reason why the handles of iron saucepans are wooden, and not the other way round. Also, think of a marble table with iron legs that has just been put out in the sun in a street-side cafe. Which material part of the table do you expect will warm up faster? The model allows you to change thermal diffusivity of the plate in two ways. You can directly change the value of ALPHA to any value you like, or you can indirectly change ALPHA by selecting a material.

Thermal diffusivity of selected materials

MaterialThermal diffusivity
(alpha cm*cm/s)
Wood (Maple)0.00128
Stone (Marble)0.0120
Iron0.2034
Aluminum0.8418
Silver1.7004

HOW IT WORKS

Initialize the plate and edges to have temperatures that equal their respective slider values. Each time through the GO procedure, diffuse the heat on each patch in the following way. Have each patch set its current temperature to the sum of the 4 neighbors' old temperature times a constant based on alpha plus a weighted version of the patch's old temperature. (For those interested, the updated temperature is calculated by using a Forward Euler Method.) Then the edges are set back to the specified values and the old temperature is updated to the current temperature. Then the plate is redrawn.

HOW TO USE IT

There are five temperature sliders which enable users to set four fixed edge temperatures and one initial plate temperature: -- TOP-TEMP - Top edge temperature -- BOTTOM-TEMP - Bottom edge temperature -- IN-PLATE-TEMP - Initial plate temperature -- LEFT-TEMP - Left edge temperature -- RIGHT-TEMP - Right edge temperature

There are two sliders that govern the thermal diffusivity of the plate: -- MATERIAL-TYPE - The value of the chooser is that of the above chart. You must press UPDATE ALPHA for this to change the value of ALPHA. -- ALPHA - The alpha constant of thermal diffusivity

There are four buttons with the following functions: -- SETUP - Initializes the model -- GO - Runs the simulation indefinitely -- GO ONCE - Runs the simulation for 1 time step -- UPDATE ALPHA - press this if you want to set ALPHA to a preset value based on a material selected by the MATERIAL-TYPE chooser

The TIME monitor shows how many time steps the model has gone through.

THINGS TO NOTICE

How does the equilibrium temperature distribution vary for different edge temperature settings?

Notice how an equilibrium (the steady-state condition) is reached.

Keep track of the units:

VariablesUnits
time0.1 second
temperaturedegrees Celsius
lengthcentimeters
diffusivitysquare centimeters per second

THINGS TO TRY

Set the parameters on the temperature sliders. Pick a value for ALPHA (or pick MATERIAL-TYPE and press UPDATE ALPHA). After you have changed all the sliders to values you like, press Setup followed by GO or GO ONCE.

Try different materials to observe the heat transfer speed. How does this compare to physical experiments?

Try the following sample settings:

  • Top:100, Bottom:0, Left:0, Right:0
  • Top:0, Bottom:100, Left:100, Right:100
  • Top:0, Bottom:66, Left:99, Right:33
  • Top:25, Bottom:25, Left:100, Right:0

EXTENDING THE MODEL

This model simulates a classic partial differential equation problem (that of heat diffusion). The thin square plate is a typical example, and the simplest model of the behavior. Try changing the shape or thickness of the plate (e.g. a circular or elliptical plate), or adding a hole in the center (the plate would then be a slice of a torus, a doughnut-shaped geometric object).

Add a slider to alter this thickness.

Try modeling derivative or combined boundary conditions.

RELATED MODELS

Heat Diffusion - Alternative Gradient

HOW TO CITE

If you mention this model or the NetLogo software in a publication, we ask that you include the citations below.

For the model itself:

Please cite the NetLogo software as:

COPYRIGHT AND LICENSE

Copyright 1998 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit https://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the project: CONNECTED MATHEMATICS: MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL MODELS (OBPML). The project gratefully acknowledges the support of the National Science Foundation (Applications of Advanced Technologies Program) -- grant numbers RED #9552950 and REC #9632612.

This model was converted to NetLogo as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227. Converted from StarLogoT to NetLogo, 2001.

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

;; set global properties for simulation
globals [
  ;; the size of the plate on which heat is diffusing
  plate-size
  ;; Used for scaling the color of the patches
  ;; the minimum temperature at setup time
  min-temp
  ;; the maximum temperature at setup time
  max-temp
  ;; the value for each material
  alpha
  room-temp
  bottom-temp
]

;; properties owned by turtles
turtles-own [
  ;; current temperature of the turtle
  temperature
  ;; old tempearture
  old-temperature
  ;; remembers the old position
  vibrate-energy
]

;;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;

;; create visualization and initialize variables

to setup
  ;; clear previous experiments
  ca
  set room-temp room-temperature
  set bottom-temp bottom-temperature
  ;; use 0.6 to make a nice sized plate
  set plate-size round (0.7 * max-pxcor)
  ;; update alpha value according to picked material
  update-alpha
  ;; set up the plate
  ask patches [
    ;; if the patch is on the plate, then change background
    ifelse (abs pycor) <= plate-size and pxcor <= plate-size + 3 and pxcor >= (- plate-size + 3)
    [ set pcolor black ]
    [ set pcolor gray ]
  ]
  ask patches with [pcolor = black][
    ;; create a turtle if on the plate
    sprout 1 [
      ;; set shape of the turtle
      set shape "circle"
      ;; assign to molecules the room temperature
      set temperature room-temp
      ;; give to the bottom ones the temperature of the bunsen
      if pycor = (- plate-size) [set temperature bottom-temp]
      ;; save old value
      set old-temperature temperature
      ;; set a mass
      set size 0.8; ^ .33
      set heading 90
    ]
  ]
  ask turtles with [pycor = -15][
    set pcolor scale-color red rescale bottom-temp 19.9 14.4
  ]
  ask patch 5 -16 [set plabel "heat source"]
  ;; find min temperature among patches
  set min-temp 0
  ;; find max temperature among patches
  set max-temp 100
  ;;
  ask turtles [color-molecule]
  ;; draw the legend
  draw-legend
  ;; start time
  reset-ticks
end 

;; rescale the temperature to fit the color scheme

to-report rescale [value]
  report ((value - room-temp) / (bottom-temp - room-temp)) * (17 - 14.5) + 14.5
end 

to-report rescale-legend [value]
  report ((value - 20) / ((floor (bottom-temp / 10) * 10) - 20)) * (17 - 14.5) + 14.5
end 

;; color turtles based on temperature

to color-molecule
  set color scale-color red rescale temperature 19.9 14.4
end 

;; sets the material

to update-alpha
  ;; assign alpha for wood
  if pick-material = "wood"     [ set alpha 0.00128 ]
  ;; assign the alpha for stone
  if pick-material = "stone"    [ set alpha 0.012   ]
  ;; assign the alpha for iron
  if pick-material = "iron"     [ set alpha 0.2034  ]
  ;; assign the alpha for aluminium
  if pick-material = "aluminum" [ set alpha 0.8418  ]
  ;; assign the alpha for silver
  if pick-material = "copper"   [ set alpha 1.7004  ]
end 

;; Draws the Color Scale Legend, from room-temperature (min) to bottom-temperature (max)

to draw-legend
  let x (1 + min-pxcor)
  let rep int (bottom-temp / 10 + 1) - 2
  repeat 3 [
    let y 0
    repeat rep [
      ask patch (x + 4) (y * 2 - 11) [ set pcolor (scale-color red rescale-legend (y * 10 + 20) 19.9 14.4) ]
      ask patch (x + 4) (y * 2 - 10) [ set pcolor (scale-color red rescale-legend (y * 10 + 20) 19.9 14.4) ]
      set y y + 1
    ]
    set x x + 1
  ]
  set x (1 + min-pxcor)
  repeat 3 [
    let y 0
    repeat rep + 1[
      if (x = (3 + min-pxcor)) [
        ask patch x (y * 2 - 12) [
          set plabel (y * 10 + 20)
        ]
      ]
      set y y + 1
    ]
    set x x + 1
  ]
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Runtime Procedures ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;

;; Runs the simulation through a loop

to go
  ;; ask only patches in the plate
  ask n-of 100 turtles [
    ;; find the new temperature
    set temperature new-temperature
    ;; set the edges back to their constant heat
    if pycor = (- plate-size) [ set temperature bottom-temp ]
    ;; save old temperature
    set old-temperature temperature
    ;;
    color-molecule
    ;;
    if ticks mod 5 = 0 [
      ;;
      if random (room-temp + 10) < temperature [
        ;;
        visualize-vibrational-energy
      ]
    ]
  ]
  ; increment time by 1 unit
  tick
end 

;; calculate a new temperature

to-report new-temperature
  ;; agents in the border/corner will have less neighbors
  let nei count turtles-on neighbors
  ;; diffuse the heat of a turtle with its neighbors
  report ( heat-diffusivity * ( sum [ old-temperature] of ( turtles-on neighbors with [pcolor != 5]) ) ) + ((1 - ( nei * heat-diffusivity )) * old-temperature)
end 

;; report the heat diffusivity constant that we use for the calculations

to-report heat-diffusivity
  ;; a few notes on the constants used here:
  ;; --we use .25 as a time step that causes the heat to diffuse at a reasonable pace
  ;; --we use alpha + .3 instead of just alpha here since alpha would be too
  ;; small to view any changes between some of the preset materials
  ;; --these constants are necessary since this model uses an Euler approximation to
  ;; calculate the temperature.  the approximation is only valid within a certain range
  ;; of time-steps and this range changes depending upon the value of alpha.
  report .25 * e ^ (-1 / (alpha + .3));
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; PARTICLES PROCEDURES ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

to visualize-vibrational-energy
  set vibrate-energy (vibrate-energy + temperature / 5)
  if vibrate-energy >= temperature [set vibrate-energy temperature]
  if vibrate-energy <= (- temperature) [set vibrate-energy (- temperature)]
  setxy pxcor +  ((sqrt vibrate-energy) * (1 - random-float 3)) / 100 pycor + ((sqrt vibrate-energy) * (1 - random-float 3)) / 100
end 

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; © 2018 Transformative Learning Technologies Lab, Stanford Graduate School of Education
;;
;; based on the original models "Heat Diffusion" © 1998 Uri Wilensky (heat conduction) and "Connected Chemistry Rusting Reaction" © 2007 Uri Wilensky
;;
;; developer: DigitalDust Consulting Sagl - info@digitaldustconsulting.com

There is only one version of this model, created over 1 year ago by Jacob Wolf.

Attached files

File Type Description Last updated
Vibrational Heat Diffusion.png preview Preview for 'Vibrational Heat Diffusion' over 1 year ago, by Jacob Wolf Download

This model does not have any ancestors.

This model does not have any descendants.