T Cell Movement in Lymph nodes

links-own [ tDCfree ]
globals [ dt ds tcell-step nDCmeet ]
; ...
; nDCmeet = number of DC-T cell encounters
breed [tcells tcell] ; the T cells
breed [DCs DC] ; the dendritic cells (DCs)

to setup
clear-all
set-default-shape turtles "circle" ; all turtles will be circles (spheres)
create-tcells 100 [
set color green ; make T cell green
setxyz random-xcor random-ycor random-zcor ; put T cell at random location
]
create-DCs 2 [
set size 2 ; make DC of size 2 (twice that of T cells)
set color red ; make DC red
setxyz random-xcor random-ycor random-zcor
]
  set dt 0.5 ; 0.5 min per time step
set ds 8 ; 8 um per patch
set tcell-step 16 / ds * dt ; (16 um/min)*(1 patch/8 um)*(0.5 min/time step)
end 

to go
move-tcells ; move T cell movement commands into a function
identify-DCbound-tcells ; new function to identify DC-bound T cells
update-link-status ; new function to update DC-T cell links
plotxy ticks nDCmeet
  tick-advance dt
end 

to move-tcells ; function for T cell motion
ask tcells [
right random-normal 0 90
roll-right random-normal 0 90
forward tcell-step
]
end 

to identify-DCbound-tcells ; function to identify DC-bound T cells
ask DCs [
create-links-to tcells with [ color != blue ] in-radius 2 [
      set nDCmeet nDCmeet + 1
set color red ; make the link red
set tDCfree 3 ; bound for 3 minutes
ask end2 [ set color blue ] ; make the linked T cell blue
]
]
end 

to update-link-status ; function to update the DC-T cell links
ask links [
set tDCfree tDCfree - dt ; update time remaining for link
if tDCfree < 0 [ ; if tDCfree has elapsed
ask end2 [ set color green ] ; set T cell to its green colour
die ; kill the link (delete it)
]
]
end